Udostępnij przez

Date.FromText

Składnia

Date.FromText(text as nullable text, optional options as any) as nullable date

Informacje

Tworzy wartość daty na podstawie tekstowej reprezentacji.

  • text: wartość tekstowa, która ma być ukryta do daty.

  • options: opcjonalny element record, który można podać, aby określić dodatkowe właściwości. Może record zawierać następujące pola:

    • Format: wartość wskazująca format text do użycia. Aby uzyskać więcej informacji, przejdź do Standardowe ciągi formatu daty i godziny i Niestandardowe ciągi formatu daty i godziny. Pominięcie tego pola lub podanie null powoduje parsowanie daty najlepszym sposobem.
    • Culture: Jeśli Format nie ma wartości null, Culture steruje niektórymi specyfikatorami formatu. Na przykład w "en-US""MMM" jest "Jan", "Feb", "Mar", ..., a w "ru-RU""MMM" jest "янв", "фев", "мар", .... Gdy Format jest ustawiony na null, Culture określa domyślny format do użycia. Gdy Culture jest null lub pominięty, używany jest Culture.Current.

Aby obsługiwać starsze przepływy pracy, options może być również wartością tekstową. Ma to takie samo zachowanie, jak w przypadku options = [Format = null, Culture = options].

Przykład 1

Przekonwertuj "2010-12-31" na wartość date.

Użycie

Date.FromText("2010-12-31")

Wyjście

#date(2010, 12, 31)

Przykład 2

Konwertowanie przy użyciu formatu niestandardowego i kultury niemieckiej.

Użycie

Date.FromText("30 Dez 2010", [Format="dd MMM yyyy", Culture="de-DE"])

Wyjście

#date(2010, 12, 30)

Przykład 3

Znajdź datę w kalendarzu gregoriańskim odpowiadającym początku 1400 w kalendarzu Hidżry.

Użycie

Date.FromText("1400", [Format="yyyy", Culture="ar-SA"])

Wyjście

#date(1979, 11, 20)

Przykład 4

Przekonwertuj daty w języku włoskim z nazwami miesięcy w skrócie w kolumnie Data publikacji na wartości dat.

Użycie

let
    Source = #table(type table [Account Code = text, Posted Date = text, Sales = number],
    {
        {"US-2004", "20 gen. 2023", 580},
        {"CA-8843", "18 lug. 2024", 280},
        {"PA-1274", "12 gen. 2023", 90},
        {"PA-4323", "14 apr. 2023", 187},
        {"US-1200", "14 dic. 2023", 350},
        {"PTY-507", "4 giu. 2024", 110}
    }),
    #"Converted Date" = Table.TransformColumns(
        Source, 
        {"Posted Date", each Date.FromText(_, [Culture = "it-IT"]), type date}
    )
in
    #"Converted Date"

Wyjście

#table(type table [Account Code = text, Posted Date = date, Sales = number],
{
    {"US-2004", #date(2023, 1, 20), 580},
    {"CA-8843", #date(2024, 7, 18), 280},
    {"PA-1274", #date(2023, 1, 12), 90},
    {"PA-4323", #date(2023, 4, 14), 187},
    {"US-1200", #date(2023, 12, 14), 350},
    {"PTY-507", #date(2024, 6, 4), 110}
})

Powiązana zawartość

  • Last updated on