Podstawy eksploracji grafu

Dotyczy: ✅Microsoft Fabric✅Azure Data Explorer

Ta strona zawiera wzorce języka KQL (Reusable Kusto Query Language) umożliwiające szybkie eksplorowanie zestawów danych grafu i odpowiadanie na typowe pytania dotyczące struktury, węzłów, krawędzi i właściwości.

Typowe zapytania analizy

Te wzorce zapytań wielokrotnego użytku działają we wszystkich modelach grafów i pomagają zrozumieć strukturę i charakterystykę dowolnego zestawu danych grafu. W poniższym przykładzie użyto przykładowych wykresów dostępnych w naszym klastrze pomocy w bazie danych Przykłady . Aby uzyskać szczegółowe informacje na temat tych wykresów, zobacz Przykładowe zestawy danych i przykłady programu Graph. Użyj tych zapytań, aby eksplorować nowe grafy, wykonywać podstawowe analizy lub jako punkty wyjścia dla bardziej złożonych badań grafów.

Omówienie wykresu i statystyki

Zrozumienie podstawowych cech grafu jest niezbędne do planowania analizy i optymalizacji wydajności. Te zapytania udostępniają podstawowe metryki dotyczące rozmiaru i struktury grafu.

Zlicz łączną liczbę węzłów i krawędzi:

Użyj tych zapytań, aby zrozumieć skalę zestawu danych grafu. Liczniki węzłów i krawędzi pomagają określić odpowiednie strategie zapytań i zidentyfikować potencjalne zagadnienia dotyczące wydajności. W tych przykładach użyto Simple grafu, który jest idealny do uczenia się podstawowych operacji grafu.

// Get node count
graph('Simple')
| graph-match (node)
    project node
| count

// Get edge count
graph('Simple')
| graph-match (source)-[edge]->(target)
    project edge
| count

Pobierz statystyki podsumowania grafu:

To połączone zapytanie wydajnie zapewnia zarówno metryki w jednym wyniku, co jest przydatne do początkowej oceny grafu i raportowania. W tym przykładzie przedstawiono technikę Simple przy użyciu grafu.

let nodes = view() { graph('Simple') | graph-match (node) project node | count }; 
let edges = view() { graph('Simple') | graph-match (source)-[edge]->(target) project edge | count };
union withsource=['Graph element'] nodes, edges

Alternatywa przy użyciu wykresu do tabeli:

W przypadku zliczania podstawowego graph-to-table operator może być bardziej wydajny, ponieważ bezpośrednio eksportuje elementy grafu bez dopasowywania wzorców. W tym przykładzie przedstawiono alternatywne podejście przy użyciu tego samego Simple grafu.

let nodes = view() { graph('Simple') | graph-to-table nodes | count };
let edges = view() { graph('Simple') | graph-to-table edges | count };
union nodes, edges

Analiza węzła

Analiza węzła pomaga zrozumieć jednostki na grafie, ich typy i dystrybucję. Te wzorce są niezbędne do oceny jakości danych i zrozumienia schematu.

Odnajdź wszystkie typy węzłów (etykiety)::

To zapytanie ujawnia różne typy jednostek na grafie i ich częstotliwości. Użyj go, aby zrozumieć model danych, zidentyfikować najbardziej typowe typy jednostek i wykryć potencjalne problemy z jakością danych. W tym przykładzie użyto grafu zawierającego Simplejednostki Person, Company i City.

graph('Simple')
| graph-match (node) 
    project labels = labels(node)
| mv-expand label = labels to typeof(string)
| summarize count() by label
| order by count_ desc

Znajdź węzły z wieloma etykietami:

Identyfikuje węzły należące jednocześnie do wielu kategorii. Jest to przydatne do zrozumienia nakładających się klasyfikacji i złożonych relacji jednostek w modelu danych. W tym przykładzie użyto grafu zawierającego BloodHound_Entraobiekty Firmy Microsoft Entra z wieloma klasyfikacjami etykiet.

graph('BloodHound_Entra')
| graph-match (node) 
    project node_id = node.id, labels = labels(node), label_count = array_length(labels(node))
| where label_count > 1
| take 3

Przykładowe węzły według typu:

Pobiera reprezentatywne przykłady określonych typów węzłów, aby zrozumieć ich strukturę i właściwości. Niezbędne do eksploracji danych i tworzenia zapytań. W tym przykładzie użytoBloodHound_Entra grafu do eksplorowania właściwości węzła AZUser w środowiskach Firmy Microsoft Entra.

