Przykład wyzwalacza dziennego (skrypty)

W tym przykładzie skryptów pokazano, jak utworzyć zadanie uruchamiające Notatnik o godzinie 8:00 każdego dnia. Zadanie zawiera dzienny wyzwalacz, który określa granicę uruchamiania, aby aktywować wyzwalacz i określić godzinę uruchomienia zadania, interwał wyzwalacza określający, że zadanie jest uruchamiane każdego dnia, oraz granica końcowa dezaktywuje wyzwalacz. W przykładzie pokazano również, jak ustawić wzorzec powtórzenia wyzwalacza w celu powtórzenia zadania. Zadanie zawiera również akcję wykonywalną uruchamianą w Notatniku.

W poniższej procedurze opisano, jak zaplanować zadanie uruchamiania pliku wykonywalnego o godzinie 8:00 każdego dnia. (Te kroki odpowiadają komentarzom kodu zawartym w przykładowym kodzie).

Aby zaplanować Notatnik, aby rozpocząć o godzinie 8:00 codziennie

1. Utwórz obiekt TaskService. Ten obiekt umożliwia utworzenie zadania w określonym folderze.
2. Pobierz folder zadania i utwórz zadanie. Użyj metody TaskService.GetFolder, aby pobrać folder, w którym jest przechowywane zadanie, oraz metodę TaskService.NewTask, aby utworzyć obiekt TaskDefinition reprezentujący zadanie.
3. Zdefiniuj informacje o zadaniu przy użyciu obiektu TaskDefinition. Użyj właściwości TaskDefinition.Settings, aby zdefiniować ustawienia określające sposób wykonywania zadania przez usługę Harmonogram zadań oraz właściwość TaskDefinition.RegistrationInfo, aby zdefiniować informacje opisujące zadanie.
4. Utwórz wyzwalacz dzienny przy użyciu właściwości TaskDefinition.Triggers. Ta właściwość zapewnia dostęp do obiektu TriggerCollection używanego do tworzenia wyzwalacza. Użyj metody TriggerCollection.Create (określając typ wyzwalacza, który chcesz utworzyć), aby utworzyć wyzwalacz dzienny. Podczas tworzenia wyzwalacza ustaw granicę początkową, aby aktywować wyzwalacz i określić godzinę uruchomienia zadania, interwał między dniami a granicą końcową, aby dezaktywować wyzwalacz. W poniższym przykładzie pokazano, jak ustawić wzorzec powtórzenia dla wyzwalacza w celu powtórzenia zadania.
5. Utwórz akcję dla zadania do wykonania przy użyciu właściwości TaskDefinition.Actions. Ta właściwość zapewnia dostęp do obiektu ActionCollection użytego do utworzenia akcji. Użyj metody ActionCollection.Create, aby określić typ akcji, którą chcesz utworzyć. W tym przykładzie użyto obiektu ExecAction, który reprezentuje akcję wykonującą operację wiersza polecenia.
6. Zarejestruj zadanie przy użyciu metody TaskFolder.RegisterTaskDefinition. W tym przykładzie zadanie zostanie uruchomione w Notatniku o godzinie 8:00 każdego dnia.

W poniższym przykładzie VBScript pokazano, jak zaplanować zadanie do wykonania Notatnika codziennie o godzinie 8:00.

'------------------------------------------------------------------
' This sample schedules a task to start on a daily basis.
'------------------------------------------------------------------

' A constant that specifies a daily trigger.
const TriggerTypeDaily = 2
' A constant that specifies an executable action.
const ActionTypeExec = 0

'********************************************************
' Create the TaskService object.
Set service = CreateObject("Schedule.Service")
call service.Connect()

'********************************************************
' Get a folder to create a task definition in. 
Dim rootFolder
Set rootFolder = service.GetFolder("\")

' The taskDefinition variable is the TaskDefinition object.
Dim taskDefinition
' The flags parameter is 0 because it is not supported.
Set taskDefinition = service.NewTask(0) 

'********************************************************
' Define information about the task.

' Set the registration info for the task by 
' creating the RegistrationInfo object.
Dim regInfo
Set regInfo = taskDefinition.RegistrationInfo
regInfo.Description = "Start notepad at 8:00AM daily"
regInfo.Author = "Administrator"

' Set the task setting info for the Task Scheduler by
' creating a TaskSettings object.
Dim settings
Set settings = taskDefinition.Settings
settings.Enabled = True
settings.StartWhenAvailable = True
settings.Hidden = False

'********************************************************
' Create a daily trigger. Note that the start boundary 
' specifies the time of day that the task starts and the 
' interval specifies what days the task is run.
Dim triggers
Set triggers = taskDefinition.Triggers

Dim trigger
Set trigger = triggers.Create(TriggerTypeDaily)

' Trigger variables that define when the trigger is active 
' and the time of day that the task is run. The format of 
' this time is YYYY-MM-DDTHH:MM:SS
Dim startTime, endTime

Dim time
startTime = "2006-05-02T08:00:00"  'Task runs at 8:00 AM
endTime = "2015-05-02T08:00:00"

WScript.Echo "startTime :" & startTime
WScript.Echo "endTime :" & endTime

trigger.StartBoundary = startTime
trigger.EndBoundary = endTime
trigger.DaysInterval = 1    'Task runs every day.
trigger.Id = "DailyTriggerId"
trigger.Enabled = True

' Set the task repetition pattern for the task.
' This will repeat the task 5 times.
Dim repetitionPattern
Set repetitionPattern = trigger.Repetition
repetitionPattern.Duration = "PT4M"
repetitionPattern.Interval = "PT1M"

'***********************************************************
' Create the action for the task to execute.

' Add an action to the task to run notepad.exe.
Dim Action
Set Action = taskDefinition.Actions.Create( ActionTypeExec )
Action.Path = "C:\Windows\System32\notepad.exe"

WScript.Echo "Task definition created. About to submit the task..."

'***********************************************************
' Register (create) the task.

call rootFolder.RegisterTaskDefinition( _
    "Test Daily Trigger", taskDefinition, 6, , , 3)

WScript.Echo "Task submitted."

Tematy pokrewne

korzystanie z harmonogramu zadań