Plug-in mysql_request

Aplica-se a: ✅Microsoft Fabric✅Azure Data Explorer

O mysql_request plug-in envia uma consulta SQL para um ponto de extremidade de rede do Azure MySQL Server e retorna o primeiro conjunto de linhas nos resultados. A consulta pode retornar mais de um conjunto de linhas, mas apenas o primeiro conjunto de linhas é disponibilizado para o restante da consulta Kusto.

O plug-in é invocado com o evaluate operador.

Sintaxe

evaluatemysql_request ( ConnectionString , SqlQuery [ , SqlParameters] ) [: Esquema de saída]

Saiba mais sobre as convenções de sintaxe.

Parâmetros

Autenticação e autorização

Para autorizar um ponto de extremidade de rede do MySQL Server, você precisa especificar as informações de autorização na cadeia de conexão. O método de autorização suportado é por meio de nome de usuário e senha.

Definir política de texto explicativo

O plug-in faz chamadas para o banco de dados MySql. Verifique se a política de texto explicativo do cluster habilita chamadas do tipo mysql para o MySqlDbUri de destino.

O exemplo a seguir mostra como definir a política de texto explicativo para bancos de dados MySQL. Recomendamos restringir a política de texto explicativo a pontos de extremidade específicos (my_endpoint1, my_endpoint2).

[
  {
    "CalloutType": "mysql",
    "CalloutUriRegex": "my_endpoint1\\.mysql\\.database\\.azure\\.com",
    "CanCall": true
  },
  {
    "CalloutType": "mysql",
    "CalloutUriRegex": "my_endpoint2\\.mysql\\.database\\.azure\\.com",
    "CanCall": true
  }
]

O exemplo a seguir mostra um .alter callout policy comando para mysql CalloutType:

.alter cluster policy callout @'[{"CalloutType": "mysql", "CalloutUriRegex": "\\.mysql\\.database\\.azure\\.com", "CanCall": true}]'

Nome de usuário e autenticação de senha

O mysql_request plug-in suporta apenas autenticação de nome de usuário e senha para o ponto de extremidade do servidor MySQL e não se integra à autenticação do Microsoft Entra.

O nome de usuário e a senha são fornecidos como parte da cadeia de conexão usando os seguintes parâmetros:

User ID=...; Password=...;

Criptografia e validação do servidor

Por segurança, SslMode é definido incondicionalmente como Required ao se conectar a um ponto de extremidade de rede do servidor MySQL. Como resultado, o servidor deve ser configurado com um certificado de servidor SSL/TLS válido.

Especificar o ponto de extremidade de rede

Especifique o ponto de extremidade de rede MySQL como parte da cadeia de conexão.

Sintaxe:

Server= FQDN [Port = Porta]

Em que:

• FQDN é o nome de domínio totalmente qualificado do ponto de extremidade.
• Porta é a porta TCP do ponto de extremidade. Por padrão, 3306 é assumido.

Exemplos

Consulta SQL para o BD MySQL do Azure

O exemplo a seguir envia uma consulta SQL para um banco de dados MySQL do Azure. Ele recupera todos os registros do [dbo].[Table]e processa os resultados.

evaluate mysql_request(
    'Server=contoso.mysql.database.azure.com; Port = 3306;'
    'Database=Fabrikam;'
    h'UID=USERNAME;'
    h'Pwd=PASSWORD;',
    'select * from `dbo`.`Table`') : (Id: int, Name: string)
| where Id > 0
| project Name

Consulta SQL a um banco de dados MySQL do Azure com modificações

O exemplo a seguir envia uma consulta SQL para um banco de dados MySQL do Azure recuperando todos os registros de [dbo].[Table], ao acrescentar outra datetime coluna e, em seguida, processa os resultados no lado Kusto. Ele especifica um parâmetro SQL (@param0) a ser usado na consulta SQL.

evaluate mysql_request(
    'Server=contoso.mysql.database.azure.com; Port = 3306;'
    'Database=Fabrikam;'
    h'UID=USERNAME;'
    h'Pwd=PASSWORD;',
    'select *, @param0 as dt from `dbo`.`Table`',
    dynamic({'param0': datetime(2020-01-01 16:47:26.7423305)})) : (Id:long, Name:string, dt: datetime)
| where Id > 0
| project Name

Consulta SQL a um banco de dados MySQL do Azure sem um esquema de saída definido por consulta

O exemplo a seguir envia uma consulta SQL para um banco de dados MySQL do Azure sem um esquema de saída. Isso não é recomendado, a menos que o esquema seja desconhecido, pois pode afetar o desempenho da consulta.

evaluate mysql_request(
    'Server=contoso.mysql.database.azure.com; Port = 3306;'
    'Database=Fabrikam;'
    h'UID=USERNAME;'
    h'Pwd=PASSWORD;',
    'select * from `dbo`.`Table`')
| where Id > 0
| project Name