Udostępnij przez

Najlepsze rozwiązania dotyczące metodyki FinOps dla usługi Storage

W tym artykule opisano kolekcję sprawdzonych rozwiązań FinOps dotyczących usług magazynowania. Udostępnia strategie optymalizacji kosztów, poprawy wydajności i używania zapytań usługi Azure Resource Graph (ARG) w celu uzyskania wglądu w zasoby magazynu. Postępując zgodnie z tymi rozwiązaniami, możesz upewnić się, że usługi magazynowania są opłacalne i dostosowane do celów finansowych organizacji.


Wykonywanie kopii zapasowej

W poniższych sekcjach przedstawiono zapytania ARG dotyczące usług kopii zapasowych. Te zapytania ułatwiają uzyskanie wglądu w zasoby kopii zapasowej i upewnienie się, że zostały skonfigurowane przy użyciu odpowiednich ustawień. Analizując elementy kopii zapasowej i identyfikując bezczynne kopie zapasowe, można zoptymalizować usługi tworzenia kopii zapasowych pod kątem wydajności kosztów.

Zapytanie: bezczynne kopie zapasowe

To zapytanie usługi ARG analizuje elementy kopii zapasowej w ramach magazynów usługi Azure Recovery Services i identyfikuje wszystkie, których kopia zapasowa nie została utworzona przez ponad 90 dni.

Kategoria

Optymalizacja

Zapytanie

recoveryservicesresources
| where type =~ 'microsoft.recoveryservices/vaults/backupfabrics/protectioncontainers/protecteditems'
| extend vaultId = tostring(properties.vaultId)
| extend resourceId = tostring(properties.sourceResourceId)
| extend idleBackup= datetime_diff('day', now(), todatetime(properties.lastBackupTime)) > 90
| extend  resourceType=tostring(properties.workloadType)
| extend protectionState=tostring(properties.protectionState)
| extend lastBackupTime=tostring(properties.lastBackupTime)
| extend resourceGroup=strcat('/subscriptions/',subscriptionId,'/resourceGroups/',resourceGroup)
| extend lastBackupDate=todatetime(properties.lastBackupTime)
| where idleBackup != 0
| project resourceId,vaultId,idleBackup,lastBackupDate,resourceType,protectionState,lastBackupTime,location,resourceGroup,subscriptionId

Zapytanie: Lista skarbców usługi Recovery Services

To zapytanie usługi Azure Resource Graph (ARG) pobiera szczegóły skrytek usługi Azure Recovery Services. Zapytanie zawiera również informacje dotyczące warstwy jednostki SKU, ustawień nadmiarowości i innych odpowiednich metadanych.

Kategoria

Optymalizacja

Zapytanie

resources
| where type == 'microsoft.recoveryservices/vaults'
| where resourceGroup in ({ResourceGroup})
| extend skuTier = tostring(sku['tier'])
| extend skuName = tostring(sku['name'])
| extend resourceGroup = strcat('/subscriptions/', subscriptionId, '/resourceGroups/', resourceGroup)
| extend redundancySettings = tostring(properties.redundancySettings['standardTierStorageRedundancy'])
| order by id asc
| project id, redundancySettings, resourceGroup, location, subscriptionId, skuTier, skuName

Dyski

W poniższych sekcjach przedstawiono zapytania ARG dotyczące usług dysków. Te zapytania ułatwiają uzyskanie wglądu w zasoby dysku i upewnienie się, że zostały skonfigurowane przy użyciu odpowiednich ustawień. Analizując migawki dysków i identyfikując dyski bezczynne, można zoptymalizować usługi dysków pod kątem wydajności kosztów.

Zapytanie: dyski bezczynne

To zapytanie usługi ARG identyfikuje bezczynne lub niedołączone dyski zarządzane w środowisku platformy Azure.

Kategoria

Optymalizacja

Zapytanie

resources
| where type =~ 'microsoft.compute/disks' and managedBy == ""
| extend diskState = tostring(properties.diskState)
| where managedBy == ""
    and diskState != 'ActiveSAS'
    and tags !contains 'ASR-ReplicaDisk'
    and tags !contains 'asrseeddisk'
| extend DiskId=id, DiskIDfull=id, DiskName=name, SKUName=sku.name, SKUTier=sku.tier, DiskSizeGB=tostring(properties.diskSizeGB), Location=location, TimeCreated=tostring(properties.timeCreated), SubId=subscriptionId
| order by DiskId asc 
| project DiskId, DiskIDfull, DiskName, DiskSizeGB, SKUName, SKUTier, resourceGroup, Location, TimeCreated, subscriptionId

Zapytanie: migawka dysku starsza niż 30 dni

To zapytanie ARG identyfikuje migawki dysku, które są starsze niż 30 dni.

Kategoria

Optymalizacja

Zapytanie

resources
| where type == 'microsoft.compute/snapshots'
| extend TimeCreated = properties.timeCreated
| extend resourceGroup = strcat("/subscriptions/",subscriptionId,"/resourceGroups/",resourceGroup)
| where TimeCreated < ago(30d)
| order by id asc 
| project id, resourceGroup, location, TimeCreated, subscriptionId

Zapytanie: migawka korzystająca z usługi Premium Storage

To zapytanie ARG identyfikuje migawki dysków, które korzystają z magazynu w warstwie Premium.

Kategoria

Optymalizacja

Zapytanie

resources
| where type == 'microsoft.compute/snapshots'
| extend
    StorageSku = tostring(sku.tier),
    resourceGroup = strcat('/subscriptions/',subscriptionId,'/resourceGroups/',resourceGroup),
    diskSize = tostring(properties.diskSizeGB)
| where StorageSku == "Premium"
| project id, name, StorageSku, diskSize, location, resourceGroup, subscriptionId

Konta magazynu

W poniższej sekcji przedstawiono zapytanie ARG dotyczące kont magazynu. Pomaga to uzyskać wgląd w zasoby magazynu i upewnić się, że są one skonfigurowane przy użyciu odpowiednich ustawień. Analizując konta magazynu i identyfikując starsze typy kont magazynu, można zoptymalizować usługi magazynu pod kątem wydajności kosztów.

Zapytanie: konto magazynowe w wersji 1

To zapytanie usługi ARG identyfikuje konta magazynu, które nadal korzystają ze starszego typu w wersji 1, co może nie zapewniać tych samych funkcji i wydajności co nowsze typy kont magazynu.

Kategoria

Optymalizacja

Zapytanie

resources
| where type =~ 'Microsoft.Storage/StorageAccounts'
    and kind !='StorageV2'
    and kind !='FileStorage'
| where resourceGroup in ({ResourceGroup})
| extend
    StorageAccountName = name,
    SAKind = kind,
    AccessTier = tostring(properties.accessTier),
    SKUName = sku.name,
    SKUTier = sku.tier,
    Location = location
| order by id asc
| project
    id,
    StorageAccountName,
    SKUName,
    SKUTier,
    SAKind,
    AccessTier,
    resourceGroup,
    Location,
    subscriptionId

Prześlij opinię

Daj nam znać, jak nam idzie, zostawiając krótką opinię. Te recenzje służą do ulepszania i rozszerzania narzędzi i zasobów FinOps.

Przesyłanie opinii

Jeśli szukasz czegoś konkretnego, zagłosuj na istniejący lub utwórz nowy pomysł. Podziel się pomysłami z innymi osobami, aby uzyskać więcej głosów. Skupiamy się na pomysłach z największą większością głosów.

Głosuj na pomysły lub sugeruj własne


Powiązana zawartość

Powiązane zasoby:

Powiązane rozwiązania:


  • Last updated on