X++ 변환 런타임 함수

이 문서에서는 변환 런타임 함수에 대해 설명합니다.

any2Date

anytype 값을 날짜 값으로 변환합니다.

date any2Date(anytype object)

매개 변수

반환 값

날짜 값입니다.

비고

개체 매개 변수는 대부분의 데이터 형식일 수 있지만 str 또는 int 형식일 때 유용한 출력을 가져옵니다. 부적절한 콘텐츠가 런타임 오류를 생성합니다.

Example

static void any2DateExample(Args _args)
{
    date myDate;
    str s;
    int i;
    s = "2010 6 17"; // A string object, of yyyy mm dd.
    myDate = any2Date(s);
    Global::info(strFmt("%1  is output, from input of "2010 6 17"", myDate));
    i = 40361; // An int object, which represents the number of days from 1900/01/01.
    myDate = any2Date(i);
    Global::info(strFmt("%1  is output, from input of 40361", myDate));
}
/**** Infolog display.
Message (04:44:15 pm)
6/17/2010 is output, from input of "2010 6 17"
7/4/2010 is output, from input of 40361
****/

any2Enum

anytype 값을 대상 열거형에 있는 요소의 Name 속성 값으로 변환합니다.

enum any2Enum(anytype object)

매개 변수

반환 값

대상 열거형의 요소 중 입력 매개 변수와 일치하는 Value 속성이 있는 요소에 대한 Name 속성의 값입니다.

비고

개체 매개 변수는 대부분의 데이터 형식일 수 있지만 str 또는 int 형식의 매개 변수를 사용하는 경우에만 유용한 데이터를 가져옵니다. 이 입력 개체 매개 변수는 대상 열거형에 있는 개별 요소의 Value 속성을 참조합니다.

Example

static void any2EnumExample(Args _args)
{
    NoYes myNoYes;  // NoYes is an enum.
    int i;
    str s;
    i = 0;  // An int that will be converted.
    myNoYes = any2Enum(i);
    Global::info(strfmt("'%1' - is the output, from input of the %2 as int.", myNoYes, i));
    s = "1";  // A str that will be converted.
    myNoYes = any2Enum(s);
    Global::info(strfmt("'%1' - is the output, from input of the %2 as str.", myNoYes, s));
    /**** Infolog display.
    Message (01:05:32 pm)
    'No' - is the output, from input of the 0 as int.
    'Yes' - is the output, from input of the 1 as str.
    ****/
}

any2Guid

지정된 anytype 개체를 GUID 개체로 변환합니다.

guid any2Guid(anytype object)

매개 변수

반환 값

GUID 개체입니다.

any2Int

anytype 값을 int 값으로 변환합니다.

int any2Int(anytype object)

매개 변수

반환 값

int 값입니다.

비고

개체 매개 변수는 대부분의 데이터 형식일 수 있지만 열거형, 실제 또는 str 형식의 매개 변수를 사용하는 경우에만 유용한 데이터를 가져옵니다.

Example

static void any2IntExample(Args _args)
{
    int myInt;
    str s;
    NoYes a;
    real r;
    s = "31";
    myInt = any2Int(s);
    Global::info(strfmt("%1 is the output, from input of 31 as a str value.", myInt));
    a = NoYes::No;
    myInt = any2Int(a);
    Global::info(strfmt("%1 is the output, from input of NoYes::No as an enum value.", myInt));
    r = 5.34e2;
    myInt = any2Int(r);
    Global::info(strfmt("%1 is the output, from the input of 5.34e2 as a real value.", myInt));
}
/**** Infolog display.
Message (02:23:59 pm)
31 is the output, from input of 31 as a str value.
0 is the output, from input of NoYes::No as an enum value.
534 is the output, from the input of 5.34e2 as a real value.
****/

any2Int64

anytype 개체를 int64 개체로 변환합니다.

int64 any2Int64(anytype object)

매개 변수

반환 값

int64 개체입니다.

any2Real

anytype 값을 실제 값으로 변환합니다.

real any2Real(anytype object)

매개 변수

반환 값

실제 값입니다.

비고

