コマンドの結果が名前付きコマンドの変数 として渡されるのと同様に、パラメーター化されたコマンドのパラメーターは、変数の として名前付きコマンドに渡すことができます。
次のコード例では、CustomerID が "ALKFI" である顧客によって行われたすべての注文を Northwind データベースから取得しようとします。 CustomerID の値は、名前付きコマンドが呼び出されたときに指定されます。
Const DS = "MySqlServer"
Const DB = "Northwind"
Const DP = "SQLOLEDB"
Dim objConn As New ADODB.Connection
Dim objRs As New ADODB.Recordset
Dim objComm As New ADODB.Command
CommandText = "SELECT OrderID, OrderDate, " & _
"RequiredDate, ShippedDate " & _
"FROM Orders " & _
"WHERE CustomerID = ? " & _
"ORDER BY OrderID"
ConnectionString = "Provider=" & DP & _
";Data Source=" & DS & _
";Initial Catalog=" & DB & _
";Integrated Security=SSPI;"
' Connect to the data source.
objConn.Open ConnectionString
' Set a named command.
objComm.CommandText = CommandText
objComm.CommandType = adCmdText
objComm.Name = "GetOrdersOf"
Set objComm.ActiveConnection = objConn
' Call the named command, passing a CustomerID value
' as the input parameter.
' "ALFKI" is the required input parameter,
' objRs is the resultant output variable.
objConn.GetOrdersOf "ALKFI", objRs
' Display the result.
Debug.Print "All orders by ALFKI:"
Do While Not objRs.EOF
Debug.Print vbTab & objRs(0) & vbTab & objRs(1) & vbTab & _
objRs(2) & vbTab & objRs(3)
objRs.MoveNext
Loop
' Clean up.
objRs.Close
objConn.Close
Set objRs = Nothing
Set objConn = Nothing
Set objComm = Nothing
すべての入力パラメーターが出力変数の前に必要であり、パラメーターのデータ型が一致する必要があり、対応するフィールドのデータ型に変換できることに注意してください。 次のステートメント
objConn.GetOrdersOf 12345, objRs
必要な入力パラメーターは、整数 型ではなく、文字列 型であるため、データ型の不一致のエラーが発生します。
次の呼び出し
objConn.GetOrdersOf "12345", objRs
は有効ですが、データベースにそのようなレコードが存在しないため、空の結果セットが生成されます。