List.PositionOfAny

Syntaxis

List.PositionOfAny(
    list as list,
    values as list,
    optional occurrence as nullable number,
    optional equationCriteria as any
) as any

Over

Retourneert de offset waarmee een item uit de opgegeven lijst met waarden in een lijst wordt weergegeven. Retourneert -1 als er geen exemplaar is gevonden.

• list: De lijst waarin gezocht moet worden.
• values: De lijst met waarden die u in de oorspronkelijke lijst kunt vinden.
• occurrence: (Optioneel) Het specifieke exemplaar dat moet worden gerapporteerd. Deze waarde kan Occurrence.First, Occurrence.Last of Occurrence.All zijn. Als er geen occurrence is opgegeven, Occurrence.First wordt deze gebruikt.
• equationCriteria: (Optioneel) Geeft aan hoe gelijkheid wordt bepaald bij het vergelijken van waarden. Deze parameter kan een sleutelkiezerfunctie, een vergelijkingsfunctie of een lijst met zowel een sleutelkiezer als een vergelijkingsfunctie zijn.

Voorbeeld 1

Zoek de eerste positie in de lijst {1, 2, 3} waarop de waarde 2 of 3 wordt weergegeven.

Gebruik

List.PositionOfAny({1, 2, 3}, {2, 3})

Uitvoer

1

Voorbeeld 2

Zoek de positie in de lijst met alle datums uit 2022 of 2023.

Gebruik

let
    Source = {
        #date(2021, 5, 10),
        #date(2022, 6, 28),
        #date(2023, 7, 15),
        #date(2025, 12, 31),
        #date(2022, 4, 8),
        #date(2024, 3, 20)
    },
    YearList = List.Transform(Source, each Date.Year(_)),
    TargetYear = {2022, 2023},
    FindPositions = List.PositionOfAny(YearList, TargetYear, Occurrence.All)
in
    FindPositions

Uitvoer

{1, 2, 4}

Voorbeeld 3

Zoek de positie in de lijst met het laatste exemplaar van het woord hond of kat, waarbij hoofdletters of kleine letters worden genegeerd.

Gebruik

let
    Source = List.PositionOfAny(
        {"dog", "cat", "DOG", "pony", "bat", "rabbit", "dOG"}, 
        {"dog", "cat"}, 
        Occurrence.Last, 
        Comparer.OrdinalIgnoreCase
    )
in
    Source

Uitvoer

6

Voorbeeld 4

Zoek een positie in de lijst binnen twee eenheden van het getal 17 of 28.

Gebruik

let
    Source = { 10, 15, 20, 25, 30 },
    Position = List.PositionOfAny(
        Source, 
        {17, 28},
        Occurrence.All, 
        (x, y) => Number.Abs(x - y) <= 2
    )
in
    Position

Uitvoer

{1, 4}

Gerelateerde inhoud

Vergelijkingscriteria