개체 매개 변수는 대부분의 데이터 형식일 수 있지만 날짜, int, enum 및 str 형식의 입력 요소에 대해 유용한 출력을 가져옵니다.

Example

static void any2RealExample(Args _args)
{
    real myReal;
    str s;
    int i;
    NoYes a;
    s = "5.12";
    myReal = any2Real(s);
    Global::info(strfmt("%1 is the output from the input of 5.12 as a str object", myReal));
    i = 64;
    myReal = any2Real(i);
    Global::info(strfmt("%1 is the output from the input of 64 as an int object", myReal));
    a = NoYes::Yes;
    myReal = any2Real(a);
    Global::info(strfmt("%1 is the output from the input of NoYes::Yes as an enum object", myReal));
}
/****Infolog display.
Message (02:43:57 pm)
5.12 is the output from the input of 5.12 as a str object
64.00 is the output from the input of 64 as an int object
1.00 is the output from the input of NoYes::Yes as an enum object
****/

any2Str

anytype 값을 str 값으로 변환합니다.

str any2Str(anytype object)

매개 변수

반환 값

str 값입니다.

비고

개체 매개 변수는 대부분의 데이터 형식일 수 있지만 날짜, int 및 열거형 형식의 입력 요소에서 유용한 출력을 가져옵니다.

Example

static void any2StrExample(Args _args)
{
    str myStr;
    anytype a;
    a = "Any to string";
    myStr = any2Str(a);
    Global::info(strFmt("%1 is output, from input of Any to string as a str value", myStr));
    a = NoYes::Yes;
    myStr = any2Str(a);
    Global::info(strFmt("%1 is output, from input of NoYes::Yes as an enumeration", myStr));
}
/****Infolog Display
Message (09:08:46 am)
Any to string is output, from input of Any to string as a str value
1 is output, from input of NoYes::Yes as an enumeration
****/

anytodate

any2Date를 참조하세요.

anytoenum

any2Enum을 참조하세요.

anytoguid

any2Guid를 참조하세요.

anytoint

any2Int를 참조하세요.

anytoint64

any2Int64를 참조하세요.

anytoreal

any2Real을 참조하세요.

anytostr

any2Str을 참조하세요.

char2Num

문자열의 문자를 문자의 ASCII 값으로 변환합니다.

int char2Num(str text, int position)

매개 변수

반환 값

int 개체인 문자의 ASCII 값입니다.

비고

char2Num("ABCDEFG",3); //Returns the numeric value of C, which is 67.
char2Num("ABCDEFG",1); //Returns the numeric value of A, which is 65.

date2Num

날짜를 1900년 1월 1일 이후의 일 수에 해당하는 정수로 변환합니다.

int date2Num(date _date)

매개 변수

반환 값

1900년 1월 1일과 지정된 날짜 사이의 일 수입니다.

Example

//Returns the value377.
date2Num(1311901);
static void date2NumExample(Args _arg)
{
    date d = today();
    int i;
    i = date2Num(d);
    print i;
}

date2Str

지정된 날짜를 문자열로 변환합니다.

str date2Str(date date, int sequence, int day, int separator1, int month, int separator2, int year [, int flags = DateFlags::None])

매개 변수

반환 값

지정된 날짜를 나타내는 문자열입니다.

비고

지정된 값이 유효하지 않은 경우 MorphX는 서식 매개 변수에 유효한 값을 할당합니다. 사용자가 국가별 설정에서 지정한 날짜 형식을 사용하려면 strFmt 또는 date2Str 함수를 사용하고 모든 서식 매개 변수에 -1 을 지정합니다. 지역 설정이 날짜 형식을 제어하는 경우 설정이 사용자에서 사용자로 변경됩니다. 구분 기호 매개 변수에 -1을 사용하는 경우 두 구분 기호 모두 기본적으로 국가별 설정으로 설정됩니다. 시퀀스 매개 변수 값은 각 숫자 1, 2 및 3의 정확히 하나의 발생을 포함하는 세 자리 숫자여야 합니다. 숫자 1, 2 및 3은 각각 일, 월 및 연도를 나타냅니다. 예를 들어 321 은 시퀀스 연도, 월 및 일을 생성합니다. 또는 지역 설정을 사용하려면 값이 -1 일 수 있습니다. 321과 같은 숫자가 0에서 250까지의 열거형 값에 유효한 값 범위를 초과하므로 이 매개 변수에는 열거형 형식을 사용하지 않아야 합니다. flags 매개 변수의 기본값은 DateFlags::None 열거형 값입니다. 즉, 왼쪽에서 오른쪽 또는 오른쪽에서 왼쪽으로 시퀀스 처리가 수행되지 않습니다.

