Wdrażanie obszaru roboczego przy użyciu narzędzia Terraform

Poniższa przykładowa konfiguracja używa dostawcy azurerm Terraform do wdrożenia obszaru roboczego Azure Databricks. Przyjęto założenie, że zalogowano się do platformy Azure (az login) na komputerze lokalnym przy użyciu użytkownika platformy Azure, który ma Contributor prawa do subskrypcji.

Aby uzyskać więcej informacji na temat azurerm wtyczki Terraform dla usługi Databricks, zobacz azurerm_databricks_workspace.

Konfiguracja prosta

terraform {
  required_providers {
    azurerm =  "~> 2.33"
    random = "~> 2.2"
  }
}

provider "azurerm" {
  features {}
}

variable "region" {
  type = string
  default = "westeurope"
}

resource "random_string" "naming" {
  special = false
  upper   = false
  length  = 6
}

data "azurerm_client_config" "current" {
}

data "external" "me" {
  program = ["az", "account", "show", "--query", "user"]
}

locals {
  prefix = "databricksdemo${random_string.naming.result}"
  tags = {
    Environment = "Demo"
    Owner       = lookup(data.external.me.result, "name")
  }
}

resource "azurerm_resource_group" "this" {
  name     = "${local.prefix}-rg"
  location = var.region
  tags     = local.tags
}

resource "azurerm_databricks_workspace" "this" {
  name                        = "${local.prefix}-workspace"
  resource_group_name         = azurerm_resource_group.this.name
  location                    = azurerm_resource_group.this.location
  sku                         = "premium"
  managed_resource_group_name = "${local.prefix}-workspace-rg"
  tags                        = local.tags
}

output "databricks_host" {
  value = "https://${azurerm_databricks_workspace.this.workspace_url}/"
}

Konfiguracja dostawcy

W obszarze Zarządzanie obszarami roboczymi usługi Databricks przy użyciu narzędzia Terraform użyj specjalnych konfiguracji dla platformy Azure:

provider "databricks" {
  host = azurerm_databricks_workspace.this.workspace_url
}