Compartilhar via

Método Report.Line (Access)

O método Linha desenha linhas e retângulos num objeto de Relatório quando ocorre o evento Imprimir .

Sintaxe

expressão. Linha (Passo (x1, y1) – Passo (x2, y2), Cor, BF)

expressão Obrigatório. Uma variável que representa um objeto Relatório . Uma expressão que retorna um dos objetos na lista Aplica-se a.

Parâmetros

Nome Tipo de dados Descrição
Etapa Palavra-chave Indica que as coordenadas do ponto de partida são relativas à posição dos gráficos atuais dadas pelas definições atuais para as propriedades CurrentX e CurrentY do argumento Objeto .
x1, y1 Single Indica as coordenadas do ponto de partida para a linha ou retângulo. As propriedades Scale (ScaleMode, ScaleLeft, ScaleTop, ScaleHeight e ScaleWidth) do objeto Relatório especificado pelo argumento Objeto determinam a unidade de medida utilizada. Se este argumento for omitido, a linha começa na posição indicada pelas propriedades CurrentX e CurrentY .
x2, y2 Single Obrigatório. Indica as coordenadas do ponto final para a linha ou retângulo. Certifique-se de que o ponto de partida e o ponto final estão separados por um hífen ( - ).
Color Long Indica a cor RGB (vermelho-verde-azul) utilizada para desenhar a linha. Se esse argumento for omitido, o valor da propriedade ForeColor é usado. Você também pode usar a função RGB ou QBColor função para especificar a cor.
B Uma opção que cria um retângulo usando as coordenadas como extremidades opostas do retângulo.
S Não é possível utilizar F sem B. Se a opção B for utilizada, a opção F especifica que o retângulo é preenchido com a mesma cor utilizada para desenhar o retângulo. Se B for usada sem F, o retângulo será preenchido com a cor especificada pelas configurações atuais das propriedades FillColor e BackStyle. O valor padrão da propriedadeBackStyle é Normal para retângulos e linhas.

Comentários

Utilize este método apenas num procedimento de evento ou numa macro especificada pela propriedade de evento OnPrint ou OnFormat para uma secção de relatório ou a propriedade evento OnPage de um relatório.

Para conectar duas linhas desenhadas, certifique-se de que uma linha começa no ponto final da linha anterior.

A largura da linha desenhada depende da definição da propriedade DrawWidth . A forma como uma linha ou retângulo é desenhado no fundo depende das definições das propriedades DrawMode e DrawStyle .

Quando aplica o método Linha , as propriedades CurrentX e CurrentY são redefinidas para o ponto final especificado pelos argumentos x2 e y2 .

Exemplo

O exemplo seguinte utiliza o método Linha para desenhar um retângulo vermelho cinco píxeis dentro da margem de um relatório com o nome EmployeeReport. A função RGB é utilizada para tornar a linha vermelha.

Para experimentar este exemplo no Microsoft Access, crie um novo relatório com o nome EmployeeReport. Cole o seguinte código na secção Declarações do módulo do relatório e, em seguida, mude para Pré-visualizar.

Private Sub Detail_Print(Cancel As Integer, PrintCount As Integer) 
    ' Call the Drawline procedure 
    DrawLine 
End Sub 
 
Sub DrawLine() 
    Dim rpt As Report, lngColor As Long 
    Dim sngTop As Single, sngLeft As Single 
    Dim sngWidth As Single, sngHeight As Single 
 
    Set rpt = Reports!EmployeeReport 
    ' Set scale to pixels. 
    rpt.ScaleMode = 3 
    ' Top inside edge. 
    sngTop = rpt.ScaleTop + 5 
    ' Left inside edge. 
    sngLeft = rpt.ScaleLeft + 5 
    ' Width inside edge. 
    sngWidth = rpt.ScaleWidth - 10 
    ' Height inside edge. 
    sngHeight = rpt.ScaleHeight - 10 
    ' Make color red. 
    lngColor = RGB(255,0,0) 
    ' Draw line as a box. 
    rpt.Line(sngTop, sngLeft) - (sngWidth, sngHeight), lngColor, B 
End Sub

Suporte e comentários

Tem dúvidas ou quer enviar comentários sobre o VBA para Office ou sobre esta documentação? Confira Suporte e comentários sobre o VBA para Office a fim de obter orientação sobre as maneiras pelas quais você pode receber suporte e fornecer comentários.

  • Last updated on