List.Distinct

Składnia

List.Distinct(list as list, optional equationCriteria as any) as list

Informacje

Zwraca listę zawierającą wszystkie wartości z określonej listy z usuniętymi duplikatami. Jeśli określona lista jest pusta, wynik jest pustą listą.

• list: lista, z której wyodrębniono odrębne wartości.
• equationCriteria: (Opcjonalnie) Określa sposób określania równości podczas porównywania wartości. Ten parametr może być funkcją selektora kluczy, funkcją porównującą lub listą zawierającą zarówno selektor klucza, jak i moduł porównujący.

Przykład 1

Usuń duplikaty z listy {1, 1, 2, 3, 3, 3, 3}.

Użycie

List.Distinct({1, 1, 2, 3, 3, 3})

Wyjście

{1, 2, 3}

Przykład 2

Począwszy od końca listy, wybierz owoce, które mają unikatową długość tekstu.

Użycie

let
    Source = {"Apple", "Banana", "Cherry", "Date", "Fig"},
    Result = List.Distinct(List.Reverse(Source), each Text.Length(_))
in
    Result

Wyjście

{"Fig", "Date", "Cherry", "Apple"}

Przykład 3

Począwszy od początku listy, wybierz unikatowe owoce, ignorując przypadek.

Użycie

let
    Source = {"apple", "Pear", "aPPle", "banana", "ORANGE", "pear", "Banana", "Cherry"},
    Result = List.Distinct(Source, Comparer.OrdinalIgnoreCase)
in
    Result

Wyjście

{"apple", "Pear", "banana", "ORANGE", "Cherry"}

Przykład 4

Wyodrębnij z listy pierwszych list z unikatowymi nazwami krajów, ignorując przypadek. Umieść wyodrębnione listy w wierszach nowej tabeli.

Użycie

let
    Source = {
        {"USA", #date(2023, 8, 1), 567},
        {"canada", #date(2023, 8, 1), 254},
        {"Usa", #date(2023, 7, 1), 450},
        {"CANADA", #date(2023, 6, 1), 357},
        {"Panama", #date(2023, 6, 2), 20},
        {"panama", #date(2023, 7, 1), 40}
    },
    DistinctByCountry = List.Distinct(
        Source,
        {each _{0}, Comparer.OrdinalIgnoreCase}
    ),
    ToTable = Table.FromRows(DistinctByCountry, {"Country", "Date", "Value"}),
    ChangeTypes = Table.TransformColumnTypes(
        ToTable, {{"Country", type text}, {"Date", type date}, {"Value", Int64.Type}}
    )
in
    ChangeTypes

Wyjście

#table(type table[Country = text, Date = date, Value = Int64.Type],
    {
        {"USA", #date(2023, 8, 1), 567},
        {"canada", #date(2023, 8, 1), 254},
        {"Panama", #date(2023, 6, 2), 20}
    }
)

Powiązana zawartość

Kryteria równania