Propriedade QueryTable.PreserveColumnInfo (Excel)

True se as informações sobre classificação, filtragem e layout de colunas forem preservadas sempre que uma tabela de consulta for atualizada. O valor padrão é True. Boolean de leitura/gravação.

Sintaxe

expressão. PreserveColumnInfo

expressão Uma variável que representa um objeto QueryTable .

Comentários

Essa propriedade só tem efeito quando a tabela de consulta está usando uma conexão de banco de dados.

Você pode definir essa propriedade como False para que haja compatibilidade com as versões anteriores do Microsoft Excel.

Se importar dados através da interface de utilizador, os dados de uma consulta Web ou de uma consulta de texto são importados como um objeto QueryTable , enquanto todos os outros dados externos são importados como um objeto ListObject .

Se importar dados com o modelo de objeto, os dados de uma consulta Web ou de uma consulta de texto têm de ser importados como uma Tabela de Consulta, enquanto todos os outros dados externos podem ser importados como um ListObject ou uma QueryTable.

Utilize a propriedade QueryTable do ListObject para aceder à propriedade PreserveColumnInfo .

Exemplo

Este exemplo preserva as informações sobre classificação, filtragem e layout de colunas para que haja compatibilidade com as versões anteriores do Microsoft Excel.

Dim cnnConnect As ADODB.Connection 
Dim rstRecordset As ADODB.Recordset 
 
Set cnnConnect = New ADODB.Connection 
cnnConnect.Open "Provider=SQLOLEDB;" & _ 
 "Data Source=srvdata;" & _ 
 "User ID=wadet;Password=4me2no;" 
 
Set rstRecordset = New ADODB.Recordset 
rstRecordset.Open _ 
 Source:="Select Name, Quantity, Price From Products", _ 
 ActiveConnection:=cnnConnect, _ 
 CursorType:=adOpenDynamic, _ 
 LockType:=adLockReadOnly, _ 
 Options:=adCmdText 
 
With ActiveSheet.QueryTables.Add( _ 
 Connection:=rstRecordset, _ 
 Destination:=Range("A1")) 
 .Name = "Contact List" 
 .FieldNames = True 
 .RowNumbers = False 
 .FillAdjacentFormulas = False 
 .PreserveFormatting = True 
 .RefreshOnFileOpen = False 
 .BackgroundQuery = True 
 .RefreshStyle = xlInsertDeleteCells 
 .SavePassword = True 
 .SaveData = True 
 .AdjustColumnWidth = True 
 .RefreshPeriod = 0 
 .PreserveColumnInfo = True 
 .Refresh BackgroundQuery:=False 
End With

Suporte e comentários

Tem dúvidas ou quer enviar comentários sobre o VBA para Office ou sobre esta documentação? Confira Suporte e comentários sobre o VBA para Office a fim de obter orientação sobre as maneiras pelas quais você pode receber suporte e fornecer comentários.