Szybki start: tworzenie wystąpienia kontenera platformy Azure przy użyciu publicznego adresu IP przy użyciu narzędzia Terraform

Użyj usługi Azure Container Instances, aby łatwo i szybko uruchamiać bezserwerowe kontenery Docker na platformie Azure. Przekaż na żądanie aplikację do instancji kontenera, gdy nie potrzebujesz pełnej platformy orkiestracji kontenerów, np. Azure Kubernetes Service. W tym artykule użyjesz narzędzia Terraform do wdrożenia izolowanego kontenera platformy Docker i udostępnienia jej aplikacji internetowej za pomocą publicznego adresu IP.

Narzędzie Terraform umożliwia definiowanie, wyświetlanie wersji zapoznawczej i wdrażanie infrastruktury chmury. Za pomocą narzędzia Terraform tworzysz pliki konfiguracji przy użyciu składni HCL. Składnia listy HCL umożliwia określenie dostawcy chmury — takiego jak platforma Azure — oraz elementów tworzących infrastrukturę chmury. Po utworzeniu plików konfiguracji utworzysz plan wykonywania , który umożliwia wyświetlenie podglądu zmian infrastruktury przed ich wdrożeniem. Po zweryfikowaniu zmian należy zastosować plan wykonywania w celu wdrożenia infrastruktury.

Z tego artykułu dowiesz się, jak wykonywać następujące działania:

Wymagania wstępne

• Instalowanie i konfigurowanie narzędzia Terraform

Implementowanie kodu narzędzia Terraform

1. Utwórz katalog, w którym chcesz przetestować i uruchomić przykładowy kod programu Terraform i utworzyć go jako bieżący katalog.

2. Utwórz plik o nazwie main.tf i wstaw następujący kod:

   resource "random_pet" "rg_name" {
     prefix = var.resource_group_name_prefix
   }
   
   resource "azurerm_resource_group" "rg" {
     name     = random_pet.rg_name.id
     location = var.resource_group_location
   }
   
   resource "random_string" "container_name" {
     length  = 25
     lower   = true
     upper   = false
     special = false
   }
   
   resource "azurerm_container_group" "container" {
     name                = "${var.container_group_name_prefix}-${random_string.container_name.result}"
     location            = azurerm_resource_group.rg.location
     resource_group_name = azurerm_resource_group.rg.name
     ip_address_type     = "Public"
     os_type             = "Linux"
     restart_policy      = var.restart_policy
     zones               = var.zone != "" ? [ var.zone ] : null
   
     container {
       name   = "${var.container_name_prefix}-${random_string.container_name.result}"
       image  = var.image
       cpu    = var.cpu_cores
       memory = var.memory_in_gb
   
       ports {
         port     = var.port
         protocol = "TCP"
       }
     }
   }
   

3. Utwórz plik o nazwie outputs.tf i wstaw następujący kod:

   output "container_ipv4_address" {
     value = azurerm_container_group.container.ip_address
   }
   

4. Utwórz plik o nazwie providers.tf i wstaw następujący kod:

   terraform {
     required_version = ">=1.0"
     required_providers {
       azurerm = {
         source  = "hashicorp/azurerm"
         version = "~>3.0"
       }
       random = {
         source  = "hashicorp/random"
         version = "~>3.0"
       }
     }
   }
   provider "azurerm" {
     features {}
   }
   

5. Utwórz plik o nazwie variables.tf i wstaw następujący kod:

   variable "resource_group_location" {
     type        = string
     default     = "eastus"
     description = "Location for all resources."
   }
   
   variable "resource_group_name_prefix" {
     type        = string
     default     = "rg"
     description = "Prefix of the resource group name that's combined with a random value so name is unique in your Azure subscription."
   }
   
   variable "container_group_name_prefix" {
     type        = string
     description = "Prefix of the container group name that's combined with a random value so name is unique in your Azure subscription."
     default     = "acigroup"
   }
   
   variable "container_name_prefix" {
     type        = string
     description = "Prefix of the container name that's combined with a random value so name is unique in your Azure subscription."
     default     = "aci"
   }
   
   variable "image" {
     type        = string
     description = "Container image to deploy. Should be of the form repoName/imagename:tag for images stored in public Docker Hub, or a fully qualified URI for other registries. Images from private registries require additional registry credentials."
     default     = "mcr.microsoft.com/azuredocs/aci-helloworld"
   }
   
   variable "port" {
     type        = number
     description = "Port to open on the container and the public IP address."
     default     = 80
   }
   
   variable "cpu_cores" {
     type        = number
     description = "The number of CPU cores to allocate to the container."
     default     = 1
   }
   
   variable "memory_in_gb" {
     type        = number
     description = "The amount of memory to allocate to the container in gigabytes."
     default     = 2
   }
   
   variable "restart_policy" {
     type        = string
     description = "The behavior of Azure runtime if container has stopped."
     default     = "Always"
     validation {
       condition     = contains(["Always", "Never", "OnFailure"], var.restart_policy)
       error_message = "The restart_policy must be one of the following: Always, Never, OnFailure."
     }
   }
   
   variable "zone" {
       type        = string
       description = "The availability zone to deploy the container group into. If not specified, the container group is nonzonal and might be deployed into any zone."
       default     = ""
   }
   

