Como criar um pacote usando um modelo de arquivo de definição de pacote

O exemplo a seguir mostra como criar um pacote e um programa usando um modelo de arquivo de definição de pacote em Configuration Manager. O modelo de arquivo de definição de pacote contém os valores padrão que são usados para criar SMS_Package e SMS_Program objetos. O exemplo a seguir usa a SMS_PDF_Package classe e o GetPDFData método para carregar as informações do modelo de arquivo de definição de pacote e para criar um pacote e os programas relacionados.

Para criar um pacote usando um modelo de arquivo de definição de pacote

1. Configure uma conexão com o Provedor de SMS.

2. Crie o novo objeto de pacote usando a SMS_PDF_Package classe.

3. Preencha quaisquer propriedades de pacote adicionais.

4. Carregue as informações do programa e associe cada programa ao pacote.

Exemplo

O método de exemplo a seguir cria um novo pacote usando um arquivo de definição de pacote.

Para obter informações sobre como chamar o código de exemplo, consulte Chamando Configuration Manager Snippets de Código.

Sub SWDCreatePDFPackage(connection, existingPDF_ID, newPackageSourceFlag, newPackageSourcePath)
    ' The PDF_ID must be passed in.
    ' The PDF_ID can be identified through the SMS_PDF_Package class.

    Dim newPDFPackage
    Dim returnCode
    Dim newPackage
    Dim newPackagePath
    Dim packageID
    Dim program
    Dim arrayOfPrograms

    ' Package Creation
    ' ----------------
    ' Create new SMS_PDF_Package instance.
    Set newPDFPackage = connection.Get("SMS_PDF_Package")

    ' Load the Package Definition File data using the GetPDFData method.
    returnCode = newPDFPackage.GetPDFData(existingPDF_ID, newPackage, arrayOfPrograms)

    ' Assign any additional package properties.
    newPackage.PkgSourceFlag = newPackageSourceFlag
    newPackage.PkgSourcePath = newPackageSourcePath

    ' Save the package path and get the Package ID.
    Set newPackagePath = newPackage.Put_
    packageID = newPackagePath.Keys("PackageID")

    ' Program Creation
    ' -----------------
    ' Enumerate through the program array and create the programs.
    For Each program In arrayOfPrograms
        program.PackageID = packageID
        program.Put_
    Next

End Sub

O método de exemplo tem os seguintes parâmetros:

Programação robusta

Para obter mais informações sobre o tratamento de erros, consulte Sobre erros de Configuration Manager.

Confira também

Visão geral da distribuiçãode software SMS_SCI_Component Classe WMI do Servidor