Udostępnij przez

geo_point_in_circle()

Dotyczy: ✅Microsoft Fabric✅Azure Data Explorer✅Azure Monitor✅Microsoft Sentinel

Oblicza, czy współrzędne geoprzestrzenne znajdują się wewnątrz okręgu na Ziemi.

Składnia

geo_point_in_circle(, p_longitude p_latitude, pc_longitude pc_latitude c_radius,, )

Dowiedz się więcej na temat konwencji składni.

Parametry

Nazwisko Type Wymagania opis
p_longitude real ✔️ Wartość współrzędnych współrzędnych geoprzestrzennych w stopniach. Prawidłowa wartość to liczba rzeczywista i w zakresie [-180, +180].
p_latitude real ✔️ Współrzędna geograficzna współrzędnych współrzędnych geograficznych w stopniach. Prawidłowa wartość to liczba rzeczywista i w zakresie [-90, +90].
pc_longitude real ✔️ Wartość współrzędnych współrzędnych geoprzestrzennych w stopniach w centrum okręgu. Prawidłowa wartość to liczba rzeczywista i w zakresie [-180, +180].
pc_latitude real ✔️ szerokość geograficzna współrzędnych współrzędnych w stopniach. Prawidłowa wartość to liczba rzeczywista i w zakresie [-90, +90].
c_radius real ✔️ Promień okręgu w metrach. Prawidłowa wartość musi być dodatnia.

Zwraca

Wskazuje, czy współrzędne geoprzestrzenne znajdują się wewnątrz okręgu. Jeśli współrzędne lub okrąg są nieprawidłowe, zapytanie generuje wynik o wartości null.

Uwaga

Przykłady

Poniższy przykład znajduje wszystkie miejsca w obszarze zdefiniowanym przez następujące koło: Promień 18 km, środek o współrzędnych [-122.317404, 47.609119].

Zrzut ekranu przedstawiający mapę z miejscami w odległości 18 km od Seattle.

Uruchamianie zapytania

datatable(longitude:real, latitude:real, place:string)
[
    real(-122.317404), 47.609119, 'Seattle',                   // In circle 
    real(-123.497688), 47.458098, 'Olympic National Forest',   // In exterior of circle  
    real(-122.201741), 47.677084, 'Kirkland',                  // In circle
    real(-122.443663), 47.247092, 'Tacoma',                    // In exterior of circle
    real(-122.121975), 47.671345, 'Redmond',                   // In circle
]
| where geo_point_in_circle(longitude, latitude, -122.317404, 47.609119, 18000)
| project place

Wyjście

place (miejsce)
Seattle
Kirkland
Redmond

Poniższy przykład znajduje zdarzenia burze w Orlando. Zdarzenia są filtrowane według współrzędnych Orlando o 100 km i agregowane według typu zdarzenia i skrótu.

Uruchamianie zapytania

StormEvents
| project BeginLon, BeginLat, EventType
| where geo_point_in_circle(BeginLon, BeginLat, real(-81.3891), 28.5346, 1000 * 100)
| summarize count() by EventType, hash = geo_point_to_s2cell(BeginLon, BeginLat)
| project geo_s2cell_to_central_point(hash), EventType, count_
| render piechart with (kind=map) // map pie rendering available in Kusto Explorer desktop

Wyjście

Zrzut ekranu przedstawiający zdarzenia burzy w Orlando renderowane z punktami wykresu kołowego na mapie.

W poniższym przykładzie pokazano w nowym Jorku odbióry taksówek w odległości 10 metrów od określonej lokalizacji. Odpowiednie odbiory są agregowane przez skrót.

Uruchamianie zapytania

nyc_taxi
| project pickup_longitude, pickup_latitude
| where geo_point_in_circle( pickup_longitude, pickup_latitude, real(-73.9928), 40.7429, 10)
| summarize by hash = geo_point_to_s2cell(pickup_longitude, pickup_latitude, 22)
| project geo_s2cell_to_central_point(hash)
| render scatterchart with (kind = map)

Wyjście

Zrzut ekranu przedstawiający renderowaną mapę przedstawiającą pobliskie odbióry taksówek w Nowym Jorku zgodnie z definicją w zapytaniu.

Poniższy przykład zwraca wartość true.

Uruchamianie zapytania

print in_circle = geo_point_in_circle(-122.143564, 47.535677, -122.100896, 47.527351, 3500)

Wyjście

in_circle
prawda

Poniższy przykład zwraca wartość false.

Uruchamianie zapytania

print in_circle = geo_point_in_circle(-122.137575, 47.630683, -122.100896, 47.527351, 3500)

Wyjście

in_circle
fałsz

Poniższy przykład zwraca wynik o wartości null z powodu nieprawidłowych danych wejściowych współrzędnych.

Uruchamianie zapytania

print in_circle = geo_point_in_circle(200, 1, 1, 1, 1)

Wyjście

in_circle

Poniższy przykład zwraca wynik o wartości null z powodu nieprawidłowych danych wejściowych promienia okręgu.

Uruchamianie zapytania

print in_circle = geo_point_in_circle(1, 1, 1, 1, -1)

Wyjście

in_circle
  • Last updated on