Compartilhar via

Tabelas Dinâmicas.Adicionar método (Excel)

Adiciona um novo relatório de tabela dinâmica. Devolve um objeto de tabela dinâmica .

Sintaxe

expressão. Adicionar (PivotCache, TableDestination, TableName, ReadData, DefaultVersion)

expressão Uma variável que representa um objeto de Tabelas Dinâmicas .

Parâmetros

Nome Obrigatório/Opcional Tipo de dados Descrição
PivotCache Obrigatório PivotCache A cache da tabela dinâmica na qual se baseia o novo relatório de tabela dinâmica. A cache fornece dados para o relatório.
TableDestination Obrigatório Variant A célula no canto superior esquerdo do intervalo de destino do relatório de tabela dinâmica (o intervalo na planilha em que o relatório resultante será inserido). Você deve especificar um intervalo de destino na planilha que contém o objeto PivotTables especificado por expressão.
TableName Opcional Variant O nome do novo relatório de tabela dinâmica.
ReadData Opcional Variant True para criar um cache de tabela dinâmica que contenha todos os registros do banco de dados externo; este cache pode ser muito grande. False para habilitar a configuração de alguns dos campos como campos de página com base em servidor antes dos dados serem lidos.
DefaultVersion Opcional Variant A versão do Microsoft Excel na qual a Tabela Dinâmica foi originalmente criada.

Valor de retorno

Um objeto PivotTable que representa o novo relatório de tabela dinâmica.

Exemplo

Este exemplo cria uma nova cache de tabela dinâmica com base num fornecedor OLAP e, em seguida, cria um novo relatório de tabela dinâmica com base na cache na célula A1 na primeira folha de cálculo.

Dim cnnConn As ADODB.Connection 
Dim rstRecordset As ADODB.Recordset 
Dim cmdCommand As ADODB.Command 
 
' Open the connection. 
Set cnnConn = New ADODB.Connection 
With cnnConn 
 .ConnectionString = _ 
 "Provider=Microsoft.Jet.OLEDB.4.0" 
 .Open "C:\perfdate\record.mdb" 
End With 
 
' Set the command text. 
Set cmdCommand = New ADODB.Command 
Set cmdCommand.ActiveConnection = cnnConn 
With cmdCommand 
 .CommandText = "Select Speed, Pressure, Time From DynoRun" 
 .CommandType = adCmdText 
 .Execute 
End With 
 
' Open the recordset. 
Set rstRecordset = New ADODB.Recordset 
Set rstRecordset.ActiveConnection = cnnConn 
rstRecordset.Open cmdCommand 
 
' Create PivotTable cache and report. 
Set objPivotCache = ActiveWorkbook.PivotCaches.Add( _ 
 SourceType:=xlExternal) 
Set objPivotCache.Recordset = rstRecordset 
 
ActiveSheet.PivotTables.Add _ 
 PivotCache:=objPivotCache, _ 
 TableDestination:=Range("A3"), _ 
 TableName:="Performance" 
 
With ActiveSheet.PivotTables("Performance") 
 .SmallGrid = False 
 With .PivotFields("Pressure") 
 .Orientation = xlRowField 
 .Position = 1 
 End With 
 With .PivotFields("Speed") 
 .Orientation = xlColumnField 
 .Position = 1 
 End With 
 With .PivotFields("Time") 
 .Orientation = xlDataField 
 .Position = 1 
 End With 
End With 
 
' Close the connections and clean up. 
cnnConn.Close 
Set cmdCommand = Nothing 
Set rstRecordSet = Nothing 
Set cnnConn = Nothing

Suporte e comentários

Tem dúvidas ou quer enviar comentários sobre o VBA para Office ou sobre esta documentação? Confira Suporte e comentários sobre o VBA para Office a fim de obter orientação sobre as maneiras pelas quais você pode receber suporte e fornecer comentários.

  • Last updated on