Quickstart: Direct webverkeer met Azure Application Gateway - Terraform

In deze quickstart gebruikt u Terraform om een Azure-toepassingsgateway te maken. Vervolgens test je de applicatiegateway om er zeker van te zijn dat deze correct werkt. De Standard v2-SKU wordt in dit voorbeeld gebruikt.

Terraform maakt de definitie, preview en implementatie van de cloudinfrastructuur mogelijk. Met Terraform maakt u configuratiebestanden met behulp van HCL-syntaxis. Met de HCL-syntaxis kunt u de cloudprovider opgeven, zoals Azure, en de elementen waaruit uw cloudinfrastructuur bestaat. Nadat u uw configuratiebestanden hebt gemaakt, maakt u een uitvoeringsplan waarmee u een voorbeeld van uw infrastructuurwijzigingen kunt bekijken voordat ze worden geïmplementeerd. Zodra u de wijzigingen hebt gecontroleerd, past u het uitvoeringsplan toe om de infrastructuur te implementeren.

Vereiste voorwaarden

• Terraform installeren en configureren

De Terraform-code implementeren

1. Maak een map aan om de voorbeeldcode van Terraform te testen en stel deze in als de huidige map.

2. Maak een bestand met de naam providers.tf en voeg de volgende code in:

   terraform {
     required_version = ">=1.2"
     
     required_providers {
       azurerm = {
         source  = "hashicorp/azurerm"
         version = "~> 3.0"
       }
       random = {
         source = "hashicorp/random"
         version = "~> 3.0"
       }
     }
   }
   
   provider "azurerm" {
     features {}
   }
   

3. Maak een bestand met de naam main.tf en voeg de volgende code in:

   resource "random_string" "rg" {
     length  = 8
     upper   = false
     special = false
   }
   
   resource "azurerm_resource_group" "rg" {
     name     = "101-application-gateway-${random_string.rg.result}"
     location = "eastus"
   }
   
   resource "azurerm_virtual_network" "vnet" {
     name                = "myVNet"
     resource_group_name = azurerm_resource_group.rg.name
     location            = azurerm_resource_group.rg.location
     address_space       = ["10.21.0.0/16"]
   }
   
   resource "azurerm_subnet" "frontend" {
     name                 = "myAGSubnet"
     resource_group_name  = azurerm_resource_group.rg.name
     virtual_network_name = azurerm_virtual_network.vnet.name
     address_prefixes     = ["10.21.0.0/24"]
   }
   
   resource "azurerm_subnet" "backend" {
     name                 = "myBackendSubnet"
     resource_group_name  = azurerm_resource_group.rg.name
     virtual_network_name = azurerm_virtual_network.vnet.name
     address_prefixes     = ["10.21.1.0/24"]
   }
   
   resource "azurerm_public_ip" "pip" {
     name                = "myAGPublicIPAddress"
     resource_group_name = azurerm_resource_group.rg.name
     location            = azurerm_resource_group.rg.location
     allocation_method   = "Static"
     sku                 = "Standard"
   }
   
   
   resource "azurerm_application_gateway" "main" {
     name                = "myAppGateway"
     resource_group_name = azurerm_resource_group.rg.name
     location            = azurerm_resource_group.rg.location
   
     sku {
       name     = "Standard_v2"
       tier     = "Standard_v2"
       capacity = 2
     }
   
     gateway_ip_configuration {
       name      = "my-gateway-ip-configuration"
       subnet_id = azurerm_subnet.frontend.id
     }
   
     frontend_port {
       name = var.frontend_port_name
       port = 80
     }
   
     frontend_ip_configuration {
       name                 = var.frontend_ip_configuration_name
       public_ip_address_id = azurerm_public_ip.pip.id
     }
   
     backend_address_pool {
       name = var.backend_address_pool_name
     }
   
     backend_http_settings {
       name                  = var.http_setting_name
       cookie_based_affinity = "Disabled"
       port                  = 80
       protocol              = "Http"
       request_timeout       = 60
     }
   
     http_listener {
       name                           = var.listener_name
       frontend_ip_configuration_name = var.frontend_ip_configuration_name
       frontend_port_name             = var.frontend_port_name
       protocol                       = "Http"
     }
   
     request_routing_rule {
       name                       = var.request_routing_rule_name
       rule_type                  = "Basic"
       http_listener_name         = var.listener_name
       backend_address_pool_name  = var.backend_address_pool_name
       backend_http_settings_name = var.http_setting_name
       priority                   = 1
     }
   }
   
   resource "azurerm_network_interface" "nic" {
     count               = 2
     name                = "nic-${count.index+1}"
     location            = azurerm_resource_group.rg.location
     resource_group_name = azurerm_resource_group.rg.name
   
     ip_configuration {
       name                          = "nic-ipconfig-${count.index+1}"
       subnet_id                     = azurerm_subnet.backend.id
       private_ip_address_allocation = "Dynamic"
     }
   }
   
   resource "azurerm_network_interface_application_gateway_backend_address_pool_association" "nic-assoc" {
     count                   = 2
     network_interface_id    = azurerm_network_interface.nic[count.index].id
     ip_configuration_name   = "nic-ipconfig-${count.index+1}"
     backend_address_pool_id = one(azurerm_application_gateway.main.backend_address_pool).id
   }
   
   resource "random_password" "password" {
     length  = 16
     special = true
     lower   = true
     upper   = true
     numeric = true
   }
   
   resource "azurerm_windows_virtual_machine" "vm" {
     count               = 2
     name                = "myVM${count.index+1}"
     resource_group_name = azurerm_resource_group.rg.name
     location            = azurerm_resource_group.rg.location
     size                = "Standard_DS1_v2"
     admin_username      = "azureadmin"
     admin_password      = random_password.password.result
   
     network_interface_ids = [
       azurerm_network_interface.nic[count.index].id,
     ]
   
     os_disk {
       caching              = "ReadWrite"
       storage_account_type = "Standard_LRS"
     }
   
   
     source_image_reference {
       publisher = "MicrosoftWindowsServer"
       offer     = "WindowsServer"
       sku       = "2019-Datacenter"
       version   = "latest"
     }
   }
   
   resource "azurerm_virtual_machine_extension" "vm-extensions" {
     count                = 2
     name                 = "vm${count.index+1}-ext"
     virtual_machine_id   = azurerm_windows_virtual_machine.vm[count.index].id
     publisher            = "Microsoft.Compute"
     type                 = "CustomScriptExtension"
     type_handler_version = "1.10"
   
     settings = <<SETTINGS
       {
           "commandToExecute": "powershell Add-WindowsFeature Web-Server; powershell Add-Content -Path \"C:\\inetpub\\wwwroot\\Default.htm\" -Value $($env:computername)"
       }
   SETTINGS
   
   }
   

