Compartilhar via

array_sort_desc() // Ordenar array em ordem decrescente

Aplica-se a: ✅Microsoft Fabric✅Azure Data Explorer✅Azure Monitor✅Microsoft Sentinel

Recebe uma ou mais matrizes. Classifica a primeira matriz em ordem decrescente. Ordena as matrizes restantes de modo a corresponder à primeira matriz reordenada.

Sintaxe

array_sort_desc( array1[, ..., argumentN])

array_sort_desc( array1[, ..., argumentN],nulls_last)

Se nulls_last não for fornecido, um valor padrão de true será usado.

Saiba mais sobre as convenções de sintaxe.

Parâmetros

Nome Digitar Obrigatória Descrição
array1... arrayN dynamic ✔️ A matriz ou lista de matrizes a serem classificadas.
nulls_last bool Determina se nulls deve ser o último.

Devoluções

Retorna o mesmo número de matrizes que na entrada, com a primeira matriz classificada em ordem crescente e as matrizes restantes ordenadas para corresponder à primeira matriz reordenada.

null é retornado para cada matriz que difere em comprimento da primeira.

Uma matriz que contém elementos de diferentes tipos é classificada na seguinte ordem:

  • Numérico, datetime, e timespan elementos
  • Elementos de cadeia de caracteres
  • Elementos Guid
  • Todos os outros elementos

Exemplos

O exemplo a seguir classifica a matriz inicial, array1, em ordem decrescente. Em seguida, classifica array2 para corresponder à nova ordem de array1.

Executar a consulta

let array1 = dynamic([1,3,4,5,2]);
let array2 = dynamic(["a","b","c","d","e"]);
print array_sort_desc(array1,array2)

Saída

array1_sorted array2_sorted
[5,4,3,2,1] ["d","c","b","e","a"]

Observação

Os nomes das colunas de saída são gerados automaticamente, com base nos argumentos para a função. Para atribuir nomes diferentes às colunas de saída, use a seguinte sintaxe: ... | extend (out1, out2) = array_sort_desc(array1,array2).

O exemplo a seguir classifica uma lista de nomes em ordem decrescente. Ele salva uma lista de nomes em uma variável, Names, que é dividida em uma matriz e classificada em ordem decrescente. A consulta retorna os nomes em ordem decrescente.

Executar a consulta

let Names = "John,Paul,Jane,Kayo";
let SortedNames = strcat_array(array_sort_desc(split(Names, ",")), ",");
print result = SortedNames

Saída

resultado
Paul, Kayo, John, Jane

O exemplo a seguir usa o operador summarize e a função array_sort_asc para organizar e classificar comandos pelo usuário em ordem cronológica decrescente.

Executar a consulta

datatable(command:string, command_time:datetime, user_id:string)
[
    'chmod',   datetime(2019-07-15),   "user1",
    'ls',      datetime(2019-07-02),   "user1",
    'dir',     datetime(2019-07-22),   "user1",
    'mkdir',   datetime(2019-07-14),   "user1",
    'rm',      datetime(2019-07-27),   "user1",
    'pwd',     datetime(2019-07-25),   "user1",
    'rm',      datetime(2019-07-23),   "user2",
    'pwd',     datetime(2019-07-25),   "user2",
]
| summarize timestamps = make_list(command_time), commands = make_list(command) by user_id
| project user_id, commands_in_chronological_order = array_sort_desc(timestamps, commands)[1]

Saída

id_do_usuário commands_in_chronological_order
user1 [
"rm",
"pcd",
"dir",
"chmod",
"mkdir",
"ls"
]
user2 [
"pcd",
"rm"
]

Observação

Se os dados puderem conter valores null, use make_list_with_nulls em vez de make_list.

Por padrão, null os valores são colocados por último na matriz classificada. No entanto, você pode controlá-lo explicitamente adicionando um bool valor como o último argumento para array_sort_asc().

O exemplo a seguir mostra o comportamento padrão:

Executar a consulta

print result=array_sort_desc(dynamic([null,"blue","yellow","green",null]))

Saída

resultado
["amarelo","verde","azul",nulo,nulo]

O exemplo a seguir mostra o comportamento não padrão usando o parâmetro false, que especifica que os nulos são colocados no início da matriz.

Executar a consulta

print result=array_sort_desc(dynamic([null,"blue","yellow","green",null]), false)

Saída

resultado
[null,null,"amarelo","verde","azul"]

Conteúdo relacionado

  • Last updated on