Let statement

Applies to: ✅Microsoft Fabric✅Azure Data Explorer✅Azure Monitor✅Microsoft Sentinel

A let statement is used to set a variable name equal to an expression or a function, or to create views.

let instructies zijn handig voor:

• Het opsplitsen van een complexe expressie in meerdere delen, elk vertegenwoordigd door een variabele.
• Constanten buiten de hoofdtekst van de query definiëren voor leesbaarheid.
• Een variabele eenmaal definiëren en meerdere keren gebruiken binnen een query.

Als de variabele eerder een andere waarde weergeeft, bijvoorbeeld in geneste instructies, is de binnenste let instructie van toepassing.

Zie letom meerdere toepassingen van de -instructie binnen één query te optimaliseren.

Syntaxis: Scalaire of tabellaire expressies

let Name=Expression

Learn more about syntax conventions.

Parameters

Syntaxis: Weergave of functie

let Name= [view] ([ Parameters ]){FunctionBody}

Learn more about syntax conventions.

Parameters

Examples

In de queryvoorbeelden ziet u de syntaxis en het voorbeeldgebruik van de operator, instructie of functie.

Scalaire waarden definiëren

In het volgende voorbeeld wordt een scalaire expressie-instructie gebruikt.

let threshold = 50;
let region = "West";
datatable(Name:string, Score:int, Region:string)
[
    "Alice", 45, "West",
    "Bob", 60, "East",
    "Charlie", 55, "West",
    "Dana", 70, "North"
]
| where Score > threshold and Region == region

Output

Tabellaire expressies definiëren

In het volgende voorbeeld wordt de naam some number gekoppeld met behulp van de notatie ['name'] en wordt deze vervolgens gebruikt in een expressie-instructie in tabelvorm.

let ['some number'] = 20;
range y from 0 to ['some number'] step 5

Output

Een door de gebruiker gedefinieerde functie maken met scalaire berekening

In dit voorbeeld wordt de let-instructie gebruikt met argumenten voor scalaire berekeningen. De query definieert functie-MultiplyByN voor het vermenigvuldigen van twee getallen.

let MultiplyByN = (val:long, n:long) { val * n };
range x from 1 to 5 step 1 
| extend result = MultiplyByN(x, 5)

Output

Een door de gebruiker gedefinieerde functie maken waarmee invoer wordt geknipt

In het volgende voorbeeld worden voorloop- en volgvolgende items uit de invoer verwijderd.

let TrimOnes = (s:string) { trim("1", s) };
range x from 10 to 15 step 1 
| extend result = TrimOnes(tostring(x))

Output

Meerdere let-instructies gebruiken

In dit voorbeeld worden twee let-instructies gedefinieerd waarbij één instructie (foo2) een andere instructie (foo1) gebruikt.

let foo1 = (_start:long, _end:long, _step:long) { range x from _start to _end step _step};
let foo2 = (_step:long) { foo1(1, 100, _step)};
foo2(2) | count

Output

Een weergave of virtuele tabel maken

In dit voorbeeld ziet u hoe u een let-instructie gebruikt om een view of virtuele tabel te maken.

let Range10 = view () { range MyColumn from 1 to 10 step 1 };
let Range20 = view () { range MyColumn from 1 to 20 step 1 };
search MyColumn == 5

Output

Een materialize-functie gebruiken

Met de functie materialize() kunt u subqueryresultaten opslaan tijdens het uitvoeren van query's. Wanneer u de functie materialize() gebruikt, worden de gegevens in de cache opgeslagen en worden bij elke volgende aanroep van het resultaat gegevens in de cache gebruikt.

let TotalEventsbyLocation = StormEvents
| summarize TotalCount = count() by Location = BeginLocation;
let materializedScope = StormEvents
| summarize by EventType, Location = EndLocation;
let cachedResult = materialize(materializedScope);
cachedResult
| project EventType, Location
| join kind = inner
(
    cachedResult
    | project EventType, Location
)
on EventType
| where Location != ""
| summarize EventCount = count() by Location
| join kind = inner
    TotalEventsbyLocation
on $left.Location == $right.Location
| project Location, EventCount, TotalCount, Percentage = EventCount * 100.0 / TotalCount

Output

Geneste let-instructies gebruiken

Geneste let-instructies zijn toegestaan, inclusief binnen een door de gebruiker gedefinieerde functie-expressie. Laat instructies en argumenten toepassen in zowel het huidige als het binnenste bereik van de hoofdtekst van de functie.

let start_time = ago(5h); 
let end_time = start_time + 2h; 
T | where Time > start_time and Time < end_time | ...

Argument in tabelvorm met schema

In het volgende voorbeeld wordt aangegeven dat de tabelparameter T een kolom moet hebben State van het type string. De tabel T kan ook andere kolommen bevatten, maar er kan niet naar worden verwezen in de functie StateState omdat deze niet zijn gedeclareerd.

let StateState=(T: (State: string)) { T | extend s_s=strcat(State, State) };
StormEvents
| invoke StateState()
| project State, s_s

Output

Argument in tabelvorm met jokerteken

De tabelparameter T elk schema kan hebben en de functie CountRecordsInTable werkt.

let CountRecordsInTable=(T: (*)) { T | count };
StormEvents | invoke CountRecordsInTable()

Output