6. Aby uczynić grupę kontenerów strefową, ustaw wartość zmiennej zone na logiczną strefę dostępności, do której chcesz ją wdrożyć.

   Ważne

   Grupy kontenerów strefowych są dostępne tylko w regionach, które obsługują strefy dostępności. Aby sprawdzić, czy region obsługuje strefy dostępności, zobacz Lista regionów platformy Azure.

Inicjowanie narzędzia Terraform

Uruchom narzędzie terraform init, aby zainicjować wdrożenie narzędzia Terraform. Polecenie to pobiera dostawcę Azure wymaganego do zarządzania zasobami Azure.

terraform init -upgrade

Kluczowe punkty:

• Parametr -upgrade uaktualnia niezbędne wtyczki dostawcy do najnowszej wersji, która jest zgodna z ograniczeniami wersji konfiguracji.

Tworzenie planu wykonania programu Terraform

Uruchom terraform plan, aby utworzyć plan wykonania.

terraform plan -out main.tfplan

Kluczowe punkty:

• Polecenie terraform plan tworzy plan wykonania, ale nie wykonuje go. Zamiast tego określa, jakie akcje są niezbędne do utworzenia konfiguracji określonej w plikach konfiguracji. Ten wzorzec umożliwia sprawdzenie, czy plan wykonania jest zgodny z oczekiwaniami przed wprowadzeniem jakichkolwiek zmian w rzeczywistych zasobach.
• Opcjonalny parametr -out umożliwia określenie pliku wyjściowego dla planu. Użycie parametru -out gwarantuje, że sprawdzony plan jest dokładnie tym, co jest stosowane.

Zastosowanie planu wykonawczego Terraform

Uruchom terraform apply, aby zastosować plan wykonania do infrastruktury chmury.

terraform apply main.tfplan

Kluczowe punkty:

• Polecenie terraform apply w przykładzie zakłada, że wcześniej uruchomiono terraform plan -out main.tfplan.
• Jeśli określono inną nazwę pliku dla parametru -out, użyj tej samej nazwy pliku w wywołaniu terraform apply.
• Jeśli nie użyłeś parametru -out, wywołaj terraform apply bez żadnych parametrów.

Weryfikowanie wyników

1. Po zastosowaniu planu wykonania narzędzie Terraform zwraca publiczny adres IP. Aby ponownie wyświetlić adres IP, uruchom terraform output.

   terraform output -raw container_ipv4_address
   

2. Wprowadź publiczny adres IP przykładu na pasku adresu przeglądarki.

   

Czyszczenie zasobów

Jeśli zasoby utworzone za pomocą narzędzia Terraform nie są już potrzebne, wykonaj następujące czynności:

1. Uruchom terraform plan i określ flagę destroy .

   terraform plan -destroy -out main.destroy.tfplan
   

   Kluczowe punkty:

   • Polecenie terraform plan tworzy plan wykonania, ale nie wykonuje go. Zamiast tego określa, jakie akcje są niezbędne do utworzenia konfiguracji określonej w plikach konfiguracji. Ten wzorzec umożliwia sprawdzenie, czy plan wykonania jest zgodny z oczekiwaniami przed wprowadzeniem jakichkolwiek zmian w rzeczywistych zasobach.
   • Opcjonalny parametr -out umożliwia określenie pliku wyjściowego dla planu. Użycie parametru -out gwarantuje, że sprawdzony plan jest dokładnie tym, co jest stosowane.

2. Uruchom terraform apply, aby wykonać plan.

   terraform apply main.destroy.tfplan
   

Rozwiązywanie problemów z programem Terraform na platformie Azure

Rozwiązywanie typowych problemów podczas korzystania z narzędzia Terraform na platformie Azure

Następne kroki