Wyświetlanie nazw zadań i stanów (skrypty)

W tym przykładzie skryptów pokazano, jak wyliczać zadania w folderze zadań i wyświetlać wartości właściwości z każdego zadania.

Poniższa procedura opisuje sposób wyświetlania nazw zadań i stanów dla wszystkich zadań w folderze zadań.

Aby wyświetlić nazwy i stan zadań dla wszystkich zadań w folderze zadań

1. Utwórz obiekt TaskService.

   Ten obiekt umożliwia nawiązywanie połączenia z usługą Harmonogram zadań i uzyskiwanie dostępu do określonego folderu zadań.

2. Pobierz folder zadań, w którym znajdują się potrzebne informacje.

   Aby pobrać folder, użyj metody TaskService.GetFolder.

3. Pobierz kolekcję zadań z folderu .

   Użyj metody TaskFolder.GetTasks, aby pobrać kolekcję zadań (RegisteredTaskCollection).

4. Pobierz liczbę zadań w kolekcji i wylicz je za pomocą każdego zadania w kolekcji.

   Użyj kolekcji obiektów RegisteredTaskCollection, aby uzyskać wystąpienie obiektu RegisteredTask. Każda instancja będzie zawierać zadanie w kolekcji. Następnie można wyświetlić informacje (wartości właściwości) z każdego zarejestrowanego zadania.

Poniższy przykład w języku VBScript pokazuje, jak wyliczać za pomocą kolekcji zarejestrowanych zadań w głównym folderze zadań i wyświetlić nazwę i stan dla każdego zadania.

'---------------------------------------------------------
' This sample enumerates through the tasks on the local computer and
' displays their name and state.
'---------------------------------------------------------


' Create the TaskService object.
Set service = CreateObject("Schedule.Service")
call service.Connect()

' Get the task folder that contains the tasks. 
Dim rootFolder
Set rootFolder = service.GetFolder("\")
 
Dim taskCollection
Set taskCollection = rootFolder.GetTasks(0)

Dim numberOfTasks
numberOfTasks = taskCollection.Count

If numberOfTasks = 0 Then 
    Wscript.Echo "No tasks are registered."
Else
    WScript.Echo "Number of tasks registered: " & numberOfTasks
    
    Dim registeredTask
    For Each registeredTask In taskCollection
        WScript.Echo "Task Name: " & registeredTask.Name
    
        Dim taskState 
        Select Case registeredTask.State 
            Case "0"
                taskState = "Unknown"
            Case "1"
                taskState = "Disabled"
            Case "2"
                taskState = "Queued"
            Case "3"
                taskState = "Ready"
            Case "4"
                taskState = "Running"
        End Select

        WScript.Echo "    Task State: " & taskState
    Next
End If

Tematy pokrewne

Korzystanie z Harmonogramu Zadań