Table.FromList

Składnia

Table.FromList(
    list as list,
    optional splitter as nullable function,
    optional columns as any,
    optional default as any,
    optional extraValues as nullable number
) as table

Informacje

Konwertuje listę, list na tabelę, stosując opcjonalną funkcję dzielenia , splitter, na każdy element na liście. Domyślnie przyjmuje się, że lista jest listą wartości tekstowych rozdzielanych przecinkami. Opcjonalne columns może być liczbą kolumn, listą kolumn lub TableType. Można również określić opcjonalne default i extraValues.

Przykład 1

Utwórz tabelę na podstawie listy przy użyciu domyślnego modułu podziału.

Użycie

Table.FromList(
    {"a,apple", "b,ball", "c,cookie", "d,door"},
    null,
    {"Letter", "Example Word"}
)

Wyjście

Table.FromRecords({
    [Letter = "a", #"Example Word" = "apple"],
    [Letter = "b", #"Example Word" = "ball"],
    [Letter = "c", #"Example Word" = "cookie"],
    [Letter = "d", #"Example Word" = "door"]
})

Przykład 2

Utwórz tabelę na podstawie listy przy użyciu niestandardowego modułu podziału.

Użycie

Table.FromList(
    {"a,apple", "b,ball", "c,cookie", "d,door"},
    Splitter.SplitByNothing(),
    {"Letter and Example Word"}
)

Wyjście

Table.FromRecords({
    [#"Letter and Example Word" = "a,apple"],
    [#"Letter and Example Word" = "b,ball"],
    [#"Letter and Example Word" = "c,cookie"],
    [#"Letter and Example Word" = "d,door"]
})

Przykład 3

Utwórz tabelę z listy przy użyciu modułu podziału Record.FieldValues.

Użycie

Table.FromList(
    {
        [CustomerID = 1, Name = "Bob"],
        [CustomerID = 2, Name = "Jim"]
    },
    Record.FieldValues,
    {"CustomerID", "Name"}
)

Wyjście

Table.FromRecords({
    [CustomerID = 1, Name = "Bob"],
    [CustomerID = 2, Name = "Jim"]
})