operator dopasowania grafu

Dotyczy: ✅Microsoft Fabric

Operator graph-match wyszukuje wszystkie wystąpienia wzorca grafu w źródle grafu wejściowego.

Składnia

G|graph-match [cycles] = [whereograniczenia] [project] =Wyrażenie [, ...]

Parametry

Notacja wzorca grafu

W poniższej tabeli przedstawiono obsługiwaną notację grafu:

Krawędź zmiennej długości

Krawędź o zmiennej długości umożliwia wielokrotne powtarzanie określonego wzorca w ramach zdefiniowanych limitów. Ten typ krawędzi jest oznaczony gwiazdką (*), po której następuje minimalna i maksymalna wartość wystąpień w formacie min..max. Zarówno wartości minimalne, jak i maksymalne muszą być skalarnymi liczbami całkowitymi . Każda sekwencja krawędzi należących do tego zakresu wystąpień może być zgodna ze zmienną krawędzią wzorca, jeśli wszystkie krawędzie w sekwencji spełniają ograniczenia opisane w klauzuli where .

Wiele sekwencji

Wiele sekwencji rozdzielonych przecinkami służy do wyrażania wzorców nieliniowych. Aby opisać połączenie między różnymi sekwencjami, muszą one współużytkować co najmniej jedną nazwę zmiennej węzła. Na przykład aby reprezentować wzorzec gwiazdy z węzłem n w środku połączonym z węzłami a,b,c i d, można użyć następującego wzorca:

( a)--(n)--()()--()--( d)

Obsługiwane są tylko pojedyncze połączone wzorce składników.

Zwraca

Operator graph-match zwraca wynik tabelaryczny, w którym każdy rekord odpowiada dopasowaniu wzorca na grafie.
Zwrócone kolumny są definiowane w klauzuli operatora project przy użyciu właściwości krawędzi i/lub węzłów zdefiniowanych we wzorcu. Właściwości i funkcje właściwości krawędzi o zmiennej długości są zwracane jako tablica dynamiczna, każda wartość w tablicy odpowiada wystąpieniu krawędzi zmiennej długości.

Przykłady

Poniższy przykład reprezentuje hierarchię organizacyjną. Pokazuje, jak można użyć krawędzi o zmiennej długości do znajdowania pracowników różnych poziomów hierarchii w jednym zapytaniu. Węzły na wykresie reprezentują pracowników, a krawędzie pochodzą od pracownika do menedżera. Po utworzeniu grafu przy użyciu metody make-graphwyszukujemy pracowników w Aliceorganizacji, które są młodsze niż 30.

let employees = datatable(name:string, age:long) 
[ 
  "Alice", 32,  
  "Bob", 31,  
  "Eve", 27,  
  "Joe", 29,  
  "Chris", 45, 
  "Alex", 35,
  "Ben", 23,
  "Richard", 39,
]; 
let reports = datatable(employee:string, manager:string) 
[ 
  "Bob", "Alice",  
  "Chris", "Alice",  
  "Eve", "Bob",
  "Ben", "Chris",
  "Joe", "Alice", 
  "Richard", "Bob"
]; 
reports 
| make-graph employee --> manager with employees on name 
| graph-match (alice)<-[reports*1..5]-(employee)
  where alice.name == "Alice" and employee.age < 30
  project employee = employee.name, age = employee.age, reportingPath = map(reports, manager)

Wynik

Poniższy przykład tworzy graf z Actions tabel i Entities . Jednostki to ludzie i systemy, a akcje opisują różne relacje między jednostkami. Po operatorze make-graph tworzącym graf jest wywołanie graph-match wzorca grafu, które wyszukuje ścieżki ataków do "Apollo" systemu.

let Entities = datatable(name:string, type:string, age:long) 
[ 
  "Alice", "Person", 23,  
  "Bob", "Person", 31,  
  "Eve", "Person", 17,  
  "Mallory", "Person", 29,  
  "Apollo", "System", 99 
]; 
let Actions = datatable(source:string, destination:string, action_type:string) 
[ 
  "Alice", "Bob", "communicatesWith",  
  "Alice", "Apollo", "trusts",  
  "Bob", "Apollo", "hasPermission",  
  "Eve", "Alice", "attacks",  
  "Mallory", "Alice", "attacks",  
  "Mallory", "Bob", "attacks"  
]; 
Actions 
| make-graph source --> destination with Entities on name 
| graph-match (mallory)-[attacks]->(compromised)-[hasPermission]->(apollo) 
  where mallory.name == "Mallory" and apollo.name == "Apollo" and attacks.action_type == "attacks" and hasPermission.action_type == "hasPermission" 
  project Attacker = mallory.name, Compromised = compromised.name, System = apollo.name

Wynik

Poniższy przykład jest podobny do poprzedniego przykładu ścieżki ataku, ale z dodatkowym ograniczeniem: chcemy, aby naruszona jednostka również komunikowała się z Alice. graph-match Prefiks wzorca jest taki sam jak w poprzednim przykładzie i dodamy kolejną sekwencję z naruszonymi zagrożeniami jako łączem między sekwencjami.

let Entities = datatable(name:string, type:string, age:long) 
[ 
  "Alice", "Person", 23,  
  "Bob", "Person", 31,  
  "Eve", "Person", 17,  
  "Mallory", "Person", 29,  
  "Apollo", "System", 99 
]; 
let Actions = datatable(source:string, destination:string, action_type:string) 
[ 
  "Alice", "Bob", "communicatesWith",  
  "Alice", "Apollo", "trusts",  
  "Bob", "Apollo", "hasPermission",  
  "Eve", "Alice", "attacks",  
  "Mallory", "Alice", "attacks",  
  "Mallory", "Bob", "attacks"  
]; 
Actions 
| make-graph source --> destination with Entities on name 
| graph-match (mallory)-[attacks]->(compromised)-[hasPermission]->(apollo), (compromised)-[communicates]-(alice) 
  where mallory.name == "Mallory" and apollo.name == "Apollo" and attacks.action_type == "attacks" and hasPermission.action_type == "hasPermission" and alice.name == "Alice"
  project Attacker = mallory.name, Compromised = compromised.name, System = apollo.name

Wynik

Powiązana zawartość

• Operatory grafu
• operator make-graph
• all()
• any()
• map()
• inner_nodes()