BaseValidatorDesigner.GetDesignTimeHtml メソッド

デザイン時にコントロールを表すために使用する HTML を取得します。

Overrides Public Function GetDesignTimeHtml() As String
[C#]
public override string GetDesignTimeHtml();
[C++]
public: String* GetDesignTimeHtml();
[JScript]
public override function GetDesignTimeHtml() : String;

戻り値

デザイン時にコントロールを表すために使用する HTML。

使用例

[Visual Basic] SimpleCompareValidatorDesigner という名前のデザイナ クラスを作成するコード例を次に示します。このクラスは、 BaseValidatorDesigner の派生クラスで、デザイン時に CustomAdRotator という名前のクラスを表示します。このコードは、 GetDesignTimeHtml をオーバーライドして、デザイン時に検証コントロールの BaseValidator.ErrorMessage プロパティと BaseValidator.Display プロパティの値を設定します。 Try ブロックのコードでいずれかのプロパティの値が変更された場合は、 Finally ブロックのコードにより、プロパティの値が元の値に戻されます。

 
Imports System
Imports System.ComponentModel
Imports System.Web
Imports System.Web.UI
Imports System.Web.UI.WebControls
Imports System.Web.UI.Design
Imports System.Web.UI.Design.WebControls
Imports Examples.AspNet

Namespace Examples.AspNet.Design

    ' Create a class that derives from the
    ' BaseValidatorDesigner class that will 
    ' display a CustomCompareValidator class 
    ' at design time.
    Public Class SimpleCompareValidatorDesigner
        Inherits BaseValidatorDesigner
       
        ' Extend the GetDesignTimeHtml functionality to
        ' alter the design-time ForeColor if the Text
        ' property is defined.
         Overrides Public Function GetDesignTimeHtml() As String
             Dim cv As SimpleCompareValidator = _
                 CType(Component, SimpleCompareValidator)
             Dim designTimeHtml As String  
      
             ' Check the control's BorderStyle property
             ' to conditionally render design-time HTML.
             If (cv.BorderStyle = BorderStyle.NotSet) Then

                 ' Create variables to hold current property settings.
                 Dim oldBorderStyle As BorderStyle = cv.BorderStyle
                    
                 ' Set properties and the design-time HTML.
                 Try
                     cv.BorderStyle = BorderStyle.Solid              
                     designTimeHtml = MyBase.GetDesignTimeHtml()
                
                 ' If an exception occurs, call the GetErrorDesignTimeHtml
                 ' method.
                 Catch ex As Exception
                     designTimeHtml = GetErrorDesignTimeHtml(ex)

                 ' Return properties to their original settings.
                 Finally
                     cv.BorderStyle = oldBorderStyle
                 End Try
          
             Else
                 designTimeHtml = MyBase.GetDesignTimeHtml()
             End If
      
             Return designTimeHtml
         End Function
            
    End Class
End Namespace
           

[C#, C++, JScript] C#、C++、および JScript のサンプルはありません。Visual Basic のサンプルを表示するには、このページの左上隅にある言語のフィルタ ボタン をクリックします。

必要条件

プラットフォーム: Windows 2000, Windows XP Professional, Windows Server 2003 ファミリ

.NET Framework セキュリティ:

• 直前の呼び出し元の完全信頼。このメンバは、部分的に信頼されているコードから使用することはできません。詳細の参照先 : 部分信頼コードからのライブラリの使用

参照

BaseValidatorDesigner クラス | BaseValidatorDesigner メンバ | System.Web.UI.Design.WebControls 名前空間