Georuimtelijke visualisaties

Van toepassing op: ✅Microsoft Fabric✅Azure Data Explorer✅Azure Monitor✅Microsoft Sentinel

Georuimtelijke gegevens kunnen worden gevisualiseerd als onderdeel van uw query met behulp van de renderoperator als punten, cirkels of bellen op een kaart.

Zie Georuimtelijke clustering voor meer informatie over georuimtelijke clustering.

Voorbeelden

In het volgende voorbeeld worden storm-gebeurtenissen gevonden en worden 100 op een kaart gevisualiseerd.

StormEvents
| take 100
| project BeginLon, BeginLat
| render scatterchart with (kind = map)

In het volgende voorbeeld worden meerdere reeks punten gevisualiseerd, waarbij het paar [Lengtegraad, Breedtegraad] elk punt definieert en een derde kolom de reeks definieert. In dit voorbeeld is EventTypede reeks .

StormEvents
| take 100
| project BeginLon, BeginLat, EventType
| render scatterchart with (kind = map)

In het volgende voorbeeld wordt een reeks punten op een kaart gevisualiseerd. Als u meerdere kolommen in het resultaat hebt, moet u de kolommen opgeven die moeten worden gebruikt voor xcolumn (lengtegraad), ycolumn (breedtegraad) en reeksen.

StormEvents
| take 100
| render scatterchart with (kind = map, xcolumn = BeginLon, ycolumns = BeginLat, series = EventType)

In het volgende voorbeeld worden punten op de kaart gevisualiseerd met behulp van dynamische GeoJSON-waarden om de punten te definiëren.

StormEvents
| project BeginLon, BeginLat
| summarize by hash=geo_point_to_s2cell(BeginLon, BeginLat, 5)
| project geo_s2cell_to_central_point(hash)
| render scatterchart with (kind = map)

In het volgende voorbeeld ziet u stormgebeurtenissen die zijn samengevoegd door S2-cellen. In de grafiek worden gebeurtenissen in bellen samengevoegd op locatie in één kleur.

StormEvents
| project BeginLon, BeginLat, EventType
| where geo_point_in_circle(BeginLon, BeginLat, real(-81.3891), 28.5346, 1000 * 100)
| summarize count() by EventType, hash = geo_point_to_s2cell(BeginLon, BeginLat)
| project geo_s2cell_to_central_point(hash), count_
| extend Events = "count"
| render piechart with (kind = map)

In het volgende voorbeeld ziet u stormgebeurtenissen die zijn samengevoegd door S2-cellen. In de grafiek worden gebeurtenissen samengevoegd op gebeurtenistype in cirkeldiagrammen op locatie.

StormEvents
| project BeginLon, BeginLat, EventType
| where geo_point_in_circle(BeginLon, BeginLat, real(-81.3891), 28.5346, 1000 * 100)
| summarize count() by EventType, hash = geo_point_to_s2cell(BeginLon, BeginLat)
| project geo_s2cell_to_central_point(hash), EventType, count_
| render piechart with (kind = map)

Verwante inhoud

• Georuimtelijke clustering
• Renderoperator
• Gegevensanalyse voor automotive test fleets (georuimtelijk clustering use case)
• Meer informatie over Azure-architectuur voor georuimtelijke gegevensverwerking en -analyse