mv-expand operator

Applies to: ✅Microsoft Fabric✅Azure Data Explorer✅Azure Monitor✅Microsoft Sentinel

Expande matrizes dinâmicas de vários valores ou pacotes de propriedade em vários registros.

mv-expand can be described as the opposite of the aggregation operators that pack multiple values into a single dynamic-typed array or property bag, such as summarize ... make-list() and make-series. Cada elemento na matriz (escalar) ou no recipiente de propriedades gera um novo registro na saída do operador. Todas as colunas da entrada que não são expandidas são duplicadas para todos os registros na saída.

Syntax

T|mv-expand [kind=(bag | array)] [with_itemindex=IndexColumnName] ColumnName [to typeof(Typename)] [,ColumnName ...] [limitRowlimit]

T|mv-expand [kind=(bag | array)] [Name=] ArrayExpression [to typeof(Typename)] [, [Name=] ArrayExpression [to typeof(Typename)] ...] [limitRowlimit]

Learn more about syntax conventions.

Parameters

Returns

Para cada registro na entrada, o operador retorna zero, um ou vários registros na saída, conforme determinado da seguinte maneira:

1. As colunas de entrada que não são expandidas aparecem na saída com o valor original delas. Se apenas um registro de entrada for expandido em vários registros de saída, o valor será duplicado para todos os registros.

2. For each ColumnName or ArrayExpression that is expanded, the number of output records is determined for each value as explained in modes of expansion. Para cada registro de entrada, o número máximo de registros de saída é calculado. Todas as matrizes ou pacotes de propriedade são expandidos "em paralelo" para que os valores ausentes (se houver) sejam substituídos por valores nulos. Os elementos são expandidos em linhas na ordem em que aparecem na matriz ou no conjunto original.

3. Se o valor dinâmico for nulo, um registro individual será produzido para esse valor nulo. Se o valor dinâmico for uma matriz vazia ou um recipiente de propriedades, nenhum registro será produzido para esse valor. Caso contrário, será produzido um número de registros igual ao número de elementos no valor dinâmico.

As colunas expandidas são do tipo dynamic, a menos que sejam explicitamente tipificadas pelo uso da cláusula to typeof().

Modos de expansão

Há suporte para dois modos de expansões de recipiente de propriedades:

• kind=bag ou bagexpansion=bag: Os sacos de propriedade são expandidos em sacos de propriedade de entrada única. Esse modo é o padrão.
• kind=array or bagexpansion=array: Property bags are expanded into two-element [key,value] array structures, allowing uniform access to keys and values. Esse modo também permite, por exemplo, a execução de uma agregação de contagem distinta por nomes de propriedade.

Examples

Os exemplos nesta seção mostram como usar a sintaxe para ajudá-lo a começar.

Coluna única - expansão de matriz

datatable (a: int, b: dynamic)
[
    1, dynamic([10, 20]),
    2, dynamic(['a', 'b'])
]
| mv-expand b

Output

Coluna única - expansão do saco

Uma expansão simples de uma única coluna:

datatable (a: int, b: dynamic)
[
    1, dynamic({"prop1": "a1", "prop2": "b1"}),
    2, dynamic({"prop1": "a2", "prop2": "b2"})
]
| mv-expand b

Output

Coluna única - expansão de embalagem para pares de valores-chave

Uma simples expansão de saco para pares de valores-chave:

datatable (a: int, b: dynamic)
[
    1, dynamic({"prop1": "a1", "prop2": "b1"}),
    2, dynamic({"prop1": "a2", "prop2": "b2"})
]
| mv-expand kind=array b 
| extend key = b[0], val=b[1]

Output

Duas colunas compactadas

Expandindo duas colunas primeiro 'zip' as colunas aplicáveis e, em seguida, expanda-as:

datatable (a: int, b: dynamic, c: dynamic)[
    1, dynamic({"prop1": "a", "prop2": "b"}), dynamic([5, 4, 3])
]
| mv-expand b, c

Output

Produto cartesiano de duas colunas

Se você quiser obter um produto cartesiano da expansão de duas colunas, expanda uma após a outra:

datatable (a: int, b: dynamic, c: dynamic)
[
    1, dynamic({"prop1": "a", "prop2": "b"}), dynamic([5, 6])
]
| mv-expand b
| mv-expand c

Output

Convert output

Para forçar a saída de um mv-expand para determinado tipo (o padrão é dinâmico), use to typeof:

datatable (a: string, b: dynamic, c: dynamic)[
    "Constant", dynamic([1, 2, 3, 4]), dynamic([6, 7, 8, 9])
]
| mv-expand b, c to typeof(int)
| getschema 

Output

Observe que a coluna b é retornada como dynamic, enquanto c é retornado como int.

Using with_itemindex

Expansão de uma matriz com with_itemindex:

range x from 1 to 4 step 1
| summarize x = make_list(x)
| mv-expand with_itemindex=Index x

Output