Delen via

Quickstart: Terraform gebruiken om een Azure IoT Device Provisioning Service te maken

In deze quickstart leert u hoe u een Azure IoT Hub Device Provisioning Service-resource (DPS) implementeert met een hash-toewijzingsbeleid met behulp van Terraform.

Deze quickstart is getest met de volgende Terraform- en Terraform-providerversies:

Terraform maakt de definitie, preview en implementatie van de cloudinfrastructuur mogelijk. Met Behulp van Terraform maakt u configuratiebestanden met behulp van de HCL-syntaxis. Met de HCL-syntaxis kunt u de cloudprovider opgeven, zoals Azure, en de elementen waaruit uw cloudinfrastructuur bestaat. Nadat u uw configuratiebestanden hebt gemaakt, maakt u een uitvoeringsplan waarmee u een voorbeeld van uw infrastructuurwijzigingen kunt bekijken voordat ze worden geïmplementeerd. Zodra u de wijzigingen hebt gecontroleerd, past u het uitvoeringsplan toe om de infrastructuur te implementeren.

In dit artikel leert u het volgende:

  • Een opslagaccount en opslagcontainer maken
  • Een Event Hubs, naamruimte en autorisatieregel maken
  • Een IoT Hub maken
  • IoT Hub koppelen aan opslagaccount-eindpunt en Event Hubs-eindpunt
  • Een gedeeld toegangsbeleid voor IoT Hub maken
  • Een DPS-resource maken
  • DPS & IoT Hub koppelen

Vereiste voorwaarden

  • Azure-abonnement: als u geen Azure-abonnement hebt, maakt u een gratis account voordat u begint.

De Terraform-code implementeren

Opmerking

De voorbeeldcode in dit artikel bevindt zich in de Azure Terraform GitHub-opslagplaats. Zie de Terraform-documentatie in Azure voor meer informatie, waaronder artikelen en voorbeeldcode die laten zien hoe u Terraform gebruikt om Azure-resources te beheren

  1. Maak een map waarin u de Terraform-voorbeeldcode wilt testen en uitvoeren en deze de huidige map wilt maken.

  2. Maak een bestand met de naam providers.tf en voeg de volgende code in:

    terraform {
  required_version = ">=1.0"

  required_providers {
    azurerm = {
      source  = "hashicorp/azurerm"
      version = ">=3.0"
    }
    random = {
      source  = "hashicorp/random"
      version = "~>3.0"
    }
  }
}

provider "azurerm" {
  features {}
}

  3. Maak een bestand met de naam main.tf en voeg de volgende code in:

    resource "random_pet" "rg_name" {
  prefix = var.resource_group_name_prefix
}

resource "azurerm_resource_group" "rg" {
  location = var.resource_group_location
  name     = random_pet.rg_name.id
}

# Create storage account & container
resource "random_string" "sa_name" {
  length  = 12
  special = false
  upper   = false
}

resource "azurerm_storage_account" "sa" {
  name                     = random_string.sa_name.id
  resource_group_name      = azurerm_resource_group.rg.name
  location                 = azurerm_resource_group.rg.location
  account_tier             = "Standard"
  account_replication_type = "LRS"
}

resource "azurerm_storage_container" "my_terraform_container" {
  name                  = "mycontainer"
  storage_account_name  = azurerm_storage_account.sa.name
  container_access_type = "private"
}


# Create an Event Hub & Authorization Rule
resource "random_pet" "eventhub_namespace_name" {
  prefix = var.eventhub_namespace_name_prefix
}

resource "azurerm_eventhub_namespace" "namespace" {
  name                = random_pet.eventhub_namespace_name.id
  resource_group_name = azurerm_resource_group.rg.name
  location            = azurerm_resource_group.rg.location
  sku                 = "Basic"
}

resource "azurerm_eventhub" "my_terraform_eventhub" {
  name                = "myEventHub"
  resource_group_name = azurerm_resource_group.rg.name
  namespace_name      = azurerm_eventhub_namespace.namespace.name
  partition_count     = 2
  message_retention   = 1
}

