동적 값

동적 은 복잡하거나 간단한 데이터 구조를 보유할 수 있는 Power Fx의 데이터 형식입니다. 명시적으로 또는 암시적으로 런타임에 직접 사용하고 다른 데이터 형식으로 변환할 수 없습니다. 동적 값의 레코드 필드는 점 표기법을 사용하여 액세스할 수 있으며, 필드의 존재는 런타임에만 확인됩니다.

동적 값을 만드는 방법에는 두 가지가 있습니다.

• ParseJSON 함수 사용
• "동적" 형식을 반환하는 커넥터를 사용합니다.

간단한 형식

동적 값을 포함하는 변수의 값은 직접 사용할 수 없습니다. 항상 해당 형식 생성자를 사용하거나 AsType 및 ParseJSON 함수를 사용하여 특정 형식으로 변환하여 올바르게 입력해야 합니다.

다음 예제에서는 이름이 DynValue 변수의 값을 변환합니다.

Text(DynValue)

Value(DynValue)

다음 표에서는 Dynamic 을 해당 데이터 형식으로 변환하는 데이터 형식 및 해당 함수를 나열합니다.

레코드 종류

레코드에 사용되는 일반 점 표기법을 사용하여 동적 레코드를 나타내는 변수의 필드에 액세스할 수 있습니다. 그러나 필드의 존재는 런타임까지 확인되지 않습니다. 결과적으로 IntelliSense도 사용할 수 없습니다. 필드가 존재하지 않거나 기본 null 값이 있는 경우 해당 필드에 액세스하면 Blank() 값이 생성됩니다.

레코드의 각 필드는 동적 형식이기도 하며 올바르게 입력해야 합니다. 필드는 단순 형식의 동적 레코드일 수 있습니다. 레코드인 경우 점 표기법을 연결할 수 있습니다. 체인에 필드가 없으면 Blank()가 반환됩니다.

다음 예제에서는 이름이 DynRecord 변수의 필드를 사용합니다.

Text(DynRecord.StringField)

Value(DynRecord.Field.ChildField)

필드 이름이 잘못된 식별자 이름으로 구성된 경우(예: 필드 이름이 숫자로 시작하거나 하이픈과 같은 잘못된 문자가 포함된 경우) 필드 이름을 작은 따옴표로 묶을 수 있습니다.

dynamic.'01'
dynamic.'my-field'

동적 컬럼 액세스

경우에 따라 레코드의 열 이름이 동적일 수 있습니다. ColumnNames 함수를 사용하여 레코드에서 사용할 수 있는 열 이름을 확인한 다음 Column 함수를 사용하여 명명된 열의 값을 검색합니다.

예를 들어

LettersUsed = ParseJSON( "{ ""d"": 2, ""p"": 3 }" );

Concat( ColumnNames( LettersUsed ) As Names, Names.Value, ", " )
// returns "d, p"

Sum( ForAll( ColumnNames( LettersUsed ) As Names, Column( LettersUsed, Names.Value ) ), Value )
// returns 5

배열

동적 변수는 배열을 포함할 수 있습니다. 배열이 레코드 배열이거나 단순 형식의 배열일 수 있지만 Table() 함수를 사용하여 동적 배열을 테이블로 변환하면 항상 단일 열 테이블인 Dynamic이 생성됩니다. ForAll() 및 Index()와 같은 함수는 먼저 Table()을 만들 필요가 없으므로 단일 열 Value 필드를 사용할 필요가 없습니다.

예를 들어 숫자 값() 을 포함하는 [1, 2, 3] 배열에서 두 번째 숫자를 가져오기 위해 다음 수식을 사용하여 표의 두 번째 행을 검색하고 열을 숫자로 변환할 수 있습니다.

Value( Index( UOArray, 2 ) )

Dynamic이 Table()으로 먼저 변환된 경우 결과 단일 열 테이블의 두 번째 행은 Value을 포함하는 열입니다.

Value( Index( Table( UOArray ), 2 ).Value )

Field라는 텍스트 열이 있는 레코드 배열의 경우 동일한 논리가 적용됩니다. Dynamic에 직접 액세스할 수 있거나 Table() 함수를 사용하면 단일 열 테이블인 Dynamic이 생성됩니다.

열은 FieldIndex() 함수에서 반환된 동적에서 직접 액세스할 수 있습니다.

Text( Index( UORecordArray, 2 ).Field )

Table() 함수를 사용하는 경우 먼저 단일 열 Value 열을 검색하여 Dynamic을 구한 다음 열에 액세스합니다Field.

Text( Index( Table( UORecordArray ), 2 ).Value.Field )

레코드 배열을 유형이 지정된 테이블로 변환하려면 ForAll() 함수를 사용하고 각 개별 필드를 변환할 수 있습니다.

ForAll( UORecordArray, { FirstField: Value(ThisRecord.FirstField), SecondField: Text(ThisRecord.SecondField) } )

Dynamic이 먼저 테이블로 변환되는 경우 다시 동적의 결과 단일 열 테이블을 사용하려면 열을 사용하여 Value 필드를 가져와야 합니다.

ForAll( Table(UORecordArray), { FirstField: Value(ThisRecord.Value.FirstField), SecondField: Text(ThisRecord.Value.SecondField) } )

형식화된 레코드 및 테이블로 변환

각 단순 값을 개별적으로 변환하는 대신 ParseJSON, IsType 및 AsType 함수를 사용하여 Dynamic 을 형식화된 개체로 대량 변환할 수 있습니다. Type 함수를 사용하여 동적 구조를 형식화된 구조체에 매핑하는 형식을 만듭니다.

예를 들어, 여기서는 DateTimeValue 함수를 호출하지 않고도 JSON 문자열을 날짜 시간 값으로 해석합니다.

Eclipse = ParseJSON( "{ ""Start"": ""2026-08-12T18:26:00.000Z"", ""End"": ""2026-08-12T18:33:00.000Z"" }",
                     Type( { Start: DateTime, End: DateTime } ) );

DateDiff( Eclipse.Start, Eclipse.End, TimeUnit.Minutes )
// 7