List.PositionOfAny

구문

List.PositionOfAny(
    list as list,
    values as list,
    optional occurrence as nullable number,
    optional equationCriteria as any
) as any

정보

지정한 값 목록의 항목이 목록에 표시되는 오프셋을 반환합니다. 발생이 없으면 -1을 반환합니다.

• list: 검색할 목록입니다.
• values: 원래 목록에서 찾을 값 목록입니다.
• occurrence: (선택 사항) 보고할 특정 항목입니다. 이 값은 Occurrence.First, Occurrence.Last 또는 Occurrence.All일 수 있습니다. 지정된 occurrence가 없으면, Occurrence.First가 사용됩니다.
• equationCriteria: (선택 사항) 값을 비교할 때 같음이 결정되는 방법을 지정합니다. 이 매개 변수는 키 선택기 함수, 비교자 함수 또는 키 선택기와 비교자를 모두 포함하는 목록일 수 있습니다.

예 1

{1, 2, 3} 목록에서 값 2 또는 3이 표시되는 첫 번째 위치를 찾습니다.

사용법

List.PositionOfAny({1, 2, 3}, {2, 3})

출력

1

예제 2

2022년 또는 2023년 날짜의 모든 인스턴스 목록에서 위치를 찾습니다.

사용법

let
    Source = {
        #date(2021, 5, 10),
        #date(2022, 6, 28),
        #date(2023, 7, 15),
        #date(2025, 12, 31),
        #date(2022, 4, 8),
        #date(2024, 3, 20)
    },
    YearList = List.Transform(Source, each Date.Year(_)),
    TargetYear = {2022, 2023},
    FindPositions = List.PositionOfAny(YearList, TargetYear, Occurrence.All)
in
    FindPositions

출력

{1, 2, 4}

예제 3

대소문자를 구분하지 않고 개의 또는 고양이의 단어가 목록에서 마지막으로 나타나는 위치를 찾습니다.

사용법

let
    Source = List.PositionOfAny(
        {"dog", "cat", "DOG", "pony", "bat", "rabbit", "dOG"}, 
        {"dog", "cat"}, 
        Occurrence.Last, 
        Comparer.OrdinalIgnoreCase
    )
in
    Source

출력

6

예제 4

목록에서 숫자 17 또는 28의 두 단위 내에 있는 위치를 찾습니다.

사용법

let
    Source = { 10, 15, 20, 25, 30 },
    Position = List.PositionOfAny(
        Source, 
        {17, 28},
        Occurrence.All, 
        (x, y) => Number.Abs(x - y) <= 2
    )
in
    Position

출력

{1, 4}

관련 콘텐츠

수식 조건