Udostępnij przez

Przykład wyzwalacza czasu (skrypty)

W tym przykładzie skryptów pokazano, jak utworzyć zadanie uruchamiające Notatnika w określonym czasie. Zadanie zawiera wyzwalacz oparty na czasie, który określa granicę uruchamiania, aby aktywować zadanie, akcję wykonywalną uruchamianą w Notatniku i granicę końcową, która dezaktywuje zadanie.

Poniższa procedura opisuje sposób planowania zadania w celu uruchomienia pliku wykonywalnego w określonym czasie.

, aby zaplanować Notatnik, aby rozpocząć o określonej godzinie

  1. Utwórz obiekt TaskService. Ten obiekt umożliwia utworzenie zadania w określonym folderze.
  2. Pobierz folder zadania i utwórz zadanie. Użyj metody TaskService.GetFolder, aby pobrać folder, w którym jest przechowywane zadanie, oraz metodę TaskService.NewTask, aby utworzyć obiekt TaskDefinition reprezentujący zadanie.
  3. Zdefiniuj informacje o zadaniu przy użyciu obiektu TaskDefinition. Użyj właściwości TaskDefinition.Settings, aby zdefiniować ustawienia określające sposób wykonywania zadania przez usługę Harmonogram zadań oraz właściwość TaskDefinition.RegistrationInfo, aby zdefiniować informacje opisujące zadanie.
  4. Utwórz wyzwalacz oparty na czasie przy użyciu właściwości TaskDefinition.Triggers. Ta właściwość zapewnia dostęp do obiektu TriggerCollection. Użyj metody TriggerCollection.Create (określając typ wyzwalacza, który chcesz utworzyć), aby utworzyć wyzwalacz oparty na czasie. Podczas tworzenia wyzwalacza ustaw granicę początkową i granicę końcową wyzwalacza, aby aktywować i dezaktywować wyzwalacz. Granica początkowa określa, kiedy zostanie wykonana akcja zadania.
  5. Utwórz akcję dla zadania do wykonania przy użyciu właściwości TaskDefinition.Actions. Ta właściwość zapewnia dostęp do obiektu ActionCollection. Użyj metody ActionCollection.Create, aby określić typ akcji, którą chcesz utworzyć. W tym przykładzie użyto obiektu ExecAction, który reprezentuje akcję wykonującą operację wiersza polecenia.
  6. Zarejestruj zadanie przy użyciu metody TaskFolder.RegisterTaskDefinition. W tym przykładzie zadanie uruchomi Notatnik w bieżącym czasie plus 30 sekund.

Poniższy przykład w języku VBScript pokazuje, jak zaplanować zadanie do wykonania Notatnika 30 sekund po zarejestrowaniu zadania.

'------------------------------------------------------------------
' This sample schedules a task to start notepad.exe 30 seconds
' from the time the task is registered.
'------------------------------------------------------------------

' A constant that specifies a time-based trigger.
const TriggerTypeTime = 1
' A constant that specifies an executable action.
const ActionTypeExec = 0   


'********************************************************
' Create the TaskService object.
Set service = CreateObject("Schedule.Service")
call service.Connect()

'********************************************************
' Get a folder to create a task definition in. 
Dim rootFolder
Set rootFolder = service.GetFolder("\")

' The taskDefinition variable is the TaskDefinition object.
Dim taskDefinition
' The flags parameter is 0 because it is not supported.
Set taskDefinition = service.NewTask(0) 

'********************************************************
' Define information about the task.

' Set the registration info for the task by 
' creating the RegistrationInfo object.
Dim regInfo
Set regInfo = taskDefinition.RegistrationInfo
regInfo.Description = "Start notepad at a certain time"
regInfo.Author = "Author Name"

'********************************************************
' Set the principal for the task
Dim principal
Set principal = taskDefinition.Principal

' Set the logon type to interactive logon
principal.LogonType = 3


' Set the task setting info for the Task Scheduler by
' creating a TaskSettings object.
Dim settings
Set settings = taskDefinition.Settings
settings.Enabled = True
settings.StartWhenAvailable = True
settings.Hidden = False

'********************************************************
' Create a time-based trigger.
Dim triggers
Set triggers = taskDefinition.Triggers

Dim trigger
Set trigger = triggers.Create(TriggerTypeTime)

' Trigger variables that define when the trigger is active.
Dim startTime, endTime

Dim time
time = DateAdd("s", 30, Now)  'start time = 30 seconds from now
startTime = XmlTime(time)

time = DateAdd("n", 5, Now) 'end time = 5 minutes from now
endTime = XmlTime(time)

WScript.Echo "startTime :" & startTime
WScript.Echo "endTime :" & endTime

trigger.StartBoundary = startTime
trigger.EndBoundary = endTime
trigger.ExecutionTimeLimit = "PT5M"    'Five minutes
trigger.Id = "TimeTriggerId"
trigger.Enabled = True

'***********************************************************
' Create the action for the task to execute.

' Add an action to the task to run notepad.exe.
Dim Action
Set Action = taskDefinition.Actions.Create( ActionTypeExec )
Action.Path = "C:\Windows\System32\notepad.exe"

WScript.Echo "Task definition created. About to submit the task..."

'***********************************************************
' Register (create) the task.

call rootFolder.RegisterTaskDefinition( _
    "Test TimeTrigger", taskDefinition, 6, , , 3)

WScript.Echo "Task submitted."



'------------------------------------------------------------------
' Used to get the time for the trigger 
' startBoundary and endBoundary.
' Return the time in the correct format: 
' YYYY-MM-DDTHH:MM:SS. 
'------------------------------------------------------------------
Function XmlTime(t)
    Dim cSecond, cMinute, CHour, cDay, cMonth, cYear
    Dim tTime, tDate

    cSecond = "0" & Second(t)
    cMinute = "0" & Minute(t)
    cHour = "0" & Hour(t)
    cDay = "0" & Day(t)
    cMonth = "0" & Month(t)
    cYear = Year(t)

    tTime = Right(cHour, 2) & ":" & Right(cMinute, 2) & _
        ":" & Right(cSecond, 2)
    tDate = cYear & "-" & Right(cMonth, 2) & "-" & Right(cDay, 2)
    XmlTime = tDate & "T" & tTime 
End Function

korzystanie z harmonogramu zadań

 

 

  • Last updated on