Udostępnij przez

Bar chart

Applies to: ✅Microsoft Fabric✅Azure Data Explorer✅Azure Monitor✅Microsoft Sentinel

Wizualizacja wykresu słupkowego wymaga co najmniej dwóch kolumn w wyniku zapytania. Domyślnie pierwsza kolumna jest używana jako oś y. Ta kolumna może zawierać typy danych tekstowych, daty/godziny lub liczb. Pozostałe kolumny są używane jako oś x i zawierają typy danych liczbowych, które mają być wyświetlane jako linie poziome. Wykresy słupkowe są używane głównie do porównywania wartości liczbowych i nominalnych, gdzie długość każdego wiersza reprezentuje jego wartość.

Note

This visualization can only be used in the context of the render operator.

Syntax

T|renderbarchart [with(propertyName=propertyValue [, ...])]

Learn more about syntax conventions.

Parameters

Name Typ Required Description
T string ✔️ Nazwa tabeli wejściowej.
propertyName, propertyValue string Rozdzielona przecinkami lista par właściwości klucz-wartość. See supported properties.

Supported properties

Wszystkie właściwości są opcjonalne.

PropertyName PropertyValue
accumulate Określa, czy wartość każdej miary jest dodawana do wszystkich jego poprzedników (true lub false).
kind Dalsze opracowanie rodzaju wizualizacji. Aby uzyskać więcej informacji, zobacz kind właściwość.
legend Czy wyświetlać legendę, czy nie (visible lub hidden).
series Rozdzielana przecinkami lista kolumn, których połączone wartości dla rekordu definiują serię, do której należy rekord.
ymin Minimalna wartość, która ma być wyświetlana na osi Y.
ymax Maksymalna wartość, która ma być wyświetlana na osi Y.
title Tytuł wizualizacji (typu string).
xaxis Jak skalować oś x (linear lub log).
xcolumn Która kolumna w wyniku jest używana dla osi x.
xtitle Tytuł osi x (typu string).
yaxis Jak skalować oś y (linear lub log).
ycolumns Rozdzielana przecinkami lista kolumn, które składają się z wartości podanych na wartość kolumny x.
ytitle Tytuł osi y (typu string).
ysplit Jak podzielić wizualizację na wiele wartości osi y. Aby uzyskać więcej informacji, zobacz ysplit właściwość.

ysplit własność

Ta wizualizacja obsługuje dzielenie na wiele wartości osi y:

ysplit Description
none Pojedyncza oś y jest wyświetlana dla wszystkich danych serii. Jest to opcja domyślna.
axes Pojedynczy wykres jest wyświetlany z wieloma osiami y (jeden na serię).
panels Jeden wykres jest renderowany dla każdej ycolumn wartości. Maksymalnie pięć paneli.

Supported properties

Wszystkie właściwości są opcjonalne.

PropertyName PropertyValue
kind Dalsze opracowanie rodzaju wizualizacji. Aby uzyskać więcej informacji, zobacz kind właściwość.
series Rozdzielana przecinkami lista kolumn, których połączone wartości dla rekordu definiują serię, do której należy rekord.
title Tytuł wizualizacji (typu string).

kind własność

Tę wizualizację można dokładniej opracować, podając kind właściwość . Obsługiwane wartości tej właściwości to:

kind wartość Description
default Każdy "pasek" stoi na własną rękę.
unstacked Tak samo jak default.
stacked Stack "bars".
stacked100 Stos "słupki" i rozciągnij każdy z nich do tej samej szerokości co pozostałe.

Examples

W przykładzie w tej sekcji pokazano, jak używać składni, aby ułatwić rozpoczęcie pracy.

The examples in this article use publicly available tables in the help cluster, such as the StormEvents table in the Samples database.

The examples in this article use publicly available tables, such as the Weather table in the Weather analytics sample gallery. Może być konieczne zmodyfikowanie nazwy tabeli w przykładowym zapytaniu, aby było zgodne z tabelą w obszarze roboczym.

Renderowanie wykresu słupkowego

Poniższe zapytanie tworzy wykres słupkowy przedstawiający liczbę zdarzeń burzy dla każdego stanu, filtrując tylko te stany z ponad 10 zdarzeniami. Wykres przedstawia wizualną reprezentację rozkładu zdarzeń w różnych stanach.

Uruchamianie zapytania

StormEvents
| summarize event_count=count() by State
| project State, event_count
| render barchart
    with (
    title="Storm count by state",
    ytitle="Storm count",
    xtitle="State",
    legend=hidden
    )

Zrzut ekranu przedstawiający oznaczony wykres słupkowy.

Renderowanie wykresu słupkowego stacked

Poniższe zapytanie tworzy wykres słupkowy, który pokazuje łączną stacked liczbę zdarzeń burzy według ich typu dla wybranych stanów Teksasu, Kalifornii i Florydy. Każdy pasek reprezentuje typ zdarzenia storm, a skumulowane słupki pokazują podział zdarzeń burzy według stanu w ramach każdego typu.

Uruchamianie zapytania

StormEvents
| where State in ("TEXAS", "CALIFORNIA", "FLORIDA")
| summarize EventCount = count() by EventType, State
| order by EventType asc, State desc
| render barchart with (kind=stacked)

Zrzut ekranu przedstawiający wizualizację skumulowanego wykresu słupkowego.

Renderowanie wykresu słupkowego stacked100

Poniższe zapytanie tworzy wykres słupkowy, który pokazuje łączną stacked100 liczbę zdarzeń burzy według ich typu dla wybranych stanów Teksasu, Kalifornii i Florydy. Wykres przedstawia rozkład zdarzeń burzy między stanami w ramach każdego typu. Chociaż stosy wizualnie sumują się do 100, wartości faktycznie reprezentują liczbę zdarzeń, a nie wartości procentowe. Ta wizualizacja jest przydatna do zrozumienia zarówno wartości procentowych, jak i rzeczywistych liczb zdarzeń.

Uruchamianie zapytania

StormEvents
| where State in ("TEXAS", "CALIFORNIA", "FLORIDA")
| summarize EventCount = count() by EventType, State
| order by EventType asc, State desc
| render barchart with (kind=stacked100)

Zrzut ekranu przedstawiający skumulowaną wizualizację wykresu słupkowego 100.

ysplit Korzystanie z właściwości

Poniższe zapytanie zawiera codzienne podsumowanie obrażeń i zgonów związanych z burzą, wizualizowane jako wykres słupkowy z podziałem osi/paneli w celu lepszego porównania.

Uruchamianie zapytania

StormEvents
| summarize
    TotalInjuries = sum(InjuriesDirect) + sum(InjuriesIndirect),
    TotalDeaths = sum(DeathsDirect) + sum(DeathsIndirect)
    by bin(StartTime, 1d)
| project StartTime, TotalInjuries, TotalDeaths
| render barchart with (ysplit=axes)

Zrzut ekranu przedstawiający wykres kolumnowy z właściwością osi ysplit.

Aby podzielić widok na oddzielne panele, określ panels zamiast axes:

Uruchamianie zapytania

StormEvents
| summarize
    TotalInjuries = sum(InjuriesDirect) + sum(InjuriesIndirect),
    TotalDeaths = sum(DeathsDirect) + sum(DeathsIndirect)
    by bin(StartTime, 1d)
| project StartTime, TotalInjuries, TotalDeaths
| render barchart with (ysplit=panels)

Zrzut ekranu przedstawiający wykres kolumnowy z właściwością paneli ysplit.

  • Last updated on