bag_unpack, wtyczka

Dotyczy: ✅Microsoft Fabric✅Azure Data Explorer

Wtyczka bag_unpack rozpakuje pojedynczą kolumnę typu dynamic, traktując każde gniazdo najwyższego poziomu właściwości jako kolumnę. Wtyczka jest wywoływana z operatorem evaluate .

Składnia

T|evaluatebag_unpack( Column [,OutputColumnPrefix ] [,columnsConflict ] [,ignoredProperties ] ) [:OutputSchema]

Dowiedz się więcej na temat konwencji składni.

Parametry

Składnia schematu wyjściowego

( Nazwakolumny:ColumnType [, ...])

Użyj symbolu wieloznakowego * jako pierwszego parametru, aby uwzględnić wszystkie kolumny tabeli źródłowej w danych wyjściowych w następujący sposób:

( * , ColumnName:ColumnType [, ...])

Zagadnienia dotyczące wydajności

Korzystanie z wtyczki bez elementu OutputSchema może mieć poważne konsekwencje dla wydajności w dużych zestawach danych i należy go unikać.

Udostępnienie modułu OutputSchema umożliwia aparatowi zapytań optymalizowanie wykonywania zapytań, ponieważ może określić schemat wyjściowy bez konieczności analizowania i analizowania danych wejściowych. Dane wyjścioweSchema są korzystne, gdy dane wejściowe są duże lub złożone. Zapoznaj się z przykładami z wpływem na wydajność korzystania z wtyczki z elementem OutputSchema i bez zdefiniowanego elementu OutputSchema.

Zwraca

Wtyczka bag_unpack zwraca tabelę z dowolną liczbą rekordów w postaci danych wejściowych tabelarycznych (T). Schemat tabeli jest taki sam jak schemat danych wejściowych tabelarycznych z następującymi modyfikacjami:

• Określona kolumna wejściowa (kolumna) jest usuwana.
• Nazwa każdej kolumny odpowiada nazwie każdego miejsca, opcjonalnie poprzedzonego prefiksem OutputColumnPrefix.
• Typ każdej kolumny jest typem gniazda, jeśli wszystkie wartości tego samego miejsca mają ten sam typ lub dynamic, jeśli wartości różnią się typem.
• Schemat jest rozszerzony o dowolną liczbę kolumn, ponieważ istnieją różne gniazda w wartościach torby właściwości najwyższego poziomu T.

Reguły schematu tabelarycznego mają zastosowanie do danych wejściowych. W szczególności:

• Nazwa kolumny wyjściowej nie może być taka sama jak istniejąca kolumna w tabelarycznych danych wejściowych T, chyba że jest to kolumna do rozpakowania (kolumna). W przeciwnym razie dane wyjściowe zawierają dwie kolumny o tej samej nazwie.
• Wszystkie nazwy miejsc, jeśli są poprzedzone prefiksem OutputColumnPrefix, muszą być prawidłowe nazwy jednostek i postępować zgodnie z regułami nazewnictwa identyfikatorów.

Wtyczka ignoruje wartości null.

Przykłady

W przykładach w tej sekcji pokazano, jak używać składni, aby ułatwić rozpoczęcie pracy.

Rozwiń torbę:

datatable(d:dynamic)
[
    dynamic({"Name": "John", "Age":20}),
    dynamic({"Name": "Dave", "Age":40}),
    dynamic({"Name": "Jasmine", "Age":30}),
]
| evaluate bag_unpack(d)

Wyjście

Rozwiń torbę i użyj OutputColumnPrefix opcji , aby utworzyć nazwy kolumn z prefiksem:

datatable(d:dynamic)
[
    dynamic({"Name": "John", "Age":20}),
    dynamic({"Name": "Dave", "Age":40}),
    dynamic({"Name": "Jasmine", "Age":30}),
]
| evaluate bag_unpack(d, 'Property_')

Wyjście

Rozwiń torbę i użyj columnsConflict opcji , aby rozwiązać konflikt kolumny między kolumną dynamiczną a istniejącą kolumną:

datatable(Name:string, d:dynamic)
[
    'James', dynamic({"Name": "John", "Age":20}),
    'David', dynamic({ "Age":40}),
    'Emily', dynamic({"Name": "Jasmine", "Age":30}),
]
| evaluate bag_unpack(d, columnsConflict='replace_source') // Replace old column Name by new column

Wyjście

datatable(Name:string, d:dynamic)
[
    'James', dynamic({"Name": "John", "Age":20}),
    'David', dynamic({"Name": "Dave", "Age":40}),
    'Emily', dynamic({"Name": "Jasmine", "Age":30}),
]
| evaluate bag_unpack(d, columnsConflict='keep_source') // Keep old column Name

Wyjście

Rozwiń torbę i użyj ignoredProperties opcji , aby zignorować 2 właściwości w torbie właściwości:

datatable(d:dynamic)
[
    dynamic({"Name": "John", "Age":20, "Address": "Address-1" }),
    dynamic({"Name": "Dave", "Age":40, "Address": "Address-2"}),
    dynamic({"Name": "Jasmine", "Age":30, "Address": "Address-3"}),
]
// Ignore 'Age' and 'Address' properties
| evaluate bag_unpack(d, ignoredProperties=dynamic(['Address', 'Age']))

Wyjście

Rozwiń torbę i użyj opcji OutputSchema:

datatable(d:dynamic)
[
    dynamic({"Name": "John", "Age":20}),
    dynamic({ "Name": "Dave", "Height": 170, "Age":40}),
    dynamic({"Name": "Jasmine", "Age":30}),
]
| evaluate bag_unpack(d)

Wyjście

Rozwiń torbę za pomocą elementu OutputSchema i użyj opcji symboli wieloznacznych*:

To zapytanie zwraca oryginalny opis miejsca i kolumny zdefiniowane w outputSchema.

datatable(d:dynamic, Description: string)
[
    dynamic({"Name": "John", "Age":20, "height":180}), "Student",
    dynamic({"Name": "Dave", "Age":40, "height":160}), "Teacher",
    dynamic({"Name": "Jasmine", "Age":30, "height":172}), "Student",
]
| evaluate bag_unpack(d) : (*, Name:string, Age:long)

Wyjście

Przykłady z implikacjami wydajności

Rozwiń torbę i bez zdefiniowanej wartości OutputSchema , aby porównać implikacje dotyczące wydajności:

W tym przykładzie użyto publicznie dostępnej tabeli w klastrze pomocy. W bazie danych ContosoSales istnieje tabela o nazwie SalesDynamic. Tabela zawiera dane sprzedaży i zawiera kolumnę dynamiczną o nazwie Customer_Properties.

• Przykład bez schematu wyjściowego: pierwsze zapytanie nie definiuje elementu OutputSchema. Zapytanie trwa 5,84 sekundy procesora CPU i skanuje 36,39 MB danych.

  Uruchamianie zapytania

  SalesDynamic
  | evaluate bag_unpack(Customer_Properties) 
  | summarize Sales=sum(SalesAmount) by Country, State
  

• Przykład ze schematem danych wyjściowych: drugie zapytanie udostępnia parametr OutputSchema. Zapytanie trwa 0,45 sekund procesora CPU i skanuje 19,31 MB danych. Zapytanie nie musi analizować tabeli wejściowej, co pozwala zaoszczędzić czas przetwarzania.

  Uruchamianie zapytania

  SalesDynamic
  | evaluate bag_unpack(Customer_Properties) :  (*, Country:string, State:string, City:string)
  | summarize Sales=sum(SalesAmount) by Country, State
  

Wyjście

Dane wyjściowe są takie same dla obu zapytań. Poniżej przedstawiono pierwsze 10 wierszy danych wyjściowych.

Powiązana zawartość

• parse_json funkcji
• operator mv-expand
• pack-all, funkcja