다음을 통해 공유

WMI 작업: 예약된 작업

WMI 예약된 태스크는 예약된 작업에 대한 정보를 만들고 가져옵니다. 다른 예제는 https://www.microsoft.com/technetTechNet ScriptCenter를 참조하세요.

이 항목에 표시된 스크립트 예제는 로컬 컴퓨터에서만 데이터를 가져옵니다. 스크립트를 사용하여 원격 컴퓨터에서 데이터를 가져오는 방법에 대한 자세한 내용은 원격 컴퓨터 WMI에 연결하는참조하세요.

다음 절차에서는 스크립트를 실행하는 방법을 설명합니다.

스크립트 실행하려면

  1. 코드를 복사하고 .vbs 확장명(예: filename.vbs파일에 저장합니다. 텍스트 편집기가 파일에 .txt 확장자를 추가하지 않는지 확인합니다.
  2. 명령 프롬프트 창을 열고 파일을 저장한 디렉터리로 이동합니다.
  3. 명령 프롬프트에서 cscript filename.vbs 입력합니다.
  4. 이벤트 로그에 액세스할 수 없는 경우 관리자 권한 명령 프롬프트에서 실행 중인지 확인합니다. 보안 이벤트 로그와 같은 일부 이벤트 로그는 UAC(사용자 액세스 제어)로 보호될 수 있습니다.

메모

기본적으로 cscript는 명령 프롬프트 창에 스크립트의 출력을 표시합니다. WMI 스크립트는 많은 양의 출력을 생성할 수 있으므로 출력을 파일로 리디렉션할 수 있습니다. 명령 프롬프트에서 cscript filename.vbs > outfile.txt 입력하여 filename.vbs 스크립트의 출력을 outfile.txt리디렉션합니다.

다음 표에서는 로컬 컴퓨터에서 다양한 형식의 데이터를 가져오는 데 사용할 수 있는 스크립트 예제를 나열합니다.

어떻게 해야 하나요? WMI 클래스 또는 메서드
... 스크립트를 사용하여 예약된 작업을 만들 수 있나요? Win32_ScheduledJob 클래스와 Create 메서드를 사용합니다. Windows 7 이상에서 이 작업을 수행하는 데 어려움이 있는 경우 Win32_ScheduledJob 설명 섹션을 참조하세요. 설정으로 인해 클래스를 사용할 수 없게 될 수 있습니다.
VB 
strComputer = "."
Set objWMIService = GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2") 
JobID = "Test"
Set objNewJob = objWMIService.Get("Win32_ScheduledJob")
errJobCreate = objNewJob.Create _
    ("Notepad.exe", "********143000.000000-420", True , 1 OR 4 OR 16, ,True, JobId) 
If errJobCreate = 0 Then
    WScript.Echo "Job created successfully: " & VBNewLine _
        & "Notepad.exe scheduled to run repeately at 14.30 (2:30 P.M.) PST" & VBNewLine _
        & "on Mon, Wed, and Fri."
Else
    WScript.Echo "Job not created. Error code = " & errJobCreate
End If

"********143000.000000-420" 문자열(Create 메서드의 StartTime 매개 변수 값에 사용됨) "********143000.000000"은 작업이 14.30(오후 2시 30분)에 시작되고 "-420"이 표준 시간대를 지정합니다. 표준 시간대 번호는 현지 시간 변환의 현재 바이어스입니다. 바이어스는 UTC 시간과 현지 시간의 차이입니다. 표준 시간대에 대한 바이어스 값을 계산하려면 표준 시간대가 GMT(그리니치 표준시)보다 앞 또는 뒤에 있는 시간 수를 60으로 곱합니다(표준 시간대가 GMT보다 앞선 경우 시간 수에 양수, 표준 시간대가 GMT 뒤에 있는 경우 음수 사용). 표준 시간대에서 일광 절약 시간을 사용하는 경우 계산에 60을 더 추가합니다. 예를 들어 태평양 표준 시간대는 GMT에 8시간 뒤이므로 일광 절약 시간이 사용 중일 때는 -420(-8 * 60 + 60)와 같으며 일광 절약 시간을 사용하지 않는 경우 -480(-8 * 60)입니다. Win32_TimeZone 클래스의 바이어스 속성을 쿼리하여 바이어스의 값을 확인할 수도 있습니다.
... 컴퓨터의 모든 예약된 작업 목록을 반환하시겠습니까?

Win32_ScheduledJob 클래스를 사용합니다. 이 클래스는 스크립트 또는 AT.exe사용하여 만든 작업만 반환할 수 있습니다. 예약된 작업 마법사에서 만들거나 수정한 작업에 대한 정보는 반환할 수 없습니다.

VB 
strComputer = "."
strComputer = "."
Set objWMIService = GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set colScheduledJobs = objWMIService.ExecQuery ("Select * from Win32_ScheduledJob")
For Each objJob in colScheduledJobs
    Wscript.Echo "Command: " & objJob.Command & VBNewLine _
    & "Days Of Month: " & objJob.DaysOfMonth & VBNewLine _
    & "Days Of Week: " & objJob.DaysOfWeek & VBNewLine _
    & "Description: " & objJob.Description & VBNewLine _
    & "Elapsed Time: " & objJob.ElapsedTime & VBNewLine _
    & "Install Date: " & objJob.InstallDate & VBNewLine _
    & "Interact with Desktop: " & objJob.InteractWithDesktop & VBNewLine _
    & "Job ID: " & objJob.JobId & VBNewLine _
    & "Job Status: " & objJob.JobStatus & VBNewLine _
    & "Name: " & objJob.Name & VBNewLine _
    & "Notify: " & objJob.Notify & VBNewLine _
    & "Owner: " & objJob.Owner & VBNewLine _
    & "Priority: " & objJob.Priority & VBNewLine _
    & "Run Repeatedly: " & objJob.RunRepeatedly & VBNewLine _
    & "Start Time: " & objJob.StartTime & VBNewLine _
    & "Status: " & objJob.Status & VBNewLine _
    & "Time Submitted: " & objJob.TimeSubmitted & VBNewLine _
    & "Until Time: " & objJob.UntilTime
Next

스크립트 및 애플리케이션 대한 WMI 작업

WMI C++ 애플리케이션 예제

TechNet ScriptCenter

  • Last updated on