References.ItemRemoved event (Access)

O evento ItemRemoved ocorre quando uma referência for removida do projeto.

Sintaxe

expressão. ItemRemoved (Referência)

expressão Uma variável que representa um objeto Referências .

Parâmetros

Comentários

O evento ItemRemoved aplica-se à coleção Referências . Não está associado a um controlo, formulário ou relatório, tal como a maioria dos outros eventos. Por conseguinte, para criar uma definição de procedimento para o procedimento de evento ItemRemoved , tem de utilizar uma sintaxe especial.

O evento ItemRemoved só pode executar um procedimento de evento quando ocorre; não pode executar uma macro.

Esse evento ocorrerá somente quando for removida uma referência do código. Não ocorre quando remove uma referência da caixa de diálogo Referências , disponível ao selecionar Referências no menu Ferramentas quando a janela Módulo é a janela ativa.

Exemplo

O exemplo a seguir inclui procedimentos de evento para os eventos ItemAdded e ItemRemoved. Para experimentar este exemplo, crie primeiro um novo módulo de classe ao selecionar Módulo de Classe no menu Inserir . Cole o seguinte código no módulo de classe e guarde o módulo como RefEvents.

' Declare object variable to represent References collection. 
Public WithEvents evtReferences As References 
 
' When instance of class is created, initialize evtReferences 
' variable. 
Private Sub Class_Initialize() 
 Set evtReferences = Application.References 
End Sub 
 
' When instance is removed, set evtReferences to Nothing. 
Private Sub Class_Terminate() 
 Set evtReferences = Nothing 
End Sub 
 
' Display message when reference is added. 
Private Sub evtReferences_ItemAdded(ByVal Reference As _ 
 Access.Reference) 
 MsgBox "Reference to " & Reference.Name & " added." 
End Sub 
 
' Display message when reference is removed. 
Private Sub evtReferences_ItemRemoved(ByVal Reference As _ 
 Access.Reference) 
 MsgBox "Reference to " & Reference.Name & " removed." 
End Sub

O procedimento de Função seguinte remove uma referência especificada. Quando uma referência é removida, o procedimento de evento ItemRemoved definido na classe RefEvents é executado.

Por exemplo, para remover uma referência ao controle de calendário, você poderia passar a cadeia de caracteres "MSACAL", que é o nome do objeto Reference que representa o controle de calendário.

Function RemoveReference(strRefName As String) As Boolean 
 Dim ref As Reference 
 
 On Error GoTo Error_RemoveReference 
 ' Return object representing existing reference. 
 Set ref = objRefEvents.evtReferences(strRefName) 
 ' Remove reference from collection. 
 objRefEvents.evtReferences.Remove ref 
 RemoveReference = True 
 
Exit_RemoveReference: 
 Exit Function 
 
Error_RemoveReference: 
 MsgBox Err & ": " & Err.Description 
 RemoveReference = False 
 Resume Exit_RemoveReference 
End Function

Suporte e comentários

Tem dúvidas ou quer enviar comentários sobre o VBA para Office ou sobre esta documentação? Confira Suporte e comentários sobre o VBA para Office a fim de obter orientação sobre as maneiras pelas quais você pode receber suporte e fornecer comentários.