Compartilhar via

Método DBEngine.RegisterDatabase (DAO)

Aplica-se ao: Access 2013, Office 2013

Insere as informações de conexão para uma fonte de dados ODBC no Registro do Windows. O driver ODBC precisa das informações de conexão quando a fonte de dados ODBC é aberta durante uma sessão.

Sintaxe

expressão . RegisterDatabase(Dsn, Driver, Silent, Attributes)

expressão Uma variável que representa um objeto DBEngine.

Parâmetros

Nome

Necessária/opcional

Tipo de dados

Descrição

Dsn

Obrigatório

String

o nome usado no método OpenDatabase . Ele se refere a um bloco de informações descritivas sobre a fonte de dados. Por exemplo, se a fonte de dados for um banco de dados remoto ODBC, ele poderá ser o nome do servidor.

Driver

Obrigatório

String

O nome do driver ODBC. Esse não é o nome do arquivo DLL do driver ODBC.

Silencioso

Obrigatório

Boolean

True se você não quiser exibir as caixas de diálogo do driver ODBC que solicitam as informações específicas do driver; ou False se você desejar exibir as caixas de diálogo do driver ODBC. Se o silencioso for True, os atributos devem conter todas as informações necessárias específicas do driver ou as caixas de diálogo serão exibidas de qualquer maneira.

Atributos

Obrigatório

String

Uma lista de palavras-chave a serem adicionadas ao Registro do Windows. As palavras-chave estão em uma sequência delimitada por retorno de carro.

Comentários

Se o banco de dados já estiver registrado (as informações de conexão já estarão inseridas) no Registro do Windows quando você usar o método RegisterDatabase, as informações de conexão serão atualizadas.

Se o método RegisterDatabase falhar por qualquer motivo, nenhuma alteração será feita no Registro do Windows, e ocorrerá um erro.

Para obter mais informações sobre drivers ODBC, como SQL Server, consulte o arquivo de Ajuda fornecido com o driver.

Exemplo

Este exemplo utiliza o método RegisterDatabase para registrar uma fonte de dados do Microsoft SQL Server chamada Publishers no Registro do Windows.

Sub RegisterDatabaseX() 
 
 Dim dbsRegister As Database 
 Dim strDescription As String 
 Dim strAttributes As String 
 Dim errLoop As Error 
 
 ' Build keywords string. 
 strDescription = InputBox( "Enter a description " & _ 
 "for the database to be registered.") 
 strAttributes = "Database=pubs" & _ 
 vbCr & "Description=" & strDescription & _ 
 vbCr & "OemToAnsi=No" & _ 
 vbCr & "Server=Server1" 
 
 ' Update Windows Registry. 
 On Error GoTo Err_Register 
 DBEngine.RegisterDatabase "Publishers", "SQL Server", _ 
 True, strAttributes 
 On Error GoTo 0 
 
 MsgBox "Use regedit.exe to view changes: " & _ 
 "HKEY_CURRENT_USER\" & _ 
 "Software\ODBC\ODBC.INI" 
 
 Exit Sub 
 
Err_Register: 
 
 ' Notify user of any errors that result from 
 ' the invalid data. 
 If DBEngine.Errors.Count > 0 Then 
 For Each errLoop In DBEngine.Errors 
 MsgBox "Error number: " & errLoop.Number & _ 
 vbCr & errLoop.Description 
 Next errLoop 
 End If 
 
 Resume Next 
 
End Sub
  • Last updated on