4. Maak een bestand met de naam variables.tf en voeg de volgende code in:

   variable "backend_address_pool_name" {
       default = "myBackendPool"
   }
   
   variable "frontend_port_name" {
       default = "myFrontendPort"
   }
   
   variable "frontend_ip_configuration_name" {
       default = "myAGIPConfig"
   }
   
   variable "http_setting_name" {
       default = "myHTTPsetting"
   }
   
   variable "listener_name" {
       default = "myListener"
   }
   
   variable "request_routing_rule_name" {
       default = "myRoutingRule"
   }
   

5. Maak een bestand met de naam outputs.tf en voeg de volgende code in:

   output "gateway_frontend_ip" {
     value = "http://${azurerm_public_ip.pip.ip_address}"
   }
   

Terraform initialiseren

Voer terraform init uit om de Terraform-implementatie te initialiseren. Met deze opdracht wordt de Azure-provider gedownload die is vereist voor het beheren van uw Azure-resources.

terraform init -upgrade

Belangrijkste punten:

• Met -upgrade de parameter worden de benodigde providerinvoegtoepassingen bijgewerkt naar de nieuwste versie die voldoet aan de versiebeperkingen van de configuratie.

Een Terraform-uitvoeringsplan maken

Voer terraform-plan uit om een uitvoeringsplan te maken.

terraform plan -out main.tfplan

Belangrijkste punten:

• De terraform plan opdracht maakt een uitvoeringsplan, maar voert het niet uit. In plaats daarvan wordt bepaald welke acties nodig zijn om de configuratie te maken die is opgegeven in uw configuratiebestanden. Met dit patroon kunt u controleren of het uitvoeringsplan aan uw verwachtingen voldoet voordat u wijzigingen aanbrengt in de werkelijke resources.
• Met de optionele -out parameter kunt u een uitvoerbestand voor het plan opgeven. Door de -out parameter te gebruiken, zorgt u ervoor dat het plan dat u hebt gecontroleerd precies wordt toegepast.

Een Terraform-uitvoeringsplan toepassen

Voer terraform apply uit om het uitvoeringsplan toe te passen op uw cloudinfrastructuur.

terraform apply main.tfplan

Belangrijkste punten:

• In het voorbeeld terraform apply opdracht wordt ervan uitgegaan dat u eerder terraform plan -out main.tfplanhebt uitgevoerd.
• Als u een andere bestandsnaam voor de -out parameter hebt opgegeven, gebruikt u diezelfde bestandsnaam in de aanroep naar terraform apply.
• Als u de -out-parameter niet hebt gebruikt, roep terraform apply dan zonder parameters aan.

De resultaten controleren

1. Wanneer u het uitvoeringsplan toepast, wordt in Terraform het openbare IP-adres van de front-end weergegeven. Als u het scherm hebt gewist, kunt u die waarde ophalen met de volgende Terraform-opdracht:

   echo $(terraform output -raw gateway_frontend_ip)
   

2. Plak het openbare IP-adres in de adresbalk van uw webbrowser. Vernieuw de browser om de naam van de virtuele machine te zien. Met een geldig antwoord wordt gecontroleerd of de toepassingsgateway is gemaakt en verbinding kan maken met de back-end.

De hulpbronnen opschonen

Voer de volgende stappen uit wanneer u de resources die zijn gemaakt via Terraform niet meer nodig hebt:

1. Voer terraform-plan uit en geef de destroy vlag op.

   terraform plan -destroy -out main.destroy.tfplan
   

   Belangrijkste punten:

   • De terraform plan opdracht maakt een uitvoeringsplan, maar voert het niet uit. In plaats daarvan wordt bepaald welke acties nodig zijn om de configuratie te maken die is opgegeven in uw configuratiebestanden. Met dit patroon kunt u controleren of het uitvoeringsplan aan uw verwachtingen voldoet voordat u wijzigingen aanbrengt in de werkelijke resources.
   • Met de optionele -out parameter kunt u een uitvoerbestand voor het plan opgeven. Door de -out parameter te gebruiken, zorgt u ervoor dat het plan dat u hebt gecontroleerd precies wordt toegepast.

2. Voer terraform apply uit om het uitvoeringsplan toe te passen.

   terraform apply main.destroy.tfplan
   

Problemen met Terraform in Azure oplossen

Veelvoorkomende problemen oplossen bij het gebruik van Terraform in Azure

Volgende stappen