Text.ToBinary

Składnia

Text.ToBinary(
    text as nullable text,
    optional encoding as nullable number,
    optional includeByteOrderMark as nullable logical
) as nullable binary

O nas

Koduje wartość tekstową do wartości binarnej przy użyciu określonego kodowania.

• text: tekst, który ma być zakodowany.
• encoding: (Opcjonalnie) Kodowanie używane do konwertowania tekstu na plik binarny. Użyj BinaryEncoding.Type polecenia , aby określić typ kodowania. Jeśli ta wartość nie jest określona, wartość domyślna to BinaryEncoding.Utf8.
• includeByteOrderMark: (Opcjonalnie) Określa, czy na początku binarnego wyjścia powinien zostać uwzględniony znacznik kolejności bajtów (BOM). Ustaw na true, aby automatycznie uwzględnić znacznik porządku bajtów (BOM), w przeciwnym razie false. Jeśli ta wartość nie jest określona, wartość domyślna to false.

Przykład 1

Zakoduj tekst do pliku binarnego, utwórz czytelny ciąg Base64, a następnie zdekoduj go z powrotem do tekstu.

Użycie

let
    originalText = "Testing 1-2-3",

    // Default UTF-8 binary
    binaryData = Text.ToBinary(originalText),

    // Convert binary to viewable Base64 string
    encodedText = Binary.ToText(binaryData, BinaryEncoding.Base64),

    // Decode back to text
    decodedText = Text.FromBinary(binaryData),

    result = [
        OriginalText = originalText,
        BinaryBase64 = encodedText,
        DecodedText = decodedText
    ]
in
    result

Wynik

[
    OriginalText = "Testing 1-2-3",
    BinaryEncoded = "VGVzdGluZyAxLTItMw==",
    DecodedText = "Testing 1-2-3"
]

Przykład 2

Zakoduj tekst w formacie binarnym z użyciem znacznika porządku bajtów (BOM), aby utworzyć widoczny ciąg szesnastkowy, a następnie zdekoduj go z powrotem na tekst.

Użycie

let
    originalText = "Testing 1-2-3",

    // Convert to binary with BOM
    binaryData = Text.ToBinary(originalText, TextEncoding.Utf16, true),

    // Show binary as hex to demonstrate presence of BOM (fffe)
    binaryAsHex = Binary.ToText(binaryData, BinaryEncoding.Hex),

    // Decode back to text
    decodedText = Text.FromBinary(binaryData, TextEncoding.Utf16),

    // Compare original text and decoded text
    isIdentical = originalText = decodedText,

    result = [
        OriginalText = originalText,
        BinaryHex = binaryAsHex,
        DecodedText = decodedText,
        IsIdentical = isIdentical
    ]
in
    result

Wynik

[
    OriginalText = "Testing 1-2-3", 
    DecodedText = "fffe540065007300740069006e006700200031002d0032002d003300",
    DecodedText = "Testing 1-2-3", 
    IsIdentical = true 
]