graph('BloodHound_Entra')
| graph-match (node) 
    where labels(node) has "AZUser"
    project node_id = node.id, properties = node.properties
| sample 2

Analiza krawędzi

Zrozumienie relacji na grafie ma kluczowe znaczenie dla identyfikowania wzorców, problemów z jakością danych i potencjalnych wskazówek analizy.

Odnajdź wszystkie typy krawędzi (działa z różnymi schematami grafu):

To zapytanie identyfikuje wszystkie typy relacji na grafie, pomagając zrozumieć połączenia dostępne do analizy. Różne grafy używają różnych nazw właściwości dla typów krawędzi, więc podano wiele odmian. W tym przykładzie użytoBloodHound_Entra grafu w celu wyświetlenia relacji uprawnień w środowiskach firmy Microsoft Entra.

graph('BloodHound_Entra')
| graph-match (source)-[edge]->(target)
    project edge_labels = labels(edge)
| mv-expand label = edge_labels to typeof(string)
| summarize count() by label
| top 5 by count_ desc

Znajdź większość połączonych węzłów (najwyższy stopień):

Analiza stopnia węzła ujawnia najbardziej wpływowe lub centralne jednostki na wykresie. Węzły wysokiego stopnia często reprezentują kluczowe elementy, wąskie gardła lub ważne składniki infrastruktury. W tym przykładzie użyto grafu , zestawu danych sieci społecznościowych idealnego LDBC_SNB_Interactivedo analizowania wzorców połączeń i wpływu.

// Find nodes with highest total degree (in + out)
graph('LDBC_SNB_Interactive')
| graph-match (node)
    project node_id = node.id, 
            in_degree = node_degree_in(node),
            out_degree = node_degree_out(node),
            total_degree = node_degree_in(node) + node_degree_out(node)
| order by total_degree desc
| take 5

Znajdź węzły o najwyższym stopniu (większość połączeń przychodzących)::

Węzły o wysokim stopniu są często obiektami docelowymi wpływu, popularnymi miejscami docelowymi lub zasobami centralnymi. W sieciach społecznościowych mogą to być wpływowe osoby; w grafach infrastruktury mogą to być usługi krytyczne. W tym przykładzie użytoLDBC_Financial grafu, aby zidentyfikować konta odbierające najwięcej transakcji.

graph('LDBC_Financial')
| graph-match (node)
    project node_id = node.node_id, 
            node_labels = labels(node),
            in_degree = node_degree_in(node)
| order by in_degree desc
| take 3

Znajdź węzły o najwyższym poziomie wychodzącym (większość połączeń wychodzących)::

Węzły wysokiego poziomu są często źródłami wpływu, dystrybutorów lub koncentratorów łączników. Te jednostki zazwyczaj inicjują wiele relacji lub dystrybuują zasoby do innych. W tym przykładzie użyto LDBC_Financial grafu , aby zidentyfikować konta, które najwięcej transakcji.

graph('LDBC_Financial')
| graph-match (node)
    project node_id = node.node_id, 
            node_labels = labels(node),
            out_degree = node_degree_out(node)
| order by out_degree desc
| take 3

Analiza wzorca relacji

Te zapytania ułatwiają identyfikowanie wzorców strukturalnych i złożonych relacji, które mogą wskazywać na ważne zachowania lub anomalie w danych.

Odnajdź relacje trójkątne (węzły połączone w trójkącie):

Trójkątne wzorce często wskazują na ścisłą współpracę, wzajemne zależności lub procesy zamkniętej pętli. W sieciach społecznościowych reprezentują one grupy przyjaciół; w procesach biznesowych mogą wskazywać łańcuchy zatwierdzania lub wzorce nadmiarowości. W tym przykładzie użytoBloodHound_AD grafu do identyfikowania relacji uprawnień cyklicznych w środowiskach usługi Active Directory.

graph('BloodHound_AD')
| graph-match (a)-->(b)-->(c)-->(a)
    where a.id != b.id and b.id != c.id and c.id != a.id
    project node1 = a.name, node2 = b.name, node3 = c.name
| take 3

Analiza właściwości

Zrozumienie właściwości dostępnych w węzłach ułatwia tworzenie bardziej zaawansowanych zapytań i identyfikowanie problemów z jakością danych.

Eksplorowanie właściwości węzła:

