Compartilhar via

Método Report.Circle (Access)

O método Circle desenha um círculo, uma reticência ou um arco num objeto Relatório quando ocorre o evento Imprimir .

Sintaxe

expressão. Círculo (Passo (x, y), Raio, Cor, Início, Fim, Aspeto)

expressão Uma variável que representa um objeto Relatório .

Parâmetros

Nome Tipo de dados Descrição
Etapa Palavra-chave Indica que o centro do círculo, das reticências ou do arco é relativo às coordenadas atuais fornecidas pelas definições atuais para as propriedades CurrentX e CurrentY do argumento Objeto .
(x, y) Single Indica as coordenadas do ponto central do círculo, das reticências ou do arco. As propriedades Scale (ScaleMode, ScaleLeft, ScaleTop, ScaleHeight e ScaleWidth) do objeto Relatório especificado pelo argumento Objeto determinam a unidade de medida utilizada.
RADIUS Single Indica o raio do círculo, reticências ou arco. As propriedades Scale (ScaleMode, ScaleLeft, ScaleTop, ScaleHeight e ScaleWidth) do objeto Relatório especificado pelo argumento Objeto determinam a unidade de medida utilizada. Por predefinição, as distâncias são medidas em twips.
Color Long Indica a cor RGB (vermelho-verde-azul) do contorno do círculo. Se esse argumento for omitido, o valor da propriedade ForeColor é usado. Você também pode usar a função RGB ou QBColor função para especificar a cor.
Start Single Quando é desenhado um círculo parcial ou reticências, o argumento Iniciar especifica (em radianos) a posição inicial do arco. O valor predefinido para o argumento Iniciar é 0 radianos. O intervalo é de -2 pi radianos a 2 pi radianos.
End Single Quando é desenhado um círculo parcial ou reticências, o argumento Fim especifica (em radianos) a posição final do arco. O valor predefinido para o argumento End é 2 pi radianos. O intervalo é de -2 pi radianos a 2 pi radianos.
Aspeto Single Indica a proporção do círculo. O valor padrão é 1.0, que produz um círculo perfeito (não elíptico) em qualquer tela.

Comentários

Utilize este método apenas num procedimento de evento ou numa macro especificada pelas propriedades do evento para uma secção de relatório ou na propriedade evento OnPage de um relatório.

Ao desenhar um círculo parcial ou reticências, se o argumento Iniciar for negativo, o método Círculo desenha um raio para a posição especificada pelo argumento Iniciar e trata o ângulo como positivo. Se o argumento End for negativo, o método Circle desenha um raio para a posição especificada pelo argumento End e trata novamente o ângulo como positivo. O método Circle sempre desenha no sentido anti-horário (positivo).

Para preencher um círculo, defina as propriedades FillColor e FillStyle do relatório. Apenas uma figura fechada poderá ser preenchida. Figuras fechadas incluem círculos, elipses e fatias de pizza, que são arcos com linhas de raios desenhadas nas duas extremidades.

Ao desenhar setores circulares, se precisar de desenhar um raio para o ângulo 0 para formar um segmento de linha horizontal à direita, especifique um valor negativo muito pequeno para o argumento Iniciar em vez de 0. Por exemplo, pode especificar -.00000001 para o argumento Iniciar .

Você pode omitir um argumento no meio da sintaxe, mas deve incluir a vírgula do argumento antes de incluir o próximo argumento. Se omitir um argumento à direita, não utilize vírgulas ao seguir o último argumento que especificar.

A largura da linha utilizada para desenhar o círculo, as reticências ou o arco depende da definição da propriedade DrawWidth . A forma como o círculo é desenhado no fundo depende das definições das propriedades DrawMode e DrawStyle .

Quando você aplica o método Circle, as propriedades CurrentX e CurrentY são definidas como o ponto central especificado pelos argumentos x e y.

Exemplo

O exemplo a seguir utiliza o método Circle para desenhar um círculo e criar uma fatia de pizza dentro do círculo e a colorir de vermelho.

Para testar esse exemplo no Microsoft Access, crie um novo relatório. Defina a propriedade OnPrint da seção Detalhes como [Procedimento do Evento]. Introduza o seguinte código no módulo do relatório e, em seguida, mude para Pré-visualizar.

Private Sub Detail_Print(Cancel As Integer, PrintCount As Integer) 
    Const conPI = 3.14159265359 
    Dim sngHCtr As Single, sngVCtr As Single 
    Dim sngRadius As Single 
    Dim sngStart As Single, sngEnd As Single 
 
    sngHCtr = Me.ScaleWidth / 2     ' Horizontal center. 
    sngVCtr = Me.ScaleHeight / 2     ' Vertical center. 
    sngRadius = Me.ScaleHeight / 3     ' Circle radius. 
    ' Draw circle. 
    Me.Circle(sngHCtr, sngVCtr), sngRadius 
    sngStart = -0.00000001             ' Start of pie slice. 
    sngEnd = -2 * conPI / 3             ' End of pie slice. 
    Me.FillColor = RGB(255,0,0)     ' Color pie slice red. 
    Me.FillStyle = 0                     ' Fill pie slice. 
    ' Draw pie slice within circle. 
    Me.Circle(sngHCtr, sngVCtr), sngRadius, , sngStart, sngEnd 
End Sub

Suporte e comentários

Tem dúvidas ou quer enviar comentários sobre o VBA para Office ou sobre esta documentação? Confira Suporte e comentários sobre o VBA para Office a fim de obter orientação sobre as maneiras pelas quais você pode receber suporte e fornecer comentários.

  • Last updated on