インデックス操作をオンラインで実行する

このトピックでは、SQL Server Management Studio または Transact-SQL を使用して、SQL Server 2014 でインデックスをオンラインで作成、再構築、または削除する方法について説明します。 ONLINE オプションを使用すると、これらのインデックス操作中に、基になるテーブルまたはクラスター化インデックスデータおよび関連付けられている非クラスター化インデックスに対する同時ユーザーアクセスが可能になります。たとえば、クラスター化インデックスが 1 人のユーザーによって再構築されている間、そのユーザーとその他のユーザーは、基になるデータの更新とクエリを続行できます。クラスター化インデックスの構築や再構築など、データ定義言語 (DDL) 操作をオフラインで実行する場合。これらの操作は、基になるデータと関連するインデックスに対する排他ロックを保持します。これにより、インデックス操作が完了するまで、基になるデータに対する変更とクエリが防止されます。

注

オンラインインデックス操作は、すべての SQL Server エディションで使用できるわけではありません。詳しくは「 Features Supported by the Editions of SQL Server 2014」をご覧ください。

このトピックについて

作業を開始する準備:

制限事項と制約事項

セキュリティ
オンラインでインデックスを再構築するには、次を使用します。

SQL Server Management Studio

Transact-SQL

開始する前に

制限事項と制約条件

インデックス操作中の同時ユーザーアクティビティの必要性が不可欠な、1 日 24 時間、週 7 日動作するビジネス環境では、オンラインインデックス操作を実行することをお勧めします。
ONLINE オプションは、次の Transact-SQL ステートメントで使用できます。
- CREATE INDEX
- ALTER INDEX
- DROP INDEX
- ALTER TABLE (CLUSTERED インデックスオプションを使用して UNIQUE 制約または PRIMARY KEY 制約を追加または削除するには)
オンラインでのインデックスの作成、再構築、または削除に関するその他の制限事項と制限については、「オンラインインデックス操作のガイドライン」を参照してください。

安全

権限

テーブルまたはビューに対する ALTER 権限が必要です。

SQL Server Management Studio の使用

オンラインでインデックスを再構築するには

オブジェクトエクスプローラーで、プラス記号をクリックして、インデックスをオンラインで再構築するテーブルを含むデータベースを展開します。
[テーブル] フォルダーを展開します。
プラス記号をクリックして、インデックスをオンラインで再構築するテーブルを展開します。
[インデックス] フォルダーを展開します。
オンラインで再構築するインデックスを右クリックし、[プロパティ] を選択 します。
[ ページの選択] で [ オプション] を選択します。
[ オンライン DML 処理を許可する] を選択し、一覧から [True ] を選択します。
OK をクリックします。
オンラインで再構築するインデックスを右クリックし、[ 再構築] を選択します。
[インデックスの再構築] ダイアログボックスで、再構築するインデックスに正しいインデックスがあることを確認し、[OK] をクリックします。

Transact-SQL の使用

オンラインでインデックスを作成、再構築、または削除するには

オブジェクトエクスプローラーで、データベースエンジンのインスタンスに接続します。
標準バーで [新しいクエリ] をクリックします。

次の例をコピーしてクエリウィンドウに貼り付け、 [実行] をクリックします。この例では、既存のオンラインを再構築します。

USE AdventureWorks2012;  
GO  
ALTER INDEX AK_Employee_NationalIDNumber ON HumanResources.Employee  
REBUILD WITH (ONLINE = ON);  
GO

次の例では、クラスター化インデックスをオンラインで削除し、MOVE TO句を使用して結果のテーブル (ヒープ) をファイルグループ NewGroupに移動します。 sys.indexes、sys.tables、およびsys.filegroupsカタログビューが照会され、移動の前後にファイルグループ内のインデックスとテーブルの配置が確認されます。

USE AdventureWorks2012;
GO
--Create a clustered index on the PRIMARY filegroup if the index does not exist.
IF NOT EXISTS (SELECT name FROM sys.indexes WHERE name = 
            N'AK_BillOfMaterials_ProductAssemblyID_ComponentID_StartDate')
    CREATE UNIQUE CLUSTERED INDEX
        AK_BillOfMaterials_ProductAssemblyID_ComponentID_StartDate 
    ON Production.BillOfMaterials (ProductAssemblyID, ComponentID, 
        StartDate)
    ON 'PRIMARY';
GO
-- Verify filegroup location of the clustered index.
SELECT t.name AS [Table Name], i.name AS [Index Name], i.type_desc,
    i.data_space_id, f.name AS [Filegroup Name]
FROM sys.indexes AS i
    JOIN sys.filegroups AS f ON i.data_space_id = f.data_space_id
    JOIN sys.tables as t ON i.object_id = t.object_id
        AND i.object_id = OBJECT_ID(N'Production.BillOfMaterials','U')
GO
--Create filegroup NewGroup if it does not exist.
IF NOT EXISTS (SELECT name FROM sys.filegroups
                WHERE name = N'NewGroup')
    BEGIN
    ALTER DATABASE AdventureWorks2012
        ADD FILEGROUP NewGroup;
    ALTER DATABASE AdventureWorks2012
        ADD FILE (NAME = File1,
            FILENAME = 'C:\Program Files\Microsoft SQL Server\MSSQL10.MSSQLSERVER\MSSQL\DATA\File1.ndf')
        TO FILEGROUP NewGroup;
    END
GO
--Verify new filegroup
SELECT * from sys.filegroups;
GO
-- Drop the clustered index and move the BillOfMaterials table to
-- the Newgroup filegroup.
-- Set ONLINE = OFF to execute this example on editions other than Enterprise Edition.
DROP INDEX AK_BillOfMaterials_ProductAssemblyID_ComponentID_StartDate 
    ON Production.BillOfMaterials 
    WITH (ONLINE = ON, MOVE TO NewGroup);
GO
-- Verify filegroup location of the moved table.
SELECT t.name AS [Table Name], i.name AS [Index Name], i.type_desc,
    i.data_space_id, f.name AS [Filegroup Name]
FROM sys.indexes AS i
    JOIN sys.filegroups AS f ON i.data_space_id = f.data_space_id
    JOIN sys.tables as t ON i.object_id = t.object_id
        AND i.object_id = OBJECT_ID(N'Production.BillOfMaterials','U');
GO

詳細については、「ALTER INDEX (Transact-SQL)」を参照してください。

Last updated on 2017-06-13