Udostępnij przez

Przykład wyzwalacza tygodniowego (skrypty)

W tym przykładzie skryptów pokazano, jak utworzyć zadanie uruchamiające Notatnik o godzinie 8:00 w poniedziałek każdego tygodnia. Zadanie zawiera dzienny wyzwalacz, który określa, kiedy zadanie jest uruchamiane i akcja wykonywalna uruchamiana w Notatniku.

Poniższa procedura opisuje, jak zaplanować zadanie, aby uruchomić plik wykonywalny o godzinie 8:00 w poniedziałek każdego tygodnia.

Aby zaplanować Notatnik, aby rozpocząć o 8:00 w poniedziałek każdego tygodnia

  1. Utwórz obiekt TaskService. Ten obiekt umożliwia utworzenie zadania w określonym folderze.

  2. Pobierz folder zadania i utwórz zadanie. Użyj metody TaskService.GetFolder, aby pobrać folder, w którym jest przechowywane zadanie, oraz metodę TaskService.NewTask, aby utworzyć obiekt TaskDefinition reprezentujący zadanie.

  3. Zdefiniuj informacje o zadaniu przy użyciu obiektu TaskDefinition. Użyj właściwości TaskDefinition.Settings, aby zdefiniować ustawienia określające sposób wykonywania zadania przez usługę Harmonogram zadań oraz właściwość TaskDefinition.RegistrationInfo, aby zdefiniować informacje opisujące zadanie.

  4. Utwórz wyzwalacz tygodniowy przy użyciu właściwości TaskDefinition.Triggers. Ta właściwość zapewnia dostęp do obiektu TriggerCollection używanego do tworzenia wyzwalacza.

    Użyj metody TriggerCollection.Create (określając typ wyzwalacza, który chcesz utworzyć), aby utworzyć wyzwalacz tygodniowy.

    Ustaw właściwość WeeklyTrigger.StartBoundary, aby określić czas aktywowania wyzwalacza i godzinę uruchomienia zadania. W tym przykładzie wyzwalacz jest aktywowany 1 stycznia 2005 r., a zadanie jest uruchamiane o godzinie 8:00.

    Ustaw właściwość WeeklyTrigger.EndBoundary, aby określić, kiedy wyzwalacz jest dezaktywowany. W tym przykładzie wyzwalacz jest dezaktywowany 1 stycznia 2015 r.

    Ustaw właściwość WeeklyTrigger.DaysOfWeek, aby określić dni tygodnia, w których jest uruchamiane zadanie. W tym przykładzie zadanie jest uruchamiane w poniedziałek.

    Ustaw właściwość WeeklyTrigger.WeeksInterval, aby określić interwał między tygodniami w harmonogramie. W tym przykładzie zadanie jest uruchamiane co tydzień.

  5. Utwórz akcję dla zadania do wykonania przy użyciu właściwości TaskDefinition.Actions. Ta właściwość zapewnia dostęp do obiektu ActionCollection użytego do utworzenia akcji. Użyj metody ActionCollection.Create, aby określić typ akcji, którą chcesz utworzyć. W tym przykładzie użyto obiektu ExecAction, który reprezentuje akcję wykonującą operację wiersza polecenia.

  6. Zarejestruj zadanie przy użyciu metody TaskFolder.RegisterTaskDefinition. W tym przykładzie zadanie zostanie uruchomione w Notatniku o godzinie 8:00 w poniedziałek każdego tygodnia.

W poniższym przykładzie VBScript pokazano, jak zaplanować zadanie do wykonania Notatnika codziennie o godzinie 8:00.

'------------------------------------------------------------------
' This sample schedules a task to start on a weekly basis.
'------------------------------------------------------------------

' A constant that specifies a weekly trigger.
const TriggerTypeWeekly = 3
' A constant that specifies an executable action.
const ActionTypeExec = 0   


'********************************************************
' Create the TaskService object.
Set service = CreateObject("Schedule.Service")
call service.Connect()

'********************************************************
' Get a folder to create a task definition in. 
Dim rootFolder
Set rootFolder = service.GetFolder("\")

' The taskDefinition variable is the TaskDefinition object.
Dim taskDefinition
' The flags parameter is 0 because it is not supported.
Set taskDefinition = service.NewTask(0) 

'********************************************************
' Define information about the task.

' Set the registration info for the task by 
' creating the RegistrationInfo object.
Dim regInfo
Set regInfo = taskDefinition.RegistrationInfo
regInfo.Description = "Start Notepad weekly."
regInfo.Author = "Administrator"

' Set the task setting info for the Task Scheduler by
' creating a TaskSettings object.
Dim settings
Set settings = taskDefinition.Settings
settings.Enabled = True
settings.StartWhenAvailable = True
settings.Hidden = False

'********************************************************
' Create a weekly trigger. Note that the start boundary 
' specifies the time of day that the task starts, the 
' day-of-week specfies on what day of the week the task 
' runs, and the interval specifies what weeks the task runs.
Dim triggers
Set triggers = taskDefinition.Triggers

Dim trigger
Set trigger = triggers.Create(TriggerTypeWeekly)

' Trigger variables that define when the trigger is active 
' and the time of day that the task is run. The format of 
' this tims is YYYY-MM-DDTHH:MM:SS
Dim startTime, endTime

Dim time
startTime = "2006-05-02T08:00:00"  'Task runs at 8:00 AM
endTime = "2015-05-02T08:00:00"

WScript.Echo "startTime :" & startTime
WScript.Echo "endTime :" & endTime

trigger.StartBoundary = startTime
trigger.EndBoundary = endTime
trigger.DaysOfWeek = 1
trigger.WeeksInterval = 1    'Task runs every week.
trigger.Id = "WeeklyTriggerId"
trigger.Enabled = True

'***********************************************************
' Create the action for the task to execute.

' Add an action to the task to run notepad.exe.
Dim Action
Set Action = taskDefinition.Actions.Create( ActionTypeExec )
Action.Path = "C:\Windows\System32\notepad.exe"

WScript.Echo "Task definition created. About to submit the task..."

'***********************************************************
' Register (create) the task.

call rootFolder.RegisterTaskDefinition( _
    "Test Weekly Trigger", taskDefinition, 6, , , 3)

WScript.Echo "Task submitted."

korzystanie z harmonogramu zadań

 

 

  • Last updated on