Implantar um workspace usando o Terraform

A configuração de exemplo a seguir usa o azurerm provedor Terraform para implantar um workspace do Azure Databricks. Ele pressupõe que você tenha se conectado ao Azure (az login) em seu computador local com um usuário do Azure que tenha Contributor direitos à sua assinatura.

Para obter mais informações sobre o plug-in do azurerm Terraform para Databricks, consulte azurerm_databricks_workspace.

Configuração simples

terraform {
  required_providers {
    azurerm =  "~> 2.33"
    random = "~> 2.2"
  }
}

provider "azurerm" {
  features {}
}

variable "region" {
  type = string
  default = "westeurope"
}

resource "random_string" "naming" {
  special = false
  upper   = false
  length  = 6
}

data "azurerm_client_config" "current" {
}

data "external" "me" {
  program = ["az", "account", "show", "--query", "user"]
}

locals {
  prefix = "databricksdemo${random_string.naming.result}"
  tags = {
    Environment = "Demo"
    Owner       = lookup(data.external.me.result, "name")
  }
}

resource "azurerm_resource_group" "this" {
  name     = "${local.prefix}-rg"
  location = var.region
  tags     = local.tags
}

resource "azurerm_databricks_workspace" "this" {
  name                        = "${local.prefix}-workspace"
  resource_group_name         = azurerm_resource_group.this.name
  location                    = azurerm_resource_group.this.location
  sku                         = "premium"
  managed_resource_group_name = "${local.prefix}-workspace-rg"
  tags                        = local.tags
}

output "databricks_host" {
  value = "https://${azurerm_databricks_workspace.this.workspace_url}/"
}

Configuração do provedor

Em Gerenciar os workspaces do Databricks usando o Terraform, use as configurações especiais do Azure:

provider "databricks" {
  host = azurerm_databricks_workspace.this.workspace_url
}