Delen via

Uw koolstofuitstoot in Azure verminderen

Koolstofoptimalisatie in Azure werkt met Azure Advisor om aanbevelingen voor optimalisatie te bieden. Azure Advisor identificeert niet-actieve en onderbenutte resources en toont de bijbehorende koolstof- en kostenbesparingen voor het implementeren van de aanbevelingen. Aanbevelingen kunnen omvatten het afsluiten van niet-actieve virtuele machines en het rechten geven van virtuele machines. Zie Servicekosten verlagen met behulp van Azure Advisorvoor meer aanbevelingen en informatie over Azure Advisor.

Als u aanbevelingen voor koolstofoptimalisatie wilt bekijken, gaat u naar de pagina Emissiereductie en selecteert u het gewenste abonnement en de gewenste resourcegroepen.

Op deze pagina ziet u het totale aantal beschikbare aanbevelingen en potentiële besparingsmogelijkheden in termen van kosten en koolstof. Er worden ook koolstofbesparingsequivalenten weergegeven zoals berekend door de calculator voor EPA-kasgasequivalenten in de Verenigde Staten.

Aanbevelingen weergeven

De lijst met aanbevelingen in de tabel toont inefficiënt gebruikte hulpbronnen die kunnen helpen bij het verlagen van koolstofuitstoot. Elke aanbeveling toont gekoppelde koolstofbesparingen en potentiële kostenbesparingen die kunnen komen door op een aanbeveling te reageren.

Actie ondernemen op de aanbeveling

Als u wilt reageren op de aanbeveling, selecteert u de resourcenaam of de tekst in de kolom Aanbeveling. Als u de aanbevelingstekst selecteert, gaat u naar de actiepagina voor de resource. Bijvoorbeeld: de pagina voor formaatwijzigingen, de pagina voor het wijzigen van het aantal exemplaren, of de overzichtspagina van de resource voor aanbevelingen voor verwijderen.

Een schermopname van de pagina emissiesreductie.

Emissiebesparingen omzetten in equivalenten

Met de calculator voor broeikasgasequivalencies kunt u emissiegegevens converteren naar de equivalente hoeveelheid kooldioxide (CO2) die door die hoeveelheid wordt uitgezonden. De calculator helpt u abstracte metingen te vertalen in concrete termen die u kunt begrijpen, zoals de jaarlijkse emissies van bomen, huishoudens of prullenbakken. Deze rekenmachine kan nuttig zijn bij het communiceren van uw strategie voor broeikasgassenreductie, reductiedoelen of andere initiatieven die zijn gericht op het verminderen van de uitstoot van broeikasgassen.

Zie Servicekosten verlagen met behulp van Azure Advisorvoor meer informatie over typen aanbevelingen.

Aanbevelingen voor exportemissiereductie

U kunt aanbevelingen voor emissiereductie exporteren met behulp van Azure Resource Graph. Voer de volgende query uit in Azure Resource Graph Explorer. Daarna kunt u de resultaten downloaden als CSV.

De export omvat:

  • Aanbevelings-id
  • Abonnements-id/abonnementsnaam
  • Naam van resourcegroep
  • Maandelijkse kostenbesparingen
  • Maandelijkse koolstofbesparing in kilogram
  • Resourcenaam
  • Aanbevelingsbericht
  • Aanbevelingstype
  • Details over de aanbeveling, inclusief de metagegevens van de resource, zoals resource-id en rolnaam
// Export emissions reduction recommendations using Azure Resource Graph

advisorresources
  | where tolower(type) == "microsoft.advisor/recommendations"
  | extend RecommendationTypeId = tostring(properties.recommendationTypeId)
  | where RecommendationTypeId in ("94aea435-ef39-493f-a547-8408092c22a7", "e10b1381-5f0a-47ff-8c7b-37bd13d7c974")
  | project stableId=name, subscriptionId, resourceGroup, properties, recommendationId=id
  | join kind=leftouter(
      advisorresources
      | where tolower(type) == 'microsoft.advisor/suppressions'
      | extend tokens = split(id, '/')
      | extend stableId = iff(array_length(tokens) > 3, tokens[(array_length(tokens)-3)], '')
      | extend expirationTimeStamp = todatetime(iff(strcmp(tostring(properties.ttl), '-1') == 0, '9999-12-31', properties.expirationTimeStamp))
      | where expirationTimeStamp > now()
      | project suppressionId = tostring(properties.suppressionId), stableId, expirationTimeStamp
  ) on stableId
  | join kind = leftouter (
      advisorresources
      | where tolower(type) == 'microsoft.advisor/configurations'
      | where isempty(resourceGroup) == true
      | project subscriptionId, excludeRecomm = properties.exclude, lowCpuThreshold = properties.lowCpuThreshold
  ) on subscriptionId
  | extend isActive = iff(isempty(excludeRecomm), true, tobool(excludeRecomm) == false)
  | extend isNotExcludedViaCpuThreshold = iff((isnotempty(lowCpuThreshold) and isnotnull(properties.extendedProperties) and isnotempty(properties.extendedProperties.MaxCpuP95)),
      todouble(properties.extendedProperties.MaxCpuP95) < todouble(lowCpuThreshold),
      iff((isnull(properties.extendedProperties) or isempty(properties.extendedProperties.MaxCpuP95) or todouble(properties.extendedProperties.MaxCpuP95) < 100),
          true,
          false))
  | where isActive == true and isNotExcludedViaCpuThreshold == true
  | join kind = leftouter (
      advisorresources
      | where type =~ 'microsoft.advisor/configurations'
      | where isnotempty(resourceGroup) == true
      | project subscriptionId, resourceGroup, excludeProperty = properties.exclude
  ) on subscriptionId, resourceGroup
  | extend shouldBeIncluded = iff(isempty(excludeProperty), true, tobool(excludeProperty) == false)
  | where shouldBeIncluded == true
  | summarize expirationTimeStamp = max(expirationTimeStamp), suppressionIds = make_list(suppressionId) by recommendationId, stableId, subscriptionId, resourceGroup, tostring(properties)
  | extend isRecommendationActive = (isnull(expirationTimeStamp) or isempty(expirationTimeStamp))
  | extend properties = parse_json(properties)
  | extend monthlyCostSavings = toreal(properties.extendedProperties.savingsAmount)
  | extend monthlyCarbonSavingsKg = toreal(properties.extendedProperties.PotentialMonthlyCarbonSavings)
  | where monthlyCarbonSavingsKg > 0
  | extend resourceId = properties.resourceMetadata.resourceId, resourceName = tostring(properties.extendedProperties.roleName), recommendationMessage = properties.extendedProperties.recommendationMessage, recommendationType=tostring(properties.extendedProperties.recommendationType)
  | project recommendationId, subscriptionId, resourceGroup, suppressionIds, isRecommendationActive, monthlyCostSavings, monthlyCarbonSavingsKg, resourceId, resourceName, recommendationMessage, recommendationType| where isRecommendationActive == true| order by monthlyCarbonSavingsKg desc

Volgende stappen

  • Last updated on