Pisanie efektu (Direct3D 9)

Pisanie efektu wymaga zrozumienia składni efektu i wygenerowania wymaganych informacji o stanie. Możesz dodać w efekcie stan shadera, stan tekstury i stan próbkujący oraz cały stan potoku wymagany przez aplikację.

Składnia efektu jest szczegółowo opisana w Format efektu (Direct3D 9). Efekt jest zazwyczaj hermetyzowany do pliku efektu (fx), ale może być również zapisywany jako ciąg tekstowy w aplikacji.

Przykład efektu

Efekty zawierają trzy typy stanu: stan cieniowania, stan tekstury i próbkowania oraz stan potoku. Oto przykład efektu z przykładu BasicHLSL Sample:

// Global variables
float4 g_MaterialAmbientColor;      // Material's ambient color
float4 g_MaterialDiffuseColor;      // Material's diffuse color
int g_nNumLights;

float3 g_LightDir[3];               // Light's direction in world space
float4 g_LightDiffuse[3];           // Light's diffuse color
float4 g_LightAmbient;              // Light's ambient color

texture g_MeshTexture;              // Color texture for mesh

float    g_fTime;                   // App's time in seconds
float4x4 g_mWorld;                  // World matrix for object
float4x4 g_mWorldViewProjection;    // World * View * Projection matrix
// Texture samplers
sampler MeshTextureSampler = 
sampler_state
{
    Texture = <g_MeshTexture>;
    MipFilter = LINEAR;
    MinFilter = LINEAR;
    MagFilter = LINEAR;
};
struct VS_OUTPUT
{
    float4 Position   : POSITION;   // vertex position 
    float2 TextureUV  : TEXCOORD0;  // vertex texture coords 
    float4 Diffuse    : COLOR0;     // vertex diffuse color
};
VS_OUTPUT RenderSceneVS( float4 vPos : POSITION, 
                         float3 vNormal : NORMAL,
                         float2 vTexCoord0 : TEXCOORD0,
                         uniform int nNumLights,
                         uniform bool bTexture,
                         uniform bool bAnimate )
{
    VS_OUTPUT Output;
    float3 vNormalWorldSpace;
  
    float4 vAnimatedPos = vPos;
    
    // Animation the vertex based on time and the vertex's object space position
    if( bAnimate )
        vAnimatedPos += float4(vNormal, 0) * (sin(g_fTime+5.5)+0.5)*5;
    
    // Transform the position from object space to homogeneous projection space
    Output.Position = mul(vAnimatedPos, g_mWorldViewProjection);
    
    // Transform the normal from object space to world space    
    vNormalWorldSpace = normalize(mul(vNormal, (float3x3)g_mWorld));
    
    // Compute simple directional lighting equation
    float3 vTotalLightDiffuse = float3(0,0,0);
    for(int i=0; i < nNumLights; i++ )
        vTotalLightDiffuse += g_LightDiffuse[i] * max(0,dot(vNormalWorldSpace, g_LightDir[i]));
        
    Output.Diffuse.rgb = g_MaterialDiffuseColor * vTotalLightDiffuse + 
                         g_MaterialAmbientColor * g_LightAmbient;   
    Output.Diffuse.a = 1.0f; 
    
    // Just copy the texture coordinate through
    if( bTexture ) 
        Output.TextureUV = vTexCoord0; 
    else
        Output.TextureUV = 0; 
    
    return Output;    
}
struct PS_OUTPUT
{
    float4 RGBColor : COLOR0;  // Pixel color    
};
PS_OUTPUT RenderScenePS( VS_OUTPUT In,
                         uniform bool bTexture ) 
{ 
    PS_OUTPUT Output;

    // Lookup mesh texture and modulate it with diffuse
    if( bTexture )
        Output.RGBColor = tex2D(MeshTextureSampler, In.TextureUV) * In.Diffuse;
    else
        Output.RGBColor = In.Diffuse;

    return Output;
}
technique RenderSceneWithTexture1Light
{
    pass P0
    {          
        VertexShader = compile vs_1_1 RenderSceneVS( 1, true, true );
        PixelShader  = compile ps_1_1 RenderScenePS( true ); 
    }
}

Ten efekt zawiera:

• Stan cieniowania, który jest stanem skojarzonym z cieniatorem wierzchołka i cieniatorem pikseli. Jest to definiowane przez funkcje cieniowania wierzchołków i pikseli, wszelkie zmienne globalne, których wymagają, oraz ich struktury danych wejściowych i wyjściowych, z których wszystkie są wymienione tutaj:

  struct VS_OUTPUT
  {  ...  };
  VS_OUTPUT RenderSceneVS( float4 vPos : POSITION, 
                           ...
  {  ...  }
  
  struct PS_OUTPUT
  {  ...  };
  PS_OUTPUT RenderScenePS( VS_OUTPUT In,
                           uniform bool bTexture ) 
  {  ...  }
  

• Parametry tekstury i próbkowania, które są zmiennymi globalnymi obiektu tekstury i obiektu próbkowania.

  texture g_MeshTexture;              // Color texture for mesh
  
  sampler MeshTextureSampler = 
  sampler_state
  {
     ...
  };
  

• Inny stan efektu. W tym przykładzie nie jest jawnie używany żaden inny stan efektu. Gdyby tak było, byłaby to technika dotycząca przepustki, do której zastosowano:

  technique RenderSceneWithTexture1Light
  {
      pass P0
      {          
          // Any other effect state can be set here.
  
          VertexShader = compile vs_1_1 RenderSceneVS( 1, true, true );
          PixelShader  = compile ps_1_1 RenderScenePS( true ); 
      }
  }
  
  

Efekty zawierają co najmniej jedną technikę i jeden lub więcej przebiegów

Opcje renderowania efektu są kontrolowane poprzez dodawanie technik i przejść.

Efekty można tworzyć za pomocą dodatkowych przejść, aby ułatwić bardziej złożone efekty renderowania. Technika umożliwia dowolną liczbę przebiegów.

technique T0
{
    pass P0
    { ... }

    pass P1
    { ... }

    ...

    pass Pn
    { ... }
}

Efekty można również utworzyć przy użyciu dowolnej liczby technik.

technique T0
{
    pass P0
    { ... }
}

technique T1
{
    pass P0
    { ... }

    pass P1
    { ... }
}

...

technique Tn
{
    pass P0
    { ... }
}

technique TVertexShaderOnly
{
    pass P0
    {
        VertexShader =
        asm
        {
         // assembly-language shader code goes here
         ...
        };
    }
}

Techniki i przebiegi mogą mieć dowolne nazwy.

Tematy pokrewne

efektów