Przykład wyzwalacza rejestracji (skrypty)

W tym przykładzie skryptów pokazano, jak utworzyć zadanie zaplanowane do wykonania Notatnika po zarejestrowaniu zadania. Zadanie zawiera wyzwalacz rejestracji, który określa granicę początkową i granicę końcową zadania. Granica początkowa określa, kiedy wyzwalacz jest aktywowany. Zadanie zawiera również akcję określającą zadanie do wykonania Notatnika.

W poniższej procedurze opisano sposób planowania pliku wykonywalnego, takiego jak Notatnik, który ma zostać uruchomiony po zarejestrowaniu zadania.

Aby zaplanować uruchamianie Notatnika po zarejestrowaniu zadania

1. Utwórz obiekt TaskService. Ten obiekt umożliwia utworzenie zadania w określonym folderze.
2. Pobierz folder zadania i utwórz zadanie. Użyj metody TaskService.GetFolder, aby pobrać folder, w którym jest przechowywane zadanie, oraz metodę TaskService.NewTask, aby utworzyć obiekt TaskDefinition reprezentujący zadanie.
3. Zdefiniuj informacje o zadaniu przy użyciu obiektu TaskDefinition. Użyj właściwości TaskDefinition.Settings, aby zdefiniować ustawienia określające sposób wykonywania zadania przez usługę Harmonogram zadań oraz właściwość TaskDefinition.RegistrationInfo, aby zdefiniować informacje opisujące zadanie.
4. Utwórz wyzwalacz rejestracji przy użyciu właściwości TaskDefinition.Triggers. Ta właściwość zapewnia dostęp do obiektu TriggerCollection. Użyj metody TriggerCollection.Create (określając typ wyzwalacza, który chcesz utworzyć), aby utworzyć wyzwalacz rejestracji.
5. Utwórz akcję dla zadania do wykonania przy użyciu właściwości TaskDefinition.Actions. Ta właściwość zapewnia dostęp do obiektu ActionCollection. Użyj metody ActionCollection.Create, aby określić typ akcji, którą chcesz utworzyć. W tym przykładzie użyto obiektu ExecAction, który reprezentuje akcję uruchamiającą plik wykonywalny.
6. Zarejestruj zadanie przy użyciu metody TaskFolder.RegisterTaskDefinition.

W poniższym przykładzie VBScript pokazano, jak utworzyć zadanie, które planuje notatnik do wykonania po zarejestrowaniu zadania.

'---------------------------------------------------------
' This sample schedules a task to start notepad.exe when
' the task is registered.
'---------------------------------------------------------

' A constant that specifies a registration trigger.
const TriggerTypeRegistration = 7
' A constant that specifies an executable action.
const ActionTypeExecutable = 0   


'********************************************************
' Create the TaskService object.
Set service = CreateObject("Schedule.Service")
call service.Connect()

'********************************************************
' Get a folder to create a task definition in. 
Dim rootFolder
Set rootFolder = service.GetFolder("\")

' The taskDefinition variable is the TaskDefinition object.
Dim taskDefinition
' The flags parameter is 0 because it is not supported.
Set taskDefinition = service.NewTask(0) 

'********************************************************
' Define information about the task.

' Set the registration info for the task by 
' creating the RegistrationInfo object.
Dim regInfo
Set regInfo = taskDefinition.RegistrationInfo
regInfo.Description = "Start Notepad when the task is registered."
regInfo.Author = "Author Name"

' Set the task setting info for the Task Scheduler by
' creating a TaskSettings object.
Dim settings
Set settings = taskDefinition.Settings
settings.StartWhenAvailable = True

'********************************************************
' Create a registration trigger.
Dim triggers
Set triggers = taskDefinition.Triggers

Dim trigger
Set trigger = triggers.Create(TriggerTypeRegistration)

trigger.ExecutionTimeLimit = "PT5M"    'Five minutes
trigger.Id = "RegistrationTriggerId"   

'***********************************************************
' Create the action for the task to execute.

' Add an action to the task. The action executes Notepad.
Dim Action
Set Action = taskDefinition.Actions.Create( ActionTypeExecutable )
Action.Path = "C:\Windows\System32\notepad.exe"

WScript.Echo "Task definition created. About to submit the task..."

'***********************************************************
' Register (create) the task.

call rootFolder.RegisterTaskDefinition( _
    "Test Registration Trigger", taskDefinition, 6, , , 3)

WScript.Echo "Task submitted."

Tematy pokrewne

korzystanie z harmonogramu zadań