Example

다음 예제에서는 현재 날짜를 연도, 월 및 일 순서로 표시합니다.

static void Job2(Args _args)
{
    date currentDate = today();
    str s;
    int iEnum;
    s = date2Str
    (currentDate, 
        321,
        DateDay::Digits2,
        DateSeparator::Hyphen, // separator1
        DateMonth::Digits2,
        DateSeparator::Hyphen, // separator2
        DateYear::Digits4
    );
    info("Today is:  " + s);
}
/** Example Infolog output
Message (12:36:21 pm)
Today is:  2009-01-13
**/

datetime2Str

utcdatetime 값을 문자열로 변환합니다.

str datetime2Str(utcdatetime datetime [, int flags = DateFlags::None])

매개 변수

반환 값

datetime 매개 변수로 지정된 utcdatetime 값을 나타내는 문자열입니다.

비고

Null 날짜-시간 입력

datetime 매개 변수에 대해 최소 utcdatetime 값을 지정하면 datetime2Str 함수는 이를 null 입력 값으로 처리합니다. 이렇게 하면 함수가 빈 문자열을 반환합니다. DateTimeUtil::minValue 메서드에 의해 날짜-시간 1900-01-01T00:00:00이 반환됩니다. 이 최소값은 null로 처리됩니다.

오른쪽에서 왼쪽으로 로컬 설정

이 함수의 기본 동작은 왼쪽에서 오른쪽 시퀀스로 문자열을 생성하는 것입니다. 여기서 연도 부분은 맨 왼쪽에 있습니다. 그러나 DateFlags::FormatAll 열거형 값의 플래그 매개 변수 값은 로컬 설정이 오른쪽에서 왼쪽으로 구성된 경우 함수가 오른쪽에서 왼쪽으로 시퀀스로 문자열을 생성하도록 지시합니다. DateTimeUtil 클래스의 toStr 메서드 형식은 지역 설정의 영향을 받지 않습니다.

Example

static void jobTestDatetime2str( Args _args )
{
    utcdatetime utc2 = 1959-06-17T15:44:33;
    str s3;
    s3 = datetime2Str( utc2 );
    info( s3 );
}

enum2Str

지정된 열거형 텍스트를 문자 표현으로 변환합니다.

str enum2Str(enum enum)

매개 변수

반환 값

문자열로 열거형의 값입니다.

Example

다음 예제에서는 "포함되지 않음" 문자열을 반환합니다. ListCode 열거형 형식의 IncludeNot 값에 대한 레이블입니다.

static void enum2StrExample(Args _arg)
{
    ListCode l;
    l =  ListCode::IncludeNot;
    print enum2Str(l);
}

guid2Str

지정된 GUID 개체를 해당하는 문자열로 변환합니다.

str guid2String(guid _uuid)

매개 변수

반환 값

지정된 GUID 개체에 해당하는 문자열입니다.

Example

static void guid2StrExample()
{
    guid _guid;
    str stringGuid;
    _guid = Global::guidFromString("{12345678-1234-1234-1234-123456789abc}");
    print strfmt("GUID is %1", _guid);
    stringGuid = guid2str(_guid);
    info("String GUID is " + stringGuid);
}
/**** Output to Infolog
String GUID is {12345678-1234-1234-1234-123456789ABC}
****/

int2Str

정수는 해당하는 문자열로 변환합니다.

str int2Str(int integer)

매개 변수

반환 값

정수의 문자열 표현입니다.

Example

static void int2StrExample(Args _arg)
{
    print "This is int2Str, value is " + int2Str(intMax());
    print "This is int642Str, value is " + int642Str(int64Max());
}

int642Str

지정된 정 수 매개 변수 를 해당하는 텍스트 문자열로 변환합니다.

