List.Select

Składnia

List.Select(list as list, selection as function) as list

O nas

Zwraca wartości z określonej listy, które są zgodne z warunkiem wyboru.

• list: Lista do zbadania.
• selection: funkcja określająca wartości do wybrania.

Przykład 1

Znajdź wartości na liście {1, -3, 4, 9, -2}, które są większe niż 0.

użycie

List.Select({1, -3, 4, 9, -2}, each _ > 0)

Wyjście

{1, 4, 9}

Przykład 2

Wybierz daty z listy, która przypada w sobotę lub niedzielę.

użycie

let
    dates = {
        #date(2025, 10, 20),  // Monday
        #date(2025, 10, 21),  // Tuesday
        #date(2025, 10, 25),  // Saturday
        #date(2025, 10, 26),  // Sunday
        #date(2025, 10, 27)   // Monday
    },
    weekendDates = List.Select(
        dates,
        each Date.DayOfWeek(_, Day.Monday) >= 5
    )
in
    weekendDates

Wyjście

{
    #date(2025, 10, 25),
    #date(2025, 10, 26)
}

Przykład 3

Wyświetl tabelę aktywnych klientów z sumami zakupów w wysokości ponad 100 USD.

użycie

let
    customers = {
        [Name = "Alice", Status = "Active", Purchases = 150],
        [Name = "Bob", Status = "Inactive", Purchases = 200],
        [Name = "Carol", Status = "Active", Purchases = 90],
        [Name = "Dave", Status = "Active", Purchases = 120]
    },
    highValueActiveCustomers = List.Select(
        customers,
        each [Status] = "Active" and [Purchases] > 100
    ),
    resultTable = Table.FromRecords(
        highValueActiveCustomers,
        type table [Name = text, Status = text, Purchases = number]
    )
in
    resultTable

Wyjście

#table(type table[Name = text, Status = text, Purchases = number],
{
    {"Alice", "Active", 150},
    {"Dave", "Active", 120}
})