Szybki start: tworzenie profilu usługi Azure Traffic Manager przy użyciu narzędzia Terraform

W tym przewodniku szybkiego startu opisano, jak za pomocą narzędzia Terraform utworzyć profil usługi Traffic Manager z zewnętrznymi punktami końcowymi przy użyciu metody trasowania wydajnościowej.

Narzędzie Terraform umożliwia definiowanie, wyświetlanie wersji zapoznawczej i wdrażanie infrastruktury chmury. Za pomocą narzędzia Terraform tworzysz pliki konfiguracji przy użyciu składni HCL. Składnia listy HCL umożliwia określenie dostawcy chmury — takiego jak platforma Azure — oraz elementów tworzących infrastrukturę chmury. Po utworzeniu plików konfiguracji utworzysz plan wykonywania, który umożliwia wyświetlenie podglądu zmian infrastruktury przed ich wdrożeniem. Po zweryfikowaniu zmian należy zastosować plan wykonywania w celu wdrożenia infrastruktury.

Z tego artykułu dowiesz się, jak wykonywać następujące działania:

Wymagania wstępne

• Instalowanie i konfigurowanie programu Terraform

Implementowanie kodu narzędzia Terraform

1. Utwórz katalog, w którym chcesz przetestować i uruchomić przykładowy kod programu Terraform i utworzyć go jako bieżący katalog.

2. Utwórz plik o nazwie providers.tf i wstaw następujący kod:

   terraform {
     required_version = ">=1.0"
     required_providers {
       azurerm = {
         source  = "hashicorp/azurerm"
         version = "~>3.0"
       }
       random = {
         source  = "hashicorp/random"
         version = "~>3.0"
       }
     }
   }
   provider "azurerm" {
     features {}
   }
   

3. Utwórz plik o nazwie main.tf i wstaw następujący kod:

   resource "random_pet" "rg_name" {
     prefix = var.resource_group_name_prefix
   }
   
   resource "azurerm_resource_group" "rg" {
     name     = random_pet.rg_name.id
     location = var.resource_group_location
   }
   
   resource "random_string" "azurerm_traffic_manager_profile_name" {
     length  = 25
     upper   = false
     numeric = false
     special = false
   }
   
   resource "random_string" "azurerm_traffic_manager_profile_dns_config_relative_name" {
     length  = 10
     upper   = false
     numeric = false
     special = false
   }
   
   resource "azurerm_traffic_manager_profile" "profile" {
     name                   = random_string.azurerm_traffic_manager_profile_name.result
     resource_group_name    = azurerm_resource_group.rg.name
     traffic_routing_method = "Performance"
     dns_config {
       relative_name = random_string.azurerm_traffic_manager_profile_dns_config_relative_name.result
       ttl           = 30
     }
   
     monitor_config {
       protocol                    = "HTTPS"
       port                        = 443
       path                        = "/"
       expected_status_code_ranges = ["200-202", "301-302"]
     }
   }
   
   resource "azurerm_traffic_manager_external_endpoint" "endpoint1" {
     profile_id        = azurerm_traffic_manager_profile.profile.id
     name              = "endpoint1"
     target            = "www.contoso.com"
     endpoint_location = "eastus"
     weight            = 50
   }
   
   resource "azurerm_traffic_manager_external_endpoint" "endpoint2" {
     profile_id        = azurerm_traffic_manager_profile.profile.id
     name              = "endpoint2"
     target            = "www.fabrikam.com"
     endpoint_location = "westus"
     weight            = 50
   }
   

4. Utwórz plik o nazwie variables.tf i wstaw następujący kod:

   variable "resource_group_location" {
     type        = string
     description = "Location for all resources."
     default     = "eastus"
   }
   
   variable "resource_group_name_prefix" {
     type        = string
     description = "Prefix of the resource group name that's combined with a random ID so name is unique in your Azure subscription."
     default     = "rg"
   }
   

5. Utwórz plik o nazwie outputs.tf i wstaw następujący kod:

   output "resource_group_name" {
     value = azurerm_resource_group.rg.name
   }
   
   output "azurerm_traffic_manager_profile_name" {
     value = azurerm_traffic_manager_profile.profile.name
   }
   
   output "azurerm_traffic_manager_profile_fqdn" {
     value = azurerm_traffic_manager_profile.profile.fqdn
   }
   

Inicjowanie narzędzia Terraform

Uruchom narzędzie terraform init , aby zainicjować wdrożenie narzędzia Terraform. Polecenie to pobiera dostawcę Azure wymaganego do zarządzania zasobami Azure.

terraform init -upgrade

Kluczowe punkty:

• Parametr -upgrade uaktualnia niezbędne wtyczki dostawcy do najnowszej wersji, która jest zgodna z ograniczeniami wersji konfiguracji.

Tworzenie planu wykonania programu Terraform

Uruchom terraform plan, aby stworzyć plan wykonania.

terraform plan -out main.tfplan

Kluczowe punkty:

• Polecenie terraform plan tworzy plan wykonania, ale nie wykonuje go. Zamiast tego określa, jakie akcje są niezbędne do utworzenia konfiguracji określonej w plikach konfiguracji. Ten wzorzec umożliwia sprawdzenie, czy plan wykonania jest zgodny z oczekiwaniami przed wprowadzeniem jakichkolwiek zmian w rzeczywistych zasobach.
• Opcjonalny parametr -out umożliwia określenie pliku wyjściowego dla planu. Użycie parametru -out gwarantuje, że sprawdzony plan jest dokładnie tym, co jest stosowane.

Zastosuj plan wykonawczy Terraform

Uruchom terraform apply, aby zastosować plan wykonania do twojej infrastruktury chmurowej.

terraform apply main.tfplan

Kluczowe punkty:

• Przykładowe polecenie terraform apply zakłada, że wcześniej uruchomiono polecenie terraform plan -out main.tfplan.
• Jeśli określono inną nazwę pliku dla parametru -out, użyj tej samej nazwy pliku w wywołaniu terraform apply.
• Jeśli nie użyłeś parametru -out, wywołaj terraform apply bez żadnych parametrów.

Weryfikowanie wyników

Czyszczenie zasobów

Jeśli zasoby utworzone za pomocą narzędzia Terraform nie są już potrzebne, wykonaj następujące czynności:

1. Uruchom terraform plan oraz określ flagę destroy.

   terraform plan -destroy -out main.destroy.tfplan
   

   Kluczowe punkty:

   • Polecenie terraform plan tworzy plan wykonania, ale nie wykonuje go. Zamiast tego określa, jakie akcje są niezbędne do utworzenia konfiguracji określonej w plikach konfiguracji. Ten wzorzec umożliwia sprawdzenie, czy plan wykonania jest zgodny z oczekiwaniami przed wprowadzeniem jakichkolwiek zmian w rzeczywistych zasobach.
   • Opcjonalny parametr -out umożliwia określenie pliku wyjściowego dla planu. Użycie parametru -out gwarantuje, że sprawdzony plan jest dokładnie tym, co jest stosowane.

2. Uruchom terraform apply, aby zastosować plan wykonania.

   terraform apply main.destroy.tfplan
   

Rozwiązywanie problemów z programem Terraform na platformie Azure

Rozwiązywanie typowych problemów podczas korzystania z narzędzia Terraform na platformie Azure

Następne kroki