str int642Str(int64 integer)

매개 변수

반환 값

정수 매개 변수의 해당 텍스트 문자열입니다.

Example

static void example()
{
    print "This is int2Str, value is " + int2Str(intMax());
    print "This is int642Str, value is " + int642Str(int64Max());
}

num2Char

정수는 해당 ASCII 문자로 변환합니다.

str num2Char(int figure)

매개 변수

반환 값

지정된 정수로 표현되는 문자입니다.

Example

static void num2CharExample(Args _arg)
{
    str s;
    s = num2Char(42);
    // Prints an asterisk * -the character represented by 42.
    print s;
}

num2Date

1900년 1월 1일 이후의 지정된 일 수에 해당하는 날짜를 검색합니다.

date num2Date(int _days)

매개 변수

반환 값

1900년 1월 1일 이후 _days 매개 변수에 지정된 일 수입니다.

비고

num2Date(366); //Returns the date 01/01/1901 (1 January 1901).

num2Str

실제 숫자를 문자열로 변환합니다.

str num2Str(real number, int character, int decimals, int separator1, int separator2)

매개 변수

반환 값

숫자를 나타내는 문자열입니다.

비고

decimals 매개 변수의 경우 최대값은 16입니다. 더 큰 숫자를 사용하는 경우 이 메서드는 대신 로컬 컴퓨터에서 decimals 매개 변수의 값을 가져옵니다. 두 경우 모두 반올림이 발생합니다. separator1 매개 변수에 대한 가능한 열거형 값은 다음과 같습니다.

• 99 – 자동(사용자의 서식 설정에 따라 사용되는 소수 구분 기호 결정), 열거형 값 DecimalSeparator::Auto
• 1 – 점(.), 열거형 값 DecimalSeparator::D ot
• 2 – 쉼표(,), 열거형 값 DecimalSeparator::Comma

separator2 매개 변수에 사용할 수 있는 값은 다음과 같습니다.

• 99 – 자동(사용자의 서식 설정에 따라 사용되는 천 단위 구분 기호가 결정됨)
• 0 – 없음(천 단위 구분 기호 없음), 열거형 값 ThousandSeparator::None
• 1 – 점(.), 열거형 값 ThousandSeparator::D ot
• 2 – 쉼표(,), 열거형 값 ThousandSeparator::Comma
• 3 – 아포스트로피('), 열거형 값 ThousandSeparator::Apostrophe
• 4 – Space (), 열거형 값 ThousandSeparator::Space

Example

다음 코드 예제에서 num2str 메서드에 대한 첫 번째 호출은 decimals 매개 변수에 대해 16을 제공하고 두 번째 호출은 17을 제공합니다.

static void Job_Num2Str(Args _args)
{
    real realNum = 0.1294567890123456777; // 19 decimals places.
    info(Num2Str(realNum, 0, 16, DecimalSeparator::Dot, ThousandSeparator::Space)); // 16 decimal places
    info(Num2Str(realNum, 0, 17, DecimalSeparator::Dot, ThousandSeparator::Space)); // 17 decimal places
}

출력

메시지는 다음 Infolog 출력에 있습니다. 출력의 첫 번째 숫자는 16개의 소수 자릿수를 포함하는 반면, 두 번째 숫자는 소수 자릿수 두 자리만 포함합니다.

Message (10:18:12)
0.1294567890123457
0.13

str2Date

지정된 문자열을 날짜 값으로 변환합니다.

date str2Date(str _text, str _sequence)

매개 변수

반환 값

날짜 값입니다.

비고

다음 값을 사용하여 _sequence 매개 변수에서 일, 월 및 연도의 위치를 지정합니다.

• 일: 1
• 월: 2
• 연도: 3

예를 들어 문자열의 시퀀스가 월, 연도 및 일인 경우 _sequence 매개 변수는 231이어야 합니다. 입력 매개 변수가 잘못된 날짜를 지정하면 0 날짜가 반환됩니다. 다음 두 예제에서는 잘못된 날짜를 지정합니다.

str2Date("31/12/44", 123) // Year must be four digits to reach the minimum of January 1 1901.
str2Date("31/12/2044", 213) // 213 means the month occurs first in the string, but 31 cannot be a month.

Example

static void str2DateExample(Args _arg)
{
    date d;
    d = str2Date("22/11/2007", 123);
    print d;
}

str2Datetime

지정된 날짜 및 시간 정보 문자열에서 utcdatetime 값을 생성합니다.

utcdatetime str2datetime( str text, int sequence )

매개 변수

반환 값

지정된 날짜 및 시간을 나타내는 utcdatetime 값입니다.

비고

텍스트 매개 변수의 날짜 부분에 대한 구문 요구 사항은 유연합니다. 유효한 형식의 다양성은 date2str 함수와 동일합니다. str2datetime에 대한 다음 각 호출은 유효하며 모두 동일한 출력을 생성합니다.

utc3 = str2datetime( "1985/02/25 23:04:59" ,321 );
utc3 = str2datetime( "Feb-1985-25 11:04:59 pm" ,231 );
utc3 = str2datetime( "2 25 1985 11:04:59 pm" ,123 );

날짜 시간의 각 구성 요소는 시퀀스 매개 변수의 숫자로 표시됩니다.

• 1 - 일
• 2 - 월
• 3 – 연도

예를 들어 연도, 월, 일 순서는 321입니다. 모든 유효한 값에는 이러한 세 자리가 정확히 한 번 포함됩니다. 시퀀스 매개 변수의 값이 유효하지 않은 경우 지역 설정은 입력 텍스트 매개 변수를 해석하는 데 사용됩니다. 입력 매개 변수가 잘못된 날짜 및 시간을 설명하는 경우 빈 문자열이 반환됩니다.

Example

static void JobTestStr2datetime( Args _args )
{
    utcdatetime utc3;
    str sTemp;
    utc3 = str2datetime( "1985/02/25 23:04:59" ,321 );
    sTemp = datetime2str( utc3 );
    print( "sTemp == " + sTemp );
}

str2Enum

지역화된 Label 속성 값이 입력 문자열과 일치하는 열거형 요소를 검색합니다.

enum str2Enum(enum _type, str _text)

매개 변수

반환 값

int도 나타내는 대상 열거형의 요소입니다.

비고

관련 함수 enum2str 는 열거형의 한 요소에서 Label 속성의 값을 반환합니다. enum2str 함수에서 반환되는 값은 str2enum 함수의 _type 매개 변수에 대한 입력일 수 있습니다. _text 매개 변수에 대한 적절한 값은 enum2Str(BankAccountType::SavingsAccount)입니다. 열거형의 각 요소에는 Name 속성과 Label 속성이 있습니다. 새로 설치할 때 Name 값은 거의 항상 영어 단어입니다. 영어 버전에서 Label 속성 값은 거의 항상 Name 값과 동일합니다. 그러나 영어가 아닌 버전에서는 레이블 값이 지역화되므로 Name 값과 일치하지 않습니다.

Example

다른 음성 언어로의 지역화로 인한 문자열 불일치를 방지하려면 enum2str 함수를 사용하여 str2enum 함수에 입력을 생성하는 것이 좋습니다. 다음 예제에서는 enum2str 함수와 함께 str2enum 함수를 사용하는 적절한 방법을 보여 줍니다.

static void str2Enum_AcrossLangs(Args _arg)
{
    BankAccountType bat;
    str sEnumValueLabelLocalized;
    int nInt;
    // enum2str.
    sEnumValueLabelLocalized = enum2str(BankAccountType::SavingsAccount);
    info("Localized friendly string: "
        + sEnumValueLabelLocalized);
    // str2enum.
    bat = str2Enum(bat, sEnumValueLabelLocalized);
    nInt = bat;
    info("nInt = " + int2str(nInt));
    /********** Actual output:
    Message (04:32:12 pm)
    Localized friendly string: Savings account
    nInt = 1
    **********/
}

str2Guid

문자열을 GUID 개체로 변환합니다.

Guid str2Guid(str text)

매개 변수

반환 값

입력 문자열로 표현되는 GUID입니다.

비고

예를 들어 guid 매개 변수에 유효한 값은 {12345678-1234-abCD-3456-123456789012}(중괄호 포함 또는 제외)입니다.

str2Int

문자열을 해당하는 정수로 변환합니다.

int str2Int(str _text)

매개 변수

반환 값

지정된 문자열에 해당하는 정수입니다.

Example

static void str2IntExample(Args _arg)
{
    int i;
    i = str2Int("1234567890");
    print "i = " + int2Str(i);
}

str2Int64

문자열을 Int64 값으로 변환합니다.

int str2Int64(str text)

매개 변수

반환 값

지정된 문자열의 Int64 값입니다.

Example

static void str2Int64Example(Args _args)
{
    str myStr;
    str tooBig;
    Int64 myInt64;
    myStr = "1234567890";
    tooBig = int642str(int64Max()+1);
    myInt64 = str2Int64(mystr);
    print strfmt ("int64: %1",myInt64);
    myInt64 = str2Int64(tooBig);
    print strfmt ("Too big int64: %1",myInt64);
}

str2Num

문자열을 실수로 변환합니다.

real str2Num(str _text)

매개 변수

반환 값

지정된 문자열에 유효한 숫자가 포함된 경우의 실수입니다. 그렇지 않으면 0 입니다.

비고

다음 예제에서는 이 함수를 사용하는 방법을 보여 줍니다.

str2Num("123.45") returns the value 123.45.
str2Num("a123") returns the value 0.0.
str2Num("123a") returns the value 123.00.

스캔은 왼쪽에서 오른쪽으로 발생하며 문자를 실수의 일부로 변환할 수 없을 때 끝납니다.

Example

static void str2NumToReal(Args _arg)
{
    real r;
    str s;
    r = str2Num("3.15");
    s = strFmt("r = %1", r);
    info(s);
}
/*** Infolog output.
Message_@SYS14327 (02:36:12 pm)
r = 3.15
***/

static void str2NumExponentialSyntax(Args _args)
{
    Qty qty1, qty2, qty3;
    qty1 = str2num('1e-3'); // Bad syntax by the user.
    qty2 = str2num('1.e-3');
    qty3 = str2num('1.0e-3');
    info(strfmt('Result: %1; Expected: %2', num2str(qty1, 0,3,2,0), '0.001'));
    info(strfmt('Result: %1; Expected: %2', num2str(qty2, 0,3,2,0), '0.001'));
    info(strfmt('Result: %1; Expected: %2', num2str(qty3, 0,3,2,0), '0.001'));
}
/*** Infolog output. The first result differs from expectations.
Message_@SYS14327 (02:20:55 pm)
Result: 1,000; Expected: 0.001
Result: 0,001; Expected: 0.001
Result: 0,001; Expected: 0.001
***/

str2Time

문자열을 timeOfDay 값으로 변환합니다.

int str2Time(str _text)

매개 변수

반환 값

자정과 _text 매개 변수 사이의 시간(초)입니다. 그렇지 않으면 -1입니다.

비고

str2Time("05:01:37") //Returns the value 18097.
str2Time("7 o'clock") //Returns the value -1.

Example

static void str2TimeExample(Args _arg)
{
    int i;
    i = str2Time("11:30");
    print i;
}

time2Str

timeOfDay 값을 시간, 분 및 초를 포함하는 문자열로 변환합니다.

str time2Str(int _time, int _separator, int _timeFormat)

매개 변수

반환 값

지정된 시간을 나타내는 문자열입니다.

비고

_time 매개 변수의 값은 자정 이후의 시간(초)입니다.

Example

static void TimeJob4(Args _args)
{
    timeOfDay theTime = timeNow();
    info( time2Str(theTime, TimeSeparator::Colon, TimeFormat::AMPM) );
}
/**
Message (04:33:56 pm)
04:33:56 pm
**/

uint2Str

정수를 문자열로 변환합니다. 정수가 부호 없는 것으로 가정합니다.

str uint2Str(int integer)

매개 변수

반환 값

지정된 부호 없는 정수에 해당하는 문자열입니다.

비고

레코드 ID와 같은 매우 큰 정수에 int2str 함수 대신 이 함수를 사용합니다.

info(int2str(3123456789)); //returns -1171510507 as a string.
info(uint2str(3123456789)); //returns 3123456789 as a string.