Let statement

Applies to: ✅Microsoft Fabric✅Azure Data Explorer✅Azure Monitor✅Microsoft Sentinel

A let statement is used to set a variable name equal to an expression or a function, or to create views.

let instrukcje są przydatne w następujących celach:

• Podzielenie złożonego wyrażenia na wiele części, z których każda jest reprezentowana przez zmienną.
• Definiowanie stałych poza treścią zapytania w celu zapewnienia czytelności.
• Definiowanie zmiennej raz i używanie jej wiele razy w zapytaniu.

Jeśli zmienna wcześniej reprezentowała inną wartość, na przykład w instrukcjach zagnieżdżonych, stosuje się najbardziej let wewnętrzną instrukcję.

Aby zoptymalizować wiele zastosowań instrukcji let w ramach jednego zapytania, zobacz Optymalizowanie zapytań używających nazwanych wyrażeń.

Składnia: wyrażenia skalarne lub tabelaryczne

let Name=Expression

Learn more about syntax conventions.

Parameters

Składnia: Wyświetlanie lub funkcja

let Name= [view] ([ Parameters ]){FunctionBody}

Learn more about syntax conventions.

Parameters

Examples

Przykłady zapytań pokazują składnię i przykładowe użycie operatora, instrukcji lub funkcji.

Definiowanie wartości skalarnych

W poniższym przykładzie użyto instrukcji wyrażenia skalarnego.

let threshold = 50;
let region = "West";
datatable(Name:string, Score:int, Region:string)
[
    "Alice", 45, "West",
    "Bob", 60, "East",
    "Charlie", 55, "West",
    "Dana", 70, "North"
]
| where Score > threshold and Region == region

Output

Definiowanie wyrażeń tabelarycznych

Poniższy przykład wiąże nazwę some number przy użyciu ['name'] notacji, a następnie używa jej w instrukcji wyrażenia tabelarycznego.

let ['some number'] = 20;
range y from 0 to ['some number'] step 5

Output

Tworzenie funkcji zdefiniowanej przez użytkownika przy użyciu obliczeń skalarnych

W tym przykładzie użyto instrukcji let z argumentami dla obliczeń skalarnych. Zapytanie definiuje funkcję MultiplyByN mnożenia dwóch liczb.

let MultiplyByN = (val:long, n:long) { val * n };
range x from 1 to 5 step 1 
| extend result = MultiplyByN(x, 5)

Output

Tworzenie funkcji zdefiniowanej przez użytkownika, która przycina dane wejściowe

Poniższy przykład usuwa wiodące i końcowe z danych wejściowych.

let TrimOnes = (s:string) { trim("1", s) };
range x from 10 to 15 step 1 
| extend result = TrimOnes(tostring(x))

Output

Używanie wielu instrukcji let

W tym przykładzie zdefiniowano dwie instrukcje let, w których jedna instrukcja (foo2) używa innej (foo1).

let foo1 = (_start:long, _end:long, _step:long) { range x from _start to _end step _step};
let foo2 = (_step:long) { foo1(1, 100, _step)};
foo2(2) | count

Output

Tworzenie widoku lub tabeli wirtualnej

W tym przykładzie pokazano, jak utworzyć tabelęview lub za pomocą instrukcji let.

let Range10 = view () { range MyColumn from 1 to 10 step 1 };
let Range20 = view () { range MyColumn from 1 to 20 step 1 };
search MyColumn == 5

Output

Używanie funkcji materializowania

Funkcja materialize() umożliwia buforowanie wyników podzapytania w czasie wykonywania zapytania. Gdy używasz materialize() funkcji, dane są buforowane, a każde kolejne wywołanie wyniku używa buforowanych danych.

let TotalEventsbyLocation = StormEvents
| summarize TotalCount = count() by Location = BeginLocation;
let materializedScope = StormEvents
| summarize by EventType, Location = EndLocation;
let cachedResult = materialize(materializedScope);
cachedResult
| project EventType, Location
| join kind = inner
(
    cachedResult
    | project EventType, Location
)
on EventType
| where Location != ""
| summarize EventCount = count() by Location
| join kind = inner
    TotalEventsbyLocation
on $left.Location == $right.Location
| project Location, EventCount, TotalCount, Percentage = EventCount * 100.0 / TotalCount

Output

Używanie zagnieżdżonych instrukcji let

Zagnieżdżone instrukcje let są dozwolone, w tym w wyrażeniu funkcji zdefiniowanej przez użytkownika. Instrukcje i argumenty let mają zastosowanie zarówno w bieżącym, jak i wewnętrznym zakresie treści funkcji.

let start_time = ago(5h); 
let end_time = start_time + 2h; 
T | where Time > start_time and Time < end_time | ...

Tabelaryczny argument ze schematem

W poniższym przykładzie określono, że parametr T tabeli musi mieć kolumnę State typu string. Tabela T może również zawierać inne kolumny, ale nie można odwoływać się do nich w funkcji StateState , ponieważ nie są zadeklarowane.

let StateState=(T: (State: string)) { T | extend s_s=strcat(State, State) };
StormEvents
| invoke StateState()
| project State, s_s

Output

Argument tabelaryczny z symbolem wieloznacznym

Parametr T tabeli może mieć dowolny schemat, a funkcja CountRecordsInTable będzie działać.

let CountRecordsInTable=(T: (*)) { T | count };
StormEvents | invoke CountRecordsInTable()

Output