List.PositionOf

구문

List.PositionOf(
    list as list,
    value as any,
    optional occurrence as nullable number,
    optional equationCriteria as any
) as any

소개

지정된 값이 목록에 표시되는 오프셋을 반환합니다. 값이 나타나지 않으면 -1을 반환합니다.

• list: 검색할 목록입니다.
• value: 목록에서 찾을 값입니다.
• occurrence: (선택 사항) 보고할 특정 항목입니다. 이 값은 Occurrence.First, Occurrence.Last 또는 Occurrence.All일 수 있습니다. occurrence를 지정하지 않으면 Occurrence.First가 사용됩니다.
• equationCriteria: (선택 사항) 값을 비교할 때 같음이 결정되는 방법을 지정합니다. 이 매개 변수는 키 선택기 함수, 비교자 함수 또는 키 선택기와 비교자를 모두 포함하는 목록일 수 있습니다.

예 1

값 3이 표시되는 {1, 2, 3} 목록에서 위치를 찾습니다.

사용법

List.PositionOf({1, 2, 3}, 3)

출력

2

예제 2

2022년 날짜의 모든 인스턴스 목록에서 위치를 찾습니다.

사용법

let
    Source = {
        #date(2021, 5, 10),
        #date(2022, 6, 28),
        #date(2023, 7, 15),
        #date(2022, 12, 31),
        #date(2022, 4, 8),
        #date(2024, 3, 20)
    },
    YearList = List.Transform(Source, each Date.Year(_)),
    TargetYear = 2022,
    FindPositions = List.PositionOf(YearList, TargetYear, Occurrence.All)
in
    FindPositions

출력

{1, 3, 4}

예제 3

대/소문자를 무시하고 개라는 단어가 마지막으로 나타나는 목록에서 위치를 찾습니다.

사용법

let
    Source = List.PositionOf(
        {"dog", "cat", "DOG", "pony", "bat", "rabbit", "dOG"}, 
        "dog", 
        Occurrence.Last, 
        Comparer.OrdinalIgnoreCase
    )
in
    Source

출력

6

예제 4

목록에서 숫자 28의 두 단위 내에 있는 위치를 찾습니다.

사용법

let
    Source = { 10, 15, 20, 25, 30 },
    Position = List.PositionOf(
        Source, 
        28,
        Occurrence.First, 
        (x, y) => Number.Abs(x - y) <= 2
    )
in
    Position

출력

4

관련 콘텐츠

수식 조건