Elementos visuais específicos do painel

Todas as visualizações criadas no contexto do operador de renderização estão disponíveis em visualizações do dashboard. No entanto, as visualizações a seguir só estão disponíveis em painéis do Azure Data Explorer, painéis em tempo real ou interface do usuário da Web do Azure Data Explorer e não com o operador de renderização.

Para saber como personalizar qualquer visual de dashboard, confira Customize Azure Data Explorer dashboard visuals

Para obter informações gerais sobre painéis no Azure Data Explorer, consulte Visualizar dados com painéis do Azure Data Explorer.

Gráfico de funil

Um gráfico de funil visualiza um processo linear com estágios sequenciais e conectados. Cada estágio de funil representa um percentual do total. Portanto, na maioria dos casos, um gráfico de funil tem a forma de um funil, com o primeiro estágio sendo o maior, e cada estágio subsequente menor que seu antecessor.

O exemplo a seguir visualiza a progressão das solicitações do servidor, mostrando o número total de sessões, solicitações e seu status de conclusão. Ele destaca a queda das sessões para as solicitações e a proporção de solicitações concluídas em comparação com incompletas.

Exemplo de consulta

let stageOrder = datatable(Stage:string, Order:int)
[
    "session_id", 1,
    "request_id", 2,
    "Completed", 3,
    "Incomplete", 4
];

let base = TransformedServerMetrics
| where MetricType == "sqlserver_requests";

// Build the funnel table dynamically
let funnelData = 
    union 
    (base | where SQLMetrics == "session_id" | summarize Count = count() | extend Stage = "session_id"),
    (base | where SQLMetrics == "request_id" | summarize Count = count() | extend Stage = "request_id"),
    (base | where SQLMetrics == "percent_complete" 
          | summarize Count = countif(Value == 100) | extend Stage = "Completed"),
    (base | where SQLMetrics == "percent_complete" 
          | summarize Count = countif(Value < 100) | extend Stage = "Incomplete");

// Join with stage order and order properly
funnelData
| join kind=inner stageOrder on Stage
| order by Order asc
| project Stage, Count

Mapa de calor

Um mapa de calor mostra valores para uma variável principal de interesse em duas variáveis de eixo como uma grade de quadrados coloridos.

Para renderizar um mapa de calor, a consulta deve gerar uma tabela com três colunas. Os dados usados para o campo de valor devem ser numéricos. As colunas que serão usadas para valores x e y usam as seguintes regras:

• Se os valores na coluna x estiverem no string formato, os valores na coluna y também deverão estar no string formato.
• Se os valores na coluna x estiverem no datetime formato, os valores na coluna y deverão ser numéricos.

O exemplo a seguir mostra a distribuição das cinco métricas SQL mais frequentes em diferentes tipos de métrica. Ele destaca quais tipos de métrica são mais comuns para cada métrica do SQL, facilitando a identificação de padrões de atividade nas principais métricas.

Exemplo de consulta

let topMetrics = TransformedServerMetrics
| summarize TotalCount = count() by SQLMetrics
| top 5 by TotalCount;  // pick only the 5 most common metrics

TransformedServerMetrics
| where SQLMetrics in (topMetrics | project SQLMetrics)
| summarize Count = count() by SQLMetrics, MetricType
| project X = MetricType, Y = SQLMetrics, Value = Count