Delen via

Quickstart: Back-up configureren voor Azure Database for PostgreSQL - Flexible Server met behulp van een Terraform-sjabloon

In deze quickstart wordt beschreven hoe u back-ups configureert voor de Azure Database for PostgreSQL - Flexible Server met behulp van de Terraform-sjabloon.

Met Azure Backup kunt u een back-up maken van uw Azure PostgreSQL - Flexibele servers met behulp van meerdere clients, zoals Azure Portal, PowerShell, CLI, Azure Resource Manager, Bicep, enzovoort.

Vereiste voorwaarden

Voordat u een back-up configureert voor Azure Database for PostgreSQL - Flexible Server, moet u ervoor zorgen dat aan de volgende vereisten wordt voldaan:

  • U hebt een Azure-account met een actief abonnement nodig. Als u nog geen account hebt, maakt u gratis een account.

  • Installeer en configureer Terraform.

  • Meld u aan bij uw Azure-account en verifieer bij Azure.

    Notitie

    Terraform biedt alleen ondersteuning voor verificatie bij Azure met de Azure CLI. Verificatie met behulp van Azure PowerShell wordt niet ondersteund. Daarom kunt u de Azure PowerShell-module gebruiken bij het uitvoeren van uw Terraform-werk. U moet zich echter eerst authenticeren bij Azure.

De Terraform-code implementeren voor de back-upconfiguratie van PostgreSQL Flexible Server

Notitie

Zie meer artikelen en voorbeeldcode over het gebruik van Terraform voor het beheren van Azure-resources.

  1. nl-NL: Maak een map die u kunt gebruiken om de Terraform-voorbeeldcode te testen en stel deze in als uw huidige map.

  2. Maak een bestand met de naam providers.tf en voeg de volgende code in:

    terraform {
  required_providers {
    azurerm = {
      source = "hashicorp/azurerm"
      version = "3.99.0"
    }
  }
}

provider "azurerm" {
   features {}
   subscription_id   = "<azure_subscription_id>"
   tenant_id = "<azure_subscription_tenant_id>"
}

  3. Maak een bestand met de naam main.tf en voeg de volgende code in:

    
# Step 1: Create the Backup Vault
resource "azurerm_data_protection_backup_vault" "backup_vault" {
  name                = var.backup_vault_name
  resource_group_name = var.backup_vault_resource_group
  location            = var.region

  identity {
    type = "SystemAssigned"
  }

  storage_settings {
    datastore_type = "VaultStore"
    type           = "LocallyRedundant"
  }
}

# Step 2: Create Backup Policy for PostgreSQL
resource "azurerm_data_protection_backup_policy" "postgresql_backup_policy" {
  name                = var.policy_name
  resource_group_name = var.backup_vault_resource_group
  vault_name          = azurerm_data_protection_backup_vault.backup_vault.name

  rule {
    name = "BackupSchedule"

    backup_parameters {
      object_type = "AzureBackupParams"
    }

    trigger {
      schedule {
        recurrence_rule {
          frequency = "Weekly"
          interval  = var.backup_schedule_frequency
        }
      }
    }

    data_store {
      datastore_type = "VaultStore"
    }
  }

  retention_rule {
    name       = "RetentionRule"
    is_default = true

    lifecycle {
      delete_after {
        object_type = "AbsoluteDeleteOption"
        duration    = format("P%dM", var.retention_duration_in_months)
      }
    }
  }

  depends_on = [
    azurerm_data_protection_backup_vault.backup_vault
  ]
}

# Step 3: Role Assignment for PostgreSQL Flexible Server Long Term Retention Backup Role
data "azurerm_postgresql_flexible_server" "postgresql_server" {
  name                = var.postgresql_server_name
  resource_group_name = var.postgresql_resource_group
}

resource "azurerm_role_assignment" "backup_role" {
  principal_id         = azurerm_data_protection_backup_vault.backup_vault.identity[0].principal_id
  role_definition_name = "PostgreSQL Flexible Server Long Term Retention Backup Role"
  scope                = data.azurerm_postgresql_flexible_server.PostgreSQL_server.id

  depends_on = [
    azurerm_data_protection_backup_policy.postgresql_backup_policy
  ]
}

# Step 4: Role Assignment for Reader on Resource Group
data "azurerm_resource_group" "postgresql_resource_group" {
  name = var.postgresql_resource_group
}

resource "azurerm_role_assignment" "reader_role" {
  principal_id         = azurerm_data_protection_backup_vault.backup_vault.identity[0].principal_id
  role_definition_name = "Reader"
  scope                = data.azurerm_resource_group.postgresql_resource_group.id

  depends_on = [
    azurerm_role_assignment.backup_role
  ]
}

# Step 5: Create Backup Instance for PostgreSQL
resource "azurerm_data_protection_backup_instance" "postgresql_backup_instance" {
  name                = "PostgreSQLBackupInstance"
  resource_group_name = var.backup_vault_resource_group
  vault_name          = azurerm_data_protection_backup_vault.backup_vault.name
  location            = var.region

  datasource {
    object_type     = "Datasource"
    datasource_type = "AzureDatabaseForPostgreSQLFlexibleServer"
    resource_id     = data.azurerm_PostgreSQL_flexible_server.postgresql_server.id
  }

  policy_id = azurerm_data_protection_backup_policy.postgresql_backup_policy.id

  depends_on = [
    azurerm_role_assignment.reader_role
  ]
}

  4. Maak een bestand met de naam variables.tf en voeg de volgende code in:


variable "backup_vault_name" {
      type        = string
      default     = "BackupVaultTF"
      description = "Name of the Backup Vault"
}
variable "backup_vault_resource_group" {
      type        = string
      default     = "Contoso_TF_RG"
      description = "Name of the resource group to which backup vault belongs to"
}

variable "postgresql_server_name" {
      type        = string
      default     = "Contoso_PostgreSQL_TF"
      description = "Name of the PostgreSQL server"
}

variable "postgresql_resource_group" {
      type        = string
      default     = "Contoso_TF_RG"
      description = "Name of the resource group to which PostgreSQL server belongs to"
}

variable "region" {
      type        = string
      default     = "eastus"
      description = "Location of the PostgreSQL server"
}

variable "policy_name" {
      type        = string
      default     = "PostgreSQLbackuppolicytfv1"
      description = "Name of the backup policy"
}

variable "backup_schedule_frequency" {
      type        = string
      default     = "1"
      description = "Schedule frequency for backup"
}
variable "retention_duration_in_months" {
      type        = string
      default     = "3"
      description = "Retention duration for backup in month"
}

Terraform initialiseren voor Back-up van PostgreSQL Flexible Server

Voer terraform init uit om de Terraform-implementatie te initialiseren. Met deze opdracht wordt de Azure-provider gedownload die is vereist voor het beheren van uw Azure-resources.

terraform init -upgrade

Belangrijkste punten:

  • Met -upgrade de parameter worden de benodigde providerinvoegtoepassingen bijgewerkt naar de nieuwste versie die voldoet aan de versiebeperkingen van de configuratie.

Een Terraform-uitvoeringsplan maken voor back-up van PostgreSQL Flexible Server

Voer terraform-plan uit om een uitvoeringsplan te maken.

terraform plan -out main.tfplan

Belangrijkste punten:

  • De terraform plan opdracht maakt een uitvoeringsplan, maar voert het niet uit. In plaats daarvan wordt bepaald welke acties nodig zijn om de configuratie te maken die is opgegeven in uw configuratiebestanden. Met dit patroon kunt u controleren of het uitvoeringsplan aan uw verwachtingen voldoet voordat u wijzigingen aanbrengt in de werkelijke resources.
  • Met de optionele -out parameter kunt u een uitvoerbestand voor het plan opgeven. Door de -out parameter te gebruiken, zorgt u ervoor dat het plan dat u hebt gecontroleerd precies wordt toegepast.

Een Terraform-uitvoeringsplan toepassen voor Back-up van PostgreSQL Flexible Server

Voer terraform apply uit om het uitvoeringsplan toe te passen op uw cloudinfrastructuur.

terraform apply main.tfplan

Belangrijkste punten:

  • Bij de voorbeeldopdracht terraform apply wordt ervan uitgegaan dat u eerder hebt uitgevoerd terraform plan -out main.tfplan.
  • Als u een andere bestandsnaam voor de -out parameter hebt opgegeven, gebruikt u diezelfde bestandsnaam in de aanroep naar terraform apply.
  • Als u de -out parameter niet hebt gebruikt, bel terraform apply zonder parameters.

Problemen met Terraform in Azure oplossen

Veelvoorkomende problemen bij het gebruik van Terraform in Azure oplossen.

Volgende stappen

Azure Database for PostgreSQL - Flexibele server herstellen met behulp van Azure CLI.

  • Last updated on