Applies to: ✅Microsoft Fabric✅Azure Data Explorer
꺾은선형 차트 시각적 개체는 가장 기본적인 차트 유형입니다. 쿼리의 첫 번째 열은 숫자여야 하며 x축으로 사용됩니다. 다른 숫자 열은 y축입니다. 꺾은선형 차트는 장단기 변경 내용을 추적합니다. 더 작은 변경 사항이 있을 경우 가로 막대형 그래프보다 꺾은선형 그래프가 더 유용합니다.
Note
This visualization can only be used in the context of the render operator.
Syntax
T|renderlinechart [with(propertyName=propertyValue [, ...] )]
Learn more about syntax conventions.
Parameters
| Name | Type | Required | Description |
|---|---|---|---|
| T | string |
✔️ | 입력 테이블 이름입니다. |
| propertyName, propertyValue | string |
키-값 속성 쌍의 쉼표로 구분된 목록입니다. See supported properties. |
Supported properties
모든 속성은 선택 사항입니다.
| PropertyName | PropertyValue |
|---|---|
accumulate |
각 측정값의 값이 모든 선행 작업(true 또는 false)에 추가되는지 여부입니다. |
legend |
범례 표시 여부(visible 또는 hidden)입니다. |
series |
레코드가 속한 계열을 정의하는 결합된 레코드당 값이 있는 열의 쉼표로 구분된 목록입니다. |
ymin |
Y축에 표시할 최소값입니다. |
ymax |
Y축에 표시할 최대값입니다. |
title |
시각화의 제목(형식 string)입니다. |
xaxis |
x축의 크기를 조정하는 방법입니다(linear 또는 log). |
xcolumn |
x축에 사용되는 결과의 열입니다. |
xtitle |
x축의 제목입니다(string 형식). |
yaxis |
y축의 크기를 조정하는 방법입니다(linear 또는 log). |
ycolumns |
x 열 값당 제공된 값으로 구성된 쉼표로 구분된 열 목록입니다. |
ysplit |
시각화를 여러 y축 값으로 분할하는 방법입니다. 자세한 내용은 속성을 참조 ysplit 하세요. |
ytitle |
y축의 제목입니다(string 형식). |
ysplit 속성
이 시각화는 여러 y축 값으로 분할을 지원합니다.
ysplit |
Description |
|---|---|
none |
모든 계열 데이터에 대해 단일 y축이 표시됩니다. (Default) |
axes |
단일 차트가 여러 y축으로 표시됩니다(계열당 하나씩). |
panels |
각 ycolumn 값에 대해 하나의 차트가 렌더링됩니다. 최대 5개의 패널. |
Examples
이 섹션의 예제에서는 구문을 사용하여 시작하는 방법을 보여 주었습니다.
The examples in this article use publicly available tables in the help cluster, such as the
StormEventstable in the Samples database.
The examples in this article use publicly available tables, such as the
Weathertable in the Weather analytics sample gallery. 작업 영역의 테이블과 일치하도록 예제 쿼리에서 테이블 이름을 수정해야 할 수 있습니다.
꺾은선형 차트 렌더링
이 쿼리는 버지니아에서 폭풍 이벤트를 검색하여 시작 시간 및 속성 손상에 초점을 맞춘 다음 이 정보를 꺾은선형 차트에 표시합니다.
StormEvents
| where State=="VIRGINIA"
| project StartTime, DamageProperty
| render linechart
꺾은선형 차트에 레이블 지정
이 쿼리는 버지니아에서 Storm 이벤트를 검색하여 시작 시간 및 속성 손상에 초점을 맞춘 다음 이 정보를 선형 차트에 표시하여 선명도와 프레젠테이션을 개선합니다.
StormEvents
| where State=="VIRGINIA"
| project StartTime, DamageProperty
| render linechart
with (
title="Property damage from storms in Virginia",
xtitle="Start time of storm",
ytitle="Property damage"
)
y축에 표시되는 값 제한
이 쿼리는 버지니아의 Storm 이벤트를 검색하여 시작 시간 및 속성 손상에 초점을 맞춘 다음, 데이터 시각화를 향상하기 위해 지정된 y축 제한이 있는 꺾은선형 차트에 이 정보를 표시합니다.
StormEvents
| where State=="VIRGINIA"
| project StartTime, DamageProperty
| render linechart with (ymin=7000, ymax=300000)
여러 y축 보기
이 쿼리는 텍사스, 네브래스카 및 캔자스에서 우박 이벤트를 검색합니다. 각 상태에 대한 일별 우박 이벤트 수를 계산한 다음 각 상태에 대해 별도의 패널이 있는 꺾은선형 차트에 이 정보를 표시합니다.
StormEvents
| where State in ("TEXAS", "NEBRASKA", "KANSAS") and EventType == "Hail"
| summarize count() by State, bin(StartTime, 1d)
| render linechart with (ysplit=panels)
