Compartilhar via

bag_pack()

Aplica-se a: ✅Microsoft Fabric✅Azure Data Explorer✅Azure Monitor✅Microsoft Sentinel

Cria um objeto de recipiente de propriedades dinâmico a partir de uma lista de chaves e valores.

Apelidos obsoletos: pack(), pack_dictionary()

Sintaxe

bag_pack( chave1, chave2,valor2,

Saiba mais sobre as convenções de sintaxe.

Parâmetros

Nome Tipo Obrigatória Descrição
chave string ✔️ O nome da chave.
value Qualquer tipo de dados escalares ✔️ O valor de chave.

Observação

As cadeias de caracteres de chave e valor são uma lista alternada, o comprimento total da lista deve ser par.

Devoluções

Retorna um dynamic objeto de recipiente de propriedades das entradas de chave e valor listadas.

Exemplos

Exemplo 1

O exemplo a seguir cria e retorna um recipiente de propriedades de uma lista alternada de chaves e valores.

Executar a consulta

print bag_pack("Level", "Information", "ProcessID", 1234, "Data", bag_pack("url", "www.bing.com"))

Resultados

print_0
{"Level": "Information", "ProcessID": 1234, "Data": {"url":"www.bing.com"}}

Exemplo 2

O exemplo a seguir cria um recipiente de propriedades e extrai o valor do recipiente de propriedades usando o operador '.'.

Executar a consulta

datatable (
    Source: int,
    Destination: int,
    Message: string
) [
    1234, 100, "Hi", 
    4567, 200, "Hello",
    1212, 300, "Hey" 
]
| extend MyBag=bag_pack("Dest", Destination, "Text", Message)
| project-away Source, Destination, Message
| extend MyBag_Dest=MyBag.Dest, MyBag_Text=MyBag.Text

Resultados

MyBag MyBag_Dest MyBag_Text
{"Dest":100,"Text":"Hi" } 100 Oi
{"Dest":200,"Text":"Hello" } 200 Olá
{"Dest":300,"Text":"Hey" } 300 Ei

Exemplo 3

O exemplo a seguir usa duas tabelas, SmsMessages e MmsMessages, e retorna suas colunas comuns e um recipiente de propriedades das outras colunas. As tabelas são criadas ad-hoc como parte da consulta.

Mensagens SMS

Número de origem Número do alvo Contagem de caracteres
555-555-1234 555-555-1212 46
555-555-1234 555-555-1213 50
555-555-1212 555-555-1234 32

Mensagens Mms

Número de origem Número do alvo Tamanho do arquivo FileType Nome do Arquivo
555-555-1212 555-555-1213 200 jpeg Foto 1
555-555-1234 555-555-1212 250 jpeg Foto 2
555-555-1234 555-555-1213 300 png Foto 3

Executar a consulta

let SmsMessages = datatable (
    SourceNumber: string,
    TargetNumber: string,
    CharsCount: string
) [
    "555-555-1234", "555-555-1212", "46", 
    "555-555-1234", "555-555-1213", "50",
    "555-555-1212", "555-555-1234", "32" 
];
let MmsMessages = datatable (
    SourceNumber: string,
    TargetNumber: string,
    FileSize: string,
    FileName: string
) [
    "555-555-1212", "555-555-1213", "200", "Pic1",
    "555-555-1234", "555-555-1212", "250", "Pic2",
    "555-555-1234", "555-555-1213", "300", "Pic3"
];
SmsMessages 
| join kind=inner MmsMessages on SourceNumber
| extend Packed=bag_pack("CharsCount", CharsCount, "FileSize", FileSize, "FileName", FileName) 
| where SourceNumber == "555-555-1234"
| project SourceNumber, TargetNumber, Packed

Resultados

Número de origem Número do alvo Packed
555-555-1234 555-555-1213 {"CharsCount":"50","FileSize":"250","FileName":"Pic2"}
555-555-1234 555-555-1212 {"CharsCount":"46","FileSize":"250","FileName":"Pic2"}
555-555-1234 555-555-1213 {"CharsCount":"50","FileSize":"300","FileName":"Pic3"}
555-555-1234 555-555-1212 {"CharsCount":"46","FileSize":"300","FileName":"Pic3"}

Conteúdo relacionado

  • Last updated on