resource "azurerm_eventhub_authorization_rule" "my_terraform_authorization_rule" {
  resource_group_name = azurerm_resource_group.rg.name
  namespace_name      = azurerm_eventhub_namespace.namespace.name
  eventhub_name       = azurerm_eventhub.my_terraform_eventhub.name
  name                = "acctest"
  send                = true
}


# Create an IoT Hub
resource "random_pet" "iothub_name" {
  prefix = var.iothub_name_prefix
  length = 1
}

resource "azurerm_iothub" "iothub" {
  name                = random_pet.iothub_name.id
  resource_group_name = azurerm_resource_group.rg.name
  location            = azurerm_resource_group.rg.location

  sku {
    name     = "S1"
    capacity = 1
  }

  endpoint {
    type                       = "AzureIotHub.StorageContainer"
    connection_string          = azurerm_storage_account.sa.primary_blob_connection_string
    name                       = "export"
    batch_frequency_in_seconds = 60
    max_chunk_size_in_bytes    = 10485760
    container_name             = azurerm_storage_container.my_terraform_container.name
    encoding                   = "Avro"
    file_name_format           = "{iothub}/{partition}_{YYYY}_{MM}_{DD}_{HH}_{mm}"
  }

  endpoint {
    type              = "AzureIotHub.EventHub"
    connection_string = azurerm_eventhub_authorization_rule.my_terraform_authorization_rule.primary_connection_string
    name              = "export2"
  }

  route {
    name           = "export"
    source         = "DeviceMessages"
    condition      = "true"
    endpoint_names = ["export"]
    enabled        = true
  }

  route {
    name           = "export2"
    source         = "DeviceMessages"
    condition      = "true"
    endpoint_names = ["export2"]
    enabled        = true
  }

  enrichment {
    key            = "tenant"
    value          = "$twin.tags.Tenant"
    endpoint_names = ["export", "export2"]
  }

  cloud_to_device {
    max_delivery_count = 30
    default_ttl        = "PT1H"
    feedback {
      time_to_live       = "PT1H10M"
      max_delivery_count = 15
      lock_duration      = "PT30S"
    }
  }

  tags = {
    purpose = "testing"
  }
}

#Create IoT Hub Access Policy
resource "azurerm_iothub_shared_access_policy" "hub_access_policy" {
  name                = "terraform-policy"
  resource_group_name = azurerm_resource_group.rg.name
  iothub_name         = azurerm_iothub.iothub.name

  registry_read   = true
  registry_write  = true
  service_connect = true
}

# Create IoT Hub DPS
resource "random_pet" "dps_name" {
  prefix = var.dps_name_prefix
  length = 1
}

resource "azurerm_iothub_dps" "dps" {
  name                = random_pet.dps_name.id
  resource_group_name = azurerm_resource_group.rg.name
  location            = azurerm_resource_group.rg.location
  allocation_policy   = "Hashed"

  sku {
    name     = "S1"
    capacity = 1
  }

  linked_hub {
    connection_string       = azurerm_iothub_shared_access_policy.hub_access_policy.primary_connection_string
    location                = azurerm_resource_group.rg.location
    allocation_weight       = 150
    apply_allocation_policy = true
  }
}

  4. Maak een bestand met de naam variables.tf en voeg de volgende code in:

    variable "resource_group_location" {
  default     = "eastus"
  description = "Location of the resource group."
}

variable "resource_group_name_prefix" {
  default     = "rg"
  description = "Prefix of the resource group name that's combined with a random ID so name is unique in your Azure subscription."
}

variable "eventhub_namespace_name_prefix" {
  default     = "namespace"
  description = "Prefix of the event hub namespace name that's combined with a random ID so name is unique in your Azure subscription."
}

variable "iothub_name_prefix" {
  default     = "iothub"
  description = "Prefix of the iot hub name that's combined with a random ID so name is unique in your Azure subscription."
}

variable "dps_name_prefix" {
  default     = "dps"
  description = "Prefix of the dps name that's combined with a random ID so name is unique in your Azure subscription."
}

  5. Maak een bestand met de naam outputs.tf en voeg de volgende code in:

    output "azurerm_iothub_name" {
  value = azurerm_iothub.iothub.name
}

output "azurerm_iothub_dps_name" {
  value = azurerm_iothub_dps.dps.name
}

output "resource_group_name" {
  value = azurerm_resource_group.rg.name
}

Terraform initialiseren

Voer terraform init uit om de Terraform-implementatie te initialiseren. Met deze opdracht wordt de Azure-provider gedownload die is vereist voor het beheren van uw Azure-resources.

terraform init -upgrade

Belangrijkste punten:

  • Met -upgrade de parameter worden de benodigde providerinvoegtoepassingen bijgewerkt naar de nieuwste versie die voldoet aan de versiebeperkingen van de configuratie.

Een Terraform-uitvoeringsplan maken

Voer terraform-plan uit om een uitvoeringsplan te maken.

terraform plan -out main.tfplan

Belangrijkste punten:

  • De terraform plan opdracht maakt een uitvoeringsplan, maar voert het niet uit. In plaats daarvan wordt bepaald welke acties nodig zijn om de configuratie te maken die is opgegeven in uw configuratiebestanden. Met dit patroon kunt u controleren of het uitvoeringsplan aan uw verwachtingen voldoet voordat u wijzigingen aanbrengt in de werkelijke resources.
  • Met de optionele -out parameter kunt u een uitvoerbestand voor het plan opgeven. Door de -out parameter te gebruiken, zorgt u ervoor dat het plan dat u hebt gecontroleerd precies wordt toegepast.

Een Terraform-uitvoeringsplan toepassen

Voer terraform apply uit om het uitvoeringsplan toe te passen op uw cloudinfrastructuur.

terraform apply main.tfplan

Belangrijkste punten:

  • In het voorbeeld terraform apply opdracht wordt ervan uitgegaan dat u eerder terraform plan -out main.tfplanhebt uitgevoerd.
  • Als u een andere bestandsnaam voor de -out parameter hebt opgegeven, gebruikt u diezelfde bestandsnaam in de aanroep naar terraform apply.
  • Als u de -out-parameter niet hebt gebruikt, roep terraform apply dan zonder parameters aan.

De resultaten controleren

Voer az iot dps uit om de Azure DPS-resource weer te geven.

az iot dps show \
   --name <azurerm_iothub_dps_name> \
   --resource-group <resource_group_name>

Belangrijkste punten:

  • De namen van de resourcegroep en het DPS-exemplaar worden weergegeven in de terraform apply uitvoer. U kunt ook terraform-uitvoer uitvoeren om deze uitvoerwaarden weer te geven.

De hulpbronnen opschonen

Voer de volgende stappen uit wanneer u de resources die zijn gemaakt via Terraform niet meer nodig hebt:

  1. Voer terraform-plan uit en geef de destroy vlag op.

    terraform plan -destroy -out main.destroy.tfplan

    Belangrijkste punten:

    • De terraform plan opdracht maakt een uitvoeringsplan, maar voert het niet uit. In plaats daarvan wordt bepaald welke acties nodig zijn om de configuratie te maken die is opgegeven in uw configuratiebestanden. Met dit patroon kunt u controleren of het uitvoeringsplan aan uw verwachtingen voldoet voordat u wijzigingen aanbrengt in de werkelijke resources.
    • Met de optionele -out parameter kunt u een uitvoerbestand voor het plan opgeven. Door de -out parameter te gebruiken, zorgt u ervoor dat het plan dat u hebt gecontroleerd precies wordt toegepast.

  2. Voer terraform apply uit om het uitvoeringsplan toe te passen.

    terraform apply main.destroy.tfplan

Problemen met Terraform in Azure oplossen

Veelvoorkomende problemen oplossen bij het gebruik van Terraform in Azure

Volgende stappen

In deze quickstart hebt u een IoT-hub en een Device Provisioning Service-exemplaar geïmplementeerd en de twee resources gekoppeld. Als u wilt weten hoe u deze installatie gebruikt om een apparaat in te richten, gaat u verder met de quickstart voor het maken van een apparaat.

Quickstart: Een gesimuleerd symmetrisch sleutelapparaat inrichten

  • Last updated on