To zapytanie ujawnia informacje przechowywane w węzłach, pomagając zrozumieć dostępne atrybuty do filtrowania i analizy. W tym przykładzie użytoBloodHound_Entra grafu do eksplorowania schematu węzłów AZUser i zrozumienia, jakie właściwości są dostępne dla obiektów użytkownika firmy Microsoft Entra.

graph('BloodHound_Entra')
| graph-match (node)
    where labels(node) has "AZUser"  // Replace with actual label
    project properties = node.properties
| mv-apply properties on (
        mv-expand kind=array properties
        | where isnotempty(properties[1])
        | extend bag =bag_pack(tostring(properties[0]), properties[1])
        | summarize properties = make_bag(bag)
    )
| summarize buildschema(properties)

Znajdź wszystkie właściwości wszystkich węzłów według etykiety:

To zaawansowane zapytanie odnajdywania schematu identyfikuje wszystkie nazwy właściwości, które istnieją w węzłach każdego typu etykiety. W przeciwieństwie do poprzedniego zapytania, które pokazuje strukturę schematu, to zapytanie agreguje nazwy właściwości we wszystkich węzłach tego samego typu, co pomaga zrozumieć, które właściwości są stale dostępne i które mogą być opcjonalne lub rzadkie. W tym przykładzie użyto grafu do eksplorowania pełnego krajobrazu LDBC_SNB_Interactive właściwości różnych typów jednostek w zestawie danych sieci społecznościowych.

graph('LDBC_SNB_Interactive')
| graph-match (node)
    project properties = node, labels = labels(node)
| mv-apply properties on (
        mv-expand kind=array properties
        | where isnotempty(properties[1])
        | summarize properties = make_set(properties[0])
    )
| mv-expand label = labels to typeof(string)
| summarize properties =make_set(properties) by label
| take 3

Znajdź wszystkie właściwości wszystkich krawędzi według etykiety:

To zapytanie wykonuje odnajdywanie schematu dla właściwości krawędzi (relacji), pokazując, jakie informacje są przechowywane z każdym typem relacji na grafie. Zrozumienie właściwości krawędzi ma kluczowe znaczenie dla analizowania metadanych relacji, takich jak znaczniki czasu, wagi, wyniki ufności lub inne atrybuty, które zapewniają kontekst połączeń. W tym przykładzie użytoBloodHound_AD grafu do eksplorowania właściwości dostępnych w różnych typach relacji uprawnień usługi Active Directory.

graph('BloodHound_AD')
| graph-match ()-[e]-()
    project properties = e, labels = labels(e)
| mv-apply properties on (
        mv-expand kind=array properties
        | where isnotempty(properties[1])
        | summarize properties = make_set(properties[0])
    )
| mv-expand label = labels to typeof(string)
| summarize properties =make_set(properties) by label
| take 3

Znajdź węzły z określonymi wartościami właściwości:

Użyj tego wzorca, aby zlokalizować jednostki o określonych cechach lub zweryfikować jakość danych, sprawdzając oczekiwane wartości właściwości. W tym przykładzie użyto grafu w celu znalezieniaBloodHound_Entra węzłów o określonych właściwościach nazw w środowiskach firmy Microsoft Entra.

graph('BloodHound_Entra')
| graph-match (node)
    where isnotempty(node.properties.name)
    project node_id = node.id, property_value = node.properties.name
| take 3

Topologia grafu

Zrozumienie ogólnej topologii grafu ujawnia typy połączeń, które istnieją między różnymi typami jednostek. Ta analiza pomaga zrozumieć model danych, zidentyfikować najczęstsze wzorce relacji i odnaleźć potencjalne ścieżki dla zapytań przechodzenia. Zapytanie topologii pokazuje, które etykiety węzłów łączą się z innymi etykietami węzłów za pośrednictwem określonych typów krawędzi, zapewniając kompleksowy widok struktury grafu.

//Topology of the graph - What's connected to what?
graph('LDBC_Financial')
| graph-match (src)-[e]->(dst)
    project SourceLabels = labels(src), EdgeLabels = labels(e), DestinationLabels = labels(dst)
| mv-expand EdgeLabel = EdgeLabels to typeof(string)
| mv-expand SourceLabel = SourceLabels to typeof(string)
| mv-expand DestinationLabel = DestinationLabels to typeof(string)
| summarize Count = count() by SourceLabel, EdgeLabel, DestinationLabel

Treści powiązane

• Semantyka grafu — omówienie
• Typowe scenariusze korzystania z semantyki grafu
• Przykładowe zestawy danych i przykłady programu Graph
• Funkcja Graph